From a0013b371da9dea58a8162de25366019c330f12a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 22 Oct 2022 13:05:00 +0100
Subject: app-arch/unp : import from gentoo, add zstd support

---
 app-arch/unp/unp-2.0_pre9-r1.ebuild | 51 +++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 app-arch/unp/unp-2.0_pre9-r1.ebuild

(limited to 'app-arch/unp/unp-2.0_pre9-r1.ebuild')

diff --git a/app-arch/unp/unp-2.0_pre9-r1.ebuild b/app-arch/unp/unp-2.0_pre9-r1.ebuild
new file mode 100644
index 00000000..f6d45a05
--- /dev/null
+++ b/app-arch/unp/unp-2.0_pre9-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1 strip-linguas
+
+DESCRIPTION="Script for unpacking various file formats"
+HOMEPAGE="https://packages.qa.debian.org/u/unp.html"
+MY_PV="${PV/_pre/$'\x7e'pre}"
+SRC_URI="mirror://debian/pool/main/u/unp/${PN}_${MY_PV}.tar.xz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~hppa ~ppc x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x86-solaris"
+IUSE="nls"
+
+DEPEND="nls? ( sys-devel/gettext )"
+
+RDEPEND="${DEPEND}
+	dev-lang/perl"
+
+PATCHES=( "${FILESDIR}"/zstd-support.patch )
+
+src_compile() {
+	if use nls; then
+		strip-linguas -i .
+		if [ -n "$LINGUAS" ]; then
+			emake -C po MOFILES="${LINGUAS// /.po }.po"
+		else
+			emake -C po
+		fi
+	fi
+}
+
+src_install() {
+	dobin unp
+	dosym unp /usr/bin/ucat
+	doman debian/unp.1
+	dodoc debian/changelog debian/README.Debian
+	newbashcomp debian/unp.bash-completion unp
+
+	if use nls; then
+		if [ -n "$LINGUAS" ]; then
+			emake -C po MOFILES="${LINGUAS// /.mo }.mo" DESTDIR="${D}" install
+		else
+			emake -C po DESTDIR="${D}" install
+		fi
+	fi
+}
-- 
cgit v1.2.3