From 1e0a42416753e739963e32fdc891c96becd56121 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 10 Feb 2018 20:47:36 +0000
Subject: dev-qt : increase qt5 revision number to 1000, so gentoo cannot beat
 it

---
 .../qtmultimedia/qtmultimedia-5.9.3-r1000.ebuild   | 65 ++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 dev-qt/qtmultimedia/qtmultimedia-5.9.3-r1000.ebuild

(limited to 'dev-qt/qtmultimedia/qtmultimedia-5.9.3-r1000.ebuild')

diff --git a/dev-qt/qtmultimedia/qtmultimedia-5.9.3-r1000.ebuild b/dev-qt/qtmultimedia/qtmultimedia-5.9.3-r1000.ebuild
new file mode 100644
index 00000000..3c3ebb9a
--- /dev/null
+++ b/dev-qt/qtmultimedia/qtmultimedia-5.9.3-r1000.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qt5-build-r10000
+
+DESCRIPTION="Multimedia (audio, video, radio, camera) library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="amd64"
+fi
+
+IUSE="alsa gles2 gstreamer openal pulseaudio qml widgets"
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2=]
+	~dev-qt/qtnetwork-${PV}
+	alsa? ( media-libs/alsa-lib )
+	gstreamer? (
+		dev-libs/glib:2
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-bad:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	qml? (
+		~dev-qt/qtdeclarative-${PV}
+		gles2? ( ~dev-qt/qtgui-${PV}[egl] )
+		openal? ( media-libs/openal )
+	)
+	widgets? (
+		~dev-qt/qtopengl-${PV}
+		~dev-qt/qtwidgets-${PV}[gles2=]
+	)
+"
+DEPEND="${RDEPEND}
+	gstreamer? ( x11-proto/videoproto )
+"
+
+src_prepare() {
+	qt_use_disable_config openal openal \
+		src/imports/imports.pro
+
+	qt_use_disable_mod qml quick \
+		src/src.pro \
+		src/plugins/plugins.pro
+
+	qt_use_disable_mod widgets widgets \
+		src/src.pro \
+		src/gsttools/gsttools.pro \
+		src/plugins/gstreamer/common.pri
+
+	qt5-build-r10000_src_prepare
+}
+
+src_configure() {
+	local myqmakeargs=(
+		--
+		$(qt_use alsa)
+		$(qt_use gstreamer)
+		$(qt_use pulseaudio)
+	)
+	qt5-build-r10000_src_configure
+}
-- 
cgit v1.2.3