2 files changed, 0 insertions, 87 deletions
diff --git a/sys-apps/apparmor-utils/Manifest b/sys-apps/apparmor-utils/Manifest
deleted file mode 100644
index ba3818a6..00000000
--- a/sys-apps/apparmor-utils/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST apparmor-2.13.4.tar.xz 4256276 BLAKE2B ccdf6f465000faab578b7ea18738b51ce6b234acb9654d60f430fa3cd6a37782ad20877005415c92c23a6e224e9990b660c562989b672d4e36eeb9e93e844858 SHA512 e79ce182d67a21bd4c00d82f8be465526a6999b1a895ccbbbe10e3040183fcfa1380184f527d4549e5115739e3077878b1d5d6a7a1b5a4737daf6741db8493ac
diff --git a/sys-apps/apparmor-utils/apparmor-utils-2.13.4-r10.ebuild b/sys-apps/apparmor-utils/apparmor-utils-2.13.4-r10.ebuild
deleted file mode 100644
index f753e04d..00000000
--- a/sys-apps/apparmor-utils/apparmor-utils-2.13.4-r10.ebuild
+++ /dev/null
@@ -1,86 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python{3_6,3_7} )
-inherit eapi7-ver perl-module python-r1 toolchain-funcs
-
-MY_PV="$(ver_cut 1-2)"
-
-DESCRIPTION="Additional userspace utils to assist with AppArmor profile management"
-HOMEPAGE="https://gitlab.com/apparmor/apparmor/wikis/home"
-SRC_URI="http://mirrors.redcorelinux.org/redcorelinux/distfiles-next/apparmor-${PV}.tar.xz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64"
-IUSE=""
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-RESTRICT="test"
-
-COMMON_DEPEND="
-	dev-lang/perl
-	~sys-libs/libapparmor-${PV}
-	${PYTHON_DEPS}"
-DEPEND="${COMMON_DEPEND}
-	sys-devel/gettext
-"
-RDEPEND="${COMMON_DEPEND}
-	~sys-libs/libapparmor-${PV}[perl,python,${PYTHON_USEDEP}]
-	~sys-apps/apparmor-${PV}
-	dev-perl/Locale-gettext
-	dev-perl/RPC-XML
-	dev-perl/TermReadKey
-	virtual/perl-Data-Dumper
-	virtual/perl-Getopt-Long"
-
-S=${WORKDIR}/apparmor-${PV}
-
-src_prepare() {
-	default
-
-	sed -i binutils/Makefile \
-		-e 's/Bstatic/Bdynamic/g' || die
-
-	sed -i utils/aa-remove-unknown \
-		-e 's#^\(APPARMOR_FUNCTIONS=\).*#\1/usr/libexec/rc.apparmor.functions#' || die
-}
-
-src_compile() {
-	python_setup
-
-	pushd utils > /dev/null || die
-	# launches non-make subprocesses causing "make jobserver unavailable"
-	# error messages to appear in generated code
-	emake -j1
-	popd > /dev/null || die
-
-	pushd binutils > /dev/null || die
-	export EXTRA_CFLAGS="${CFLAGS}"
-	emake CC="$(tc-getCC)" USE_SYSTEM=1
-	popd > /dev/null || die
-}
-
-src_install() {
-	pushd utils > /dev/null || die
-	perl_set_version
-	emake DESTDIR="${D}" PERLDIR="${D}/${VENDOR_LIB}/Immunix" \
-		VIM_INSTALL_PATH="${D}/usr/share/vim/vimfiles/syntax" install
-
-	install_python() {
-		local -x PYTHONDONTWRITEBYTECODE=
-		"${PYTHON}" "${S}"/utils/python-tools-setup.py install --prefix=/usr \
-			--root="${D}" --optimize 2
-	}
-
-	python_foreach_impl install_python
-	python_replicate_script "${D}"/usr/bin/aa-easyprof "${D}"/usr/sbin/apparmor_status \
-		"${D}"/usr/sbin/aa-{audit,autodep,cleanprof,complain,disable,enforce,genprof,logprof,mergeprof,status,unconfined}
-	popd > /dev/null || die
-
-	pushd binutils > /dev/null || die
-	emake install DESTDIR="${D}" USE_SYSTEM=1
-	popd > /dev/null || die
-}