From 7224c1253228e5c29c78cb3f0f26ce34770f2356 Mon Sep 17 00:00:00 2001
From: BlackNoxis <steven.darklight@gmail.com>
Date: Sat, 15 Feb 2014 23:24:26 +0200
Subject: Added ebuilds for kogaion desktop

---
 .../nvidia-settings/nvidia-settings-310.19.ebuild  | 66 ++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 media-video/nvidia-settings/nvidia-settings-310.19.ebuild

(limited to 'media-video/nvidia-settings/nvidia-settings-310.19.ebuild')

diff --git a/media-video/nvidia-settings/nvidia-settings-310.19.ebuild b/media-video/nvidia-settings/nvidia-settings-310.19.ebuild
new file mode 100644
index 00000000..42f9cf45
--- /dev/null
+++ b/media-video/nvidia-settings/nvidia-settings-310.19.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=4
+
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="NVIDIA Linux X11 Settings Utility"
+HOMEPAGE="http://www.nvidia.com/"
+SRC_URI="ftp://download.nvidia.com/XFree86/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd ~amd64-fbsd"
+IUSE="examples"
+
+COMMON_DEPEND="x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXxf86vm
+	x11-libs/gtk+:2
+	x11-libs/gdk-pixbuf[X]
+	media-libs/mesa
+	x11-libs/pango[X]
+	x11-libs/libXv
+	x11-libs/libXrandr
+	dev-libs/glib:2"
+
+RDEPEND="=x11-drivers/nvidia-drivers-3*
+	${COMMON_DEPEND}"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	x11-proto/xproto"
+
+src_compile() {
+	einfo "Building libXNVCtrl..."
+	emake -C src/libXNVCtrl/ clean # NVidia ships pre-built archives :(
+	emake -C src/libXNVCtrl/ CC="$(tc-getCC)" RANLIB="$(tc-getRANLIB)" libXNVCtrl.a
+
+	einfo "Building nvidia-settings..."
+	emake -C src/ CC="$(tc-getCC)" LD="$(tc-getLD)" STRIP_CMD="$(type -P true)" NV_VERBOSE=1
+}
+
+src_install() {
+	emake -C src/ DESTDIR="${D}" PREFIX=/usr install
+
+	insinto /usr/$(get_libdir)
+	doins src/libXNVCtrl/libXNVCtrl.a
+
+	insinto /usr/include/NVCtrl
+	doins src/libXNVCtrl/*.h
+
+#	doicon doc/${PN}.png # Installed through nvidia-drivers
+	make_desktop_entry ${PN} "NVIDIA X Server Settings" ${PN} Settings
+
+	# bug 412569 - Installed through nvidia-drivers
+#	rm -rf "${D}"/usr/share/man
+
+	dodoc doc/*.txt
+
+	if use examples; then
+		docinto examples/
+		dodoc samples/*.c
+		dodoc samples/README
+	fi
+}
-- 
cgit v1.2.3