From d4c7245d0e7690f2f455ba3c7e09edcd3f62209d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 22 May 2019 12:07:09 +0100
Subject: lxqt-base/lxqt-panel : EAPI bump

---
 lxqt-base/lxqt-panel/lxqt-panel-0.14.1.ebuild | 120 +++++++++++++++++---------
 1 file changed, 78 insertions(+), 42 deletions(-)

(limited to 'lxqt-base')

diff --git a/lxqt-base/lxqt-panel/lxqt-panel-0.14.1.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-0.14.1.ebuild
index 6cfb13f0..7f7f60da 100644
--- a/lxqt-base/lxqt-panel/lxqt-panel-0.14.1.ebuild
+++ b/lxqt-base/lxqt-panel/lxqt-panel-0.14.1.ebuild
@@ -1,36 +1,54 @@
-# Copyright 1999-2016 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=7
+
 inherit cmake-utils
 
 DESCRIPTION="LXQt desktop panel and plugins"
-HOMEPAGE="http://lxqt.org/"
+HOMEPAGE="https://lxqt.org/"
+
+MY_PV="$(ver_cut 1-2)*"
 
-SRC_URI="https://github.com/lxde/${PN}/releases/download/${PV}/${P}.tar.xz"
-KEYWORDS="amd64"
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/downloads/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
 
 LICENSE="LGPL-2.1+"
 SLOT="0"
-IUSE="+alsa +clock colorpicker cpuload +desktopswitch dom +kbindicator +mainmenu
+IUSE="+alsa colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator +mainmenu
 	+mount networkmonitor pulseaudio +quicklaunch sensors +showdesktop
-	statusnotifier sysstat +taskbar +tray +volume worldclock"
-REQUIRED_USE="volume? ( || ( alsa pulseaudio ) )"
+	+spacer statusnotifier sysstat +taskbar +tray +volume +worldclock"
 
-CDEPEND="
-	>=dev-libs/glib-2.50.0
-	>=dev-libs/libqtxdg-3.2.0
+# Work around a missing header issue: https://bugs.gentoo.org/666278
+REQUIRED_USE="
+	|| ( desktopswitch mainmenu showdesktop taskbar )
+	volume? ( || ( alsa pulseaudio ) )
+"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	>=lxqt-base/lxqt-build-tools-0.6.0
+	virtual/pkgconfig
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.3.1
 	dev-qt/qtcore:5
 	dev-qt/qtdbus:5
 	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
 	dev-qt/qtwidgets:5
 	dev-qt/qtx11extras:5
 	dev-qt/qtxml:5
-	kde-frameworks/kguiaddons:5
 	kde-frameworks/kwindowsystem:5[X]
-	>=lxde-base/menu-cache-0.3.3
-	~lxqt-base/liblxqt-${PV}
-	~lxqt-base/lxqt-globalkeys-${PV}
+	>=lxde-base/lxmenu-data-0.1.5
+	>=lxde-base/menu-cache-1.1.0
+	=lxqt-base/liblxqt-${MY_PV}
+	=lxqt-base/lxqt-globalkeys-${MY_PV}
 	x11-libs/libX11
 	cpuload? ( sys-libs/libstatgrab )
 	kbindicator? ( x11-libs/libxkbcommon )
@@ -38,39 +56,57 @@ CDEPEND="
 	networkmonitor? ( sys-libs/libstatgrab )
 	sensors? ( sys-apps/lm_sensors )
 	statusnotifier? ( dev-libs/libdbusmenu-qt[qt5(+)] )
-	sysstat? ( =lxqt-base/libsysstat-0.4* )
-	tray? ( x11-libs/libXcomposite
+	sysstat? ( >=lxqt-base/libsysstat-0.4.1 )
+	tray? (
+		x11-libs/libxcb:=
+		x11-libs/libXcomposite
 		x11-libs/libXdamage
-		x11-libs/libXrender )
-	volume? ( alsa? ( media-libs/alsa-lib )
-		pulseaudio? ( media-sound/pulseaudio ) )"
-DEPEND="${CDEPEND}
-	dev-qt/linguist-tools:5
-	!lxqt-base/lxqt-common"
-RDEPEND="${CDEPEND}
-	dev-qt/qtsvg:5
-	>=lxde-base/lxmenu-data-0.1.2"
+		x11-libs/libXrender
+		x11-libs/xcb-util
+	)
+	volume? (
+		alsa? ( media-libs/alsa-lib )
+		pulseaudio? (
+			media-sound/pavucontrol-qt
+			media-sound/pulseaudio
+		)
+	)
+"
+RDEPEND="${DEPEND}
+	!lxqt-base/lxqt-l10n
+"
 
-src_prepare() {
-	epatch "${FILESDIR}"/lxqt-menu-cleanup.patch
-	cmake-utils_src_prepare
-}
+PATCHES=( "${FILESDIR}"/lxqt-menu-cleanup.patch )
 
 src_configure() {
-	local mycmakeargs i y
-	mycmakeargs=( -DPULL_TRANSLATIONS=OFF )
-	for i in clock colorpicker cpuload desktopswitch dom kbindicator mainmenu mount \
-		networkmonitor quicklaunch sensors showdesktop statusnotifier \
-		sysstat taskbar tray volume worldclock; do
-		#Switch to ^^ when we switch to EAPI=6.
-		#y=${i^^}
-		y=$(tr '[:lower:]' '[:upper:]' <<< "${i}")
-		mycmakeargs+=( $(cmake-utils_use ${i} ${y}_PLUGIN) )
-	done
+	local mycmakeargs=(
+		# Plugins
+		-DCOLORPICKER_PLUGIN=$(usex colorpicker)
+		-DCPULOAD_PLUGIN=$(usex cpuload)
+		-DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
+		-DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
+		-DDOM_PLUGIN=$(usex dom)
+		-DKBINDICATOR_PLUGIN=$(usex kbindicator)
+		-DMAINMENU_PLUGIN=$(usex mainmenu)
+		-DMOUNT_PLUGIN=$(usex mount)
+		-DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
+		-DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
+		-DSENSORS_PLUGIN=$(usex sensors)
+		-DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
+		-DSPACER_PLUGIN=$(usex spacer)
+		-DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
+		-DSYSSTAT_PLUGIN=$(usex sysstat)
+		-DTASKBAR_PLUGIN=$(usex taskbar)
+		-DTRAY_PLUGIN=$(usex tray)
+		-DVOLUME_PLUGIN=$(usex volume)
+		-DWORLDCLOCK_PLUGIN=$(usex worldclock)
+	)
 
 	if use volume; then
-		mycmakeargs+=( $(cmake-utils_use alsa VOLUME_USE_ALSA)
-			$(cmake-utils_use pulseaudio VOLUME_USE_PULSEAUDIO) )
+		mycmakeargs+=(
+			-DVOLUME_USE_ALSA=$(usex alsa)
+			-DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
+		)
 	fi
 
 	cmake-utils_src_configure
-- 
cgit v1.2.3