1 files changed, 57 insertions, 0 deletions
diff --git a/sys-kernel/linux-headers/linux-headers-4.14-r1337.ebuild b/sys-kernel/linux-headers/linux-headers-4.14-r1337.ebuild
new file mode 100644
index 00000000..12291f99
--- /dev/null
+++ b/sys-kernel/linux-headers/linux-headers-4.14-r1337.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+ETYPE="headers"
+H_SUPPORTEDARCH="alpha amd64 arc arm arm64 avr32 bfin cris frv hexagon hppa ia64 m32r m68k metag microblaze mips mn10300 nios2 openrisc ppc ppc64 s390 score sh sparc tile x86 xtensa"
+inherit kernel-2
+detect_version
+
+PATCH_VER="1"
+SRC_URI="mirror://gentoo/gentoo-headers-base-${PV}.tar.xz
+	${PATCH_VER:+mirror://gentoo/gentoo-headers-${PV}-${PATCH_VER}.tar.xz}"
+
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-linux ~x86-linux"
+
+DEPEND="app-arch/xz-utils
+	dev-lang/perl"
+RDEPEND="!!media-sound/alsa-headers"
+
+S=${WORKDIR}/gentoo-headers-base-${PV}
+
+src_unpack() {
+	unpack ${A}
+}
+
+src_prepare() {
+	default
+
+	[[ -n ${PATCH_VER} ]] && eapply "${WORKDIR}/${PV}"/*.patch
+}
+
+src_install() {
+	kernel-2_src_install
+
+	# hrm, build system sucks
+	find "${ED}" '(' -name '.install' -o -name '*.cmd' ')' -delete
+	find "${ED}" -depth -type d -delete 2>/dev/null
+}
+
+src_test() {
+	# Make sure no uapi/ include paths are used by accident.
+	egrep -r \
+		-e '# *include.*["<]uapi/' \
+		"${D}" && die "#include uapi/xxx detected"
+
+	einfo "Possible unescaped attribute/type usage"
+	egrep -r \
+		-e '(^|[[:space:](])(asm|volatile|inline)[[:space:](]' \
+		-e '\<([us](8|16|32|64))\>' \
+		.
+
+	einfo "Missing linux/types.h include"
+	egrep -l -r -e '__[us](8|16|32|64)' "${ED}" | xargs grep -L linux/types.h
+
+	emake ARCH=$(tc-arch-kernel) headers_check
+}