From ff68d802c43d3bebde7fe823b708c3a4ecaf6787 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 20 Mar 2021 16:44:50 +0000
Subject: dev-libs/ocl-icd : version bump

---
 dev-libs/ocl-icd/ocl-icd-2.2.14-r10.ebuild | 44 ++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 dev-libs/ocl-icd/ocl-icd-2.2.14-r10.ebuild

(limited to 'dev-libs/ocl-icd/ocl-icd-2.2.14-r10.ebuild')

diff --git a/dev-libs/ocl-icd/ocl-icd-2.2.14-r10.ebuild b/dev-libs/ocl-icd/ocl-icd-2.2.14-r10.ebuild
new file mode 100644
index 00000000..e4d747fa
--- /dev/null
+++ b/dev-libs/ocl-icd/ocl-icd-2.2.14-r10.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic multilib-minimal
+
+DESCRIPTION="Alternative to vendor specific OpenCL ICD loaders"
+HOMEPAGE="https://github.com/OCL-dev/ocl-icd"
+SRC_URI="https://github.com/OCL-dev/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# Does nothing now but by keeping it here we avoid having to have virtual/opencl
+# handle ebuilds both with and without this flag.
+IUSE="+khronos-headers"
+
+BDEPEND="dev-lang/ruby:2.5
+	virtual/rubygems"
+DEPEND=">=dev-util/opencl-headers-2020.12.18"
+RDEPEND="${DEPEND}
+	!app-eselect/eselect-opencl
+	!dev-libs/opencl-icd-loader"
+
+src_prepare() {
+	replace-flags -Os -O2 # bug 646122
+
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	# dev-util/opencl-headers ARE official Khronos Group headers, what this option
+	# does is disable the use of the bundled ones
+	ECONF_SOURCE="${S}" econf --enable-pthread-once --disable-official-khronos-headers
+}
+
+multilib_src_install() {
+	default
+
+	# Drop .la files
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3