From 9ba29c9ada954c7ef80401b59bf091dc2c3698f0 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 30 Sep 2024 03:41:13 +0100
Subject: lxqt-base/lxqt-meta : use qt5ct && qt6ct for theming, instead of
 lxqt-qtplugin

---
 lxqt-base/lxqt-config/lxqt-config-2.0.0-r1.ebuild | 72 +++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 lxqt-base/lxqt-config/lxqt-config-2.0.0-r1.ebuild

(limited to 'lxqt-base/lxqt-config/lxqt-config-2.0.0-r1.ebuild')

diff --git a/lxqt-base/lxqt-config/lxqt-config-2.0.0-r1.ebuild b/lxqt-base/lxqt-config/lxqt-config-2.0.0-r1.ebuild
new file mode 100644
index 00000000..6564120d
--- /dev/null
+++ b/lxqt-base/lxqt-config/lxqt-config-2.0.0-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PV="$(ver_cut 1-2)"
+
+inherit cmake xdg-utils
+
+DESCRIPTION="LXQt system configuration control center"
+HOMEPAGE="https://lxqt-project.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="amd64 arm64 ~riscv ~x86"
+fi
+
+LICENSE="GPL-2 GPL-2+ GPL-3 LGPL-2 LGPL-2+ LGPL-2.1+ WTFPL-2"
+SLOT="0"
+IUSE="+monitor +touchpad"
+
+BDEPEND="
+	>=dev-qt/qttools-6.6:6[linguist]
+	>=dev-util/lxqt-build-tools-2.0.0
+"
+DEPEND="
+	>=dev-libs/libqtxdg-4.0.0
+	>=dev-qt/qtbase-6.6:6[gui,widgets,xml]
+	>=dev-qt/qtsvg-6.6:6
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	=lxqt-base/lxqt-menu-data-${MY_PV}*
+	sys-libs/zlib:=
+	x11-apps/setxkbmap
+	x11-libs/libxcb:=
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	monitor? ( kde-plasma/libkscreen:6= )
+	touchpad? (
+		virtual/libudev:=
+		x11-drivers/xf86-input-libinput
+		x11-libs/libXi
+	)
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}"/"${PN}"-qt5ct.patch )
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MONITOR=$(usex monitor)
+		-DWITH_TOUCHPAD=$(usex touchpad)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman man/*.1 liblxqt-config-cursor/man/*.1 lxqt-config-appearance/man/*.1
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
-- 
cgit v1.2.3