1 files changed, 51 insertions, 0 deletions
diff --git a/dev-libs/spdlog/spdlog-1.8.5-r10.ebuild b/dev-libs/spdlog/spdlog-1.8.5-r10.ebuild
new file mode 100644
index 00000000..b0e43d34
--- /dev/null
+++ b/dev-libs/spdlog/spdlog-1.8.5-r10.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Very fast, header only, C++ logging library"
+HOMEPAGE="https://github.com/gabime/spdlog"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/gabime/${PN}"
+else
+	SRC_URI="https://github.com/gabime/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/1"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+DEPEND="
+	>=dev-libs/libfmt-6.1.2:=
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/libfmt8.patch
+)
+
+src_prepare() {
+	cmake_src_prepare
+	rm -r include/spdlog/fmt/bundled || die "Failed to delete bundled libfmt"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSPDLOG_BUILD_BENCH=no
+		-DSPDLOG_BUILD_EXAMPLE=no
+		-DSPDLOG_FMT_EXTERNAL=yes
+		-DSPDLOG_BUILD_SHARED=yes
+		-DSPDLOG_BUILD_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}