From d59f5f405188d93f5c00e21840930d4f1eaf8dd1 Mon Sep 17 00:00:00 2001
From: BlackNoxis <steven.darklight@gmail.com>
Date: Wed, 31 Dec 2014 22:37:52 +0200
Subject: Added media gfx,libs,sound

---
 media-libs/jackd-firewire/Manifest                 |  1 +
 .../jackd-firewire/jackd-firewire-0.121.3.ebuild   | 61 ++++++++++++++++++++++
 media-libs/jackd-firewire/metadata.xml             |  5 ++
 3 files changed, 67 insertions(+)
 create mode 100644 media-libs/jackd-firewire/Manifest
 create mode 100644 media-libs/jackd-firewire/jackd-firewire-0.121.3.ebuild
 create mode 100644 media-libs/jackd-firewire/metadata.xml

(limited to 'media-libs')

diff --git a/media-libs/jackd-firewire/Manifest b/media-libs/jackd-firewire/Manifest
new file mode 100644
index 00000000..a0beecca
--- /dev/null
+++ b/media-libs/jackd-firewire/Manifest
@@ -0,0 +1 @@
+DIST jack-audio-connection-kit-0.121.3.tar.gz 1083545 SHA256 b7095d3deabeecd19772b37241e89c6c79de6afd6c031ba7567513cfe51beafa
diff --git a/media-libs/jackd-firewire/jackd-firewire-0.121.3.ebuild b/media-libs/jackd-firewire/jackd-firewire-0.121.3.ebuild
new file mode 100644
index 00000000..d27304a8
--- /dev/null
+++ b/media-libs/jackd-firewire/jackd-firewire-0.121.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=2
+
+inherit multilib
+
+MY_PN="jack-audio-connection-kit"
+DESCRIPTION="FFADO backend for JACK Audio Connection Kit"
+HOMEPAGE="http://www.jackaudio.org"
+SRC_URI="http://www.jackaudio.org/downloads/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE=""
+
+RDEPEND="
+	>=media-libs/alsa-lib-1.0.18
+	media-libs/libffado
+	~media-sound/${MY_PN}-${PV}[-ffado]
+"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+	sed -i \
+		-e "s:\$(top_builddir)/libjack/libjack.la:${ROOT}usr/$(get_libdir)/libjack.la:" \
+		-e "s:\$(top_builddir)/jackd/libjackserver.la:${ROOT}usr/$(get_libdir)/libjackserver.la:" \
+		drivers/firewire/Makefile.in || die
+}
+
+src_configure() {
+	# use !doc equivalent
+	export ac_cv_prog_HAVE_DOXYGEN=false
+
+	econf \
+		--enable-firewire \
+		--disable-altivec \
+		--disable-alsa \
+		--disable-coreaudio \
+		--disable-debug \
+		--disable-mmx \
+		--disable-oss \
+		--disable-portaudio \
+		--disable-sse \
+		--with-html-dir=/usr/share/doc/${PF} \
+		--disable-dependency-tracking \
+		|| die "configure failed"
+}
+
+src_compile() {
+	emake -C drivers/firewire || die
+}
+
+src_install() {
+	emake -C drivers/firewire DESTDIR="${D}" install || die "install failed"
+}
diff --git a/media-libs/jackd-firewire/metadata.xml b/media-libs/jackd-firewire/metadata.xml
new file mode 100644
index 00000000..40221f6b
--- /dev/null
+++ b/media-libs/jackd-firewire/metadata.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer><email>slawomir.nizio@sabayon.org</email></maintainer>
+</pkgmetadata>
-- 
cgit v1.2.3