From 9bead8a623206cc8940e107fc9caf04409bfb6fc Mon Sep 17 00:00:00 2001
From: BlackNoxis <steven.darklight@gmail.com>
Date: Sun, 22 Feb 2015 12:51:34 +0200
Subject: Added jackd-firewire

---
 media-libs/jackd-firewire/Manifest                 |  1 +
 .../jackd-firewire/jackd-firewire-0.124.1.ebuild   | 61 ++++++++++++++++++++++
 2 files changed, 62 insertions(+)
 create mode 100644 media-libs/jackd-firewire/jackd-firewire-0.124.1.ebuild

(limited to 'media-libs')

diff --git a/media-libs/jackd-firewire/Manifest b/media-libs/jackd-firewire/Manifest
index a0beecca..28c4cd98 100644
--- a/media-libs/jackd-firewire/Manifest
+++ b/media-libs/jackd-firewire/Manifest
@@ -1 +1,2 @@
 DIST jack-audio-connection-kit-0.121.3.tar.gz 1083545 SHA256 b7095d3deabeecd19772b37241e89c6c79de6afd6c031ba7567513cfe51beafa
+DIST jack-audio-connection-kit-0.124.1.tar.gz 1113456 SHA256 eb42df6065576f08feeeb60cb9355dce4eb53874534ad71534d7aa31bae561d6 SHA512 9c885da516f2ca246edba94db26c851229d063f1557ea91ec76ca57d675a510d16cc4baad5adb316cf46aaaa8b8d7579b484a53b9a803b34fc9bb34c983a8fe2 WHIRLPOOL 41232400d99a72b29a75f4d781c373a7f453c704a52b0a669cab71296574881b0a99b21b86628d02db8c3d7a64bec6a259ae1ba0a4c721867e19283139cee824
diff --git a/media-libs/jackd-firewire/jackd-firewire-0.124.1.ebuild b/media-libs/jackd-firewire/jackd-firewire-0.124.1.ebuild
new file mode 100644
index 00000000..6b851235
--- /dev/null
+++ b/media-libs/jackd-firewire/jackd-firewire-0.124.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=2
+
+inherit multilib
+
+MY_PN="jack-audio-connection-kit"
+DESCRIPTION="FFADO backend for JACK Audio Connection Kit"
+HOMEPAGE="http://www.jackaudio.org"
+SRC_URI="http://www.jackaudio.org/downloads/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE=""
+
+RDEPEND="
+	>=media-libs/alsa-lib-1.0.18
+	media-libs/libffado
+	~media-sound/${MY_PN}-${PV}[-ffado]
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+	sed -i \
+		-e "s:\$(top_builddir)/libjack/libjack.la:${ROOT}usr/$(get_libdir)/libjack.la:" \
+		-e "s:\$(top_builddir)/jackd/libjackserver.la:${ROOT}usr/$(get_libdir)/libjackserver.la:" \
+		drivers/firewire/Makefile.in || die
+}
+
+src_configure() {
+	# use !doc equivalent
+	export ac_cv_prog_HAVE_DOXYGEN=false
+
+	econf \
+		--enable-firewire \
+		--disable-altivec \
+		--disable-alsa \
+		--disable-coreaudio \
+		--disable-debug \
+		--disable-mmx \
+		--disable-oss \
+		--disable-portaudio \
+		--disable-sse \
+		--with-html-dir=/usr/share/doc/${PF} \
+		--disable-dependency-tracking \
+		|| die "configure failed"
+}
+
+src_compile() {
+	emake -C drivers/firewire || die
+}
+
+src_install() {
+	emake -C drivers/firewire DESTDIR="${D}" install || die "install failed"
+}
-- 
cgit v1.2.3