gentoo resync : 18.08.2019

2 files changed, 113 insertions, 0 deletions

diff --git a/app-accessibility/speech-dispatcher/Manifest b/app-accessibility/speech-dispatcher/Manifest
index e6b638c647cb..dc9fc386b5aa 100644
--- a/app-accessibility/speech-dispatcher/Manifest
+++ b/app-accessibility/speech-dispatcher/Manifest
@@ -1,3 +1,4 @@
 DIST speech-dispatcher-0.8.7.tar.gz 1333677 BLAKE2B 0b08f1a1228fe1240e14b3d52913f8fa64a1f2ee9b563294b49ea8d3e5cfd3041aa5572ec72354b360dabd2d263deb79e418b95b6174a5b89ee541e9fd23c7e2 SHA512 0e7af02e8521aa8d397ea4d0329f9a8d56970beed645456dfedc738ececd2ccd8ecfdf66e92ae852878a473ba991175e1d4dc2b8b0148c958163682b49678375
+EBUILD speech-dispatcher-0.8.7-r1.ebuild 2719 BLAKE2B 58fe087a399b0f682341a05337063818056359dc70fc4d5b361e7053ab7d9065a782ae33039ca7b63bba77b0ea70150b46fb3dcfc4b2b199367f61de1fdbfba3 SHA512 45d0f024d7259ea9cfa4398cb1651e3ab8890f335df47eff88b39d9f14feeea88b10312d4c4d933e5ccd037f57afab2e0cfb83e719df268f39c5f7edf7acfbc9
 EBUILD speech-dispatcher-0.8.7.ebuild 2707 BLAKE2B 8f010e26ffdb79b57f3307b5ef16bfbdf72d8d1301370f2b5267d08e92500a0c2814098254fc8b5b09165d8dad85b9e7185990791aff3934b818b0f720fb9210 SHA512 f9fbc151c6e08e04b27e2c120f201764373306e9ba14e469ba8730e0b435b587689c6d340a7c09e3fd55560d57baa60bc89987deb2aa7da4051d7c44294cb492
 MISC metadata.xml 632 BLAKE2B 2a60d2e822db36bf3f0547d97ccaad05d6bcce11afa71534b108358f1d71f857f200907f01c31c3083a5196e43eb681c06e2991a086c91731daced3f56282c2d SHA512 db94cba99bd2c9bbfe98b1647ac53a3861cbd697df791bea025e2a713a5991ca6929f2bc82a985ba38eef4a2571515d96aac6558fe143b68e24713490c12dd0a
diff --git a/app-accessibility/speech-dispatcher/speech-dispatcher-0.8.7-r1.ebuild b/app-accessibility/speech-dispatcher/speech-dispatcher-0.8.7-r1.ebuild
new file mode 100644
index 000000000000..44d74058468a
--- /dev/null
+++ b/app-accessibility/speech-dispatcher/speech-dispatcher-0.8.7-r1.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit eutils python-r1
+
+DESCRIPTION="Speech synthesis interface"
+HOMEPAGE="http://www.freebsoft.org/speechd"
+SRC_URI="http://www.freebsoft.org/pub/projects/speechd/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="alsa ao +espeak flite nas pulseaudio python static-libs"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="python? ( ${PYTHON_DEPS} )
+	>=dev-libs/dotconf-1.3
+	>=dev-libs/glib-2.28:2
+	dev-libs/libltdl:0
+	>=media-libs/libsndfile-1.0.2
+	alsa? ( media-libs/alsa-lib )
+	ao? ( media-libs/libao )
+	espeak? ( app-accessibility/espeak )
+	flite? ( app-accessibility/flite )
+	nas? ( media-libs/nas )
+	pulseaudio? ( media-sound/pulseaudio )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40.0
+	virtual/pkgconfig"
+RDEPEND="${COMMON_DEPEND}
+	python? ( dev-python/pyxdg[${PYTHON_USEDEP}] )"
+
+src_configure() {
+	# bug 573732
+	export GIT_CEILING_DIRECTORIES="${WORKDIR}"
+
+	local myeconfargs=(
+		--disable-python
+		$(use_enable static-libs static)
+		$(use_with alsa)
+		$(use_with ao libao)
+		$(use_with espeak)
+		$(use_with flite)
+		$(use_with pulseaudio pulse)
+		$(use_with nas)
+	)
+	econf ${myeconfargs[@]}
+}
+
+src_compile() {
+	use python && python_copy_sources
+
+	emake
+
+	if use python; then
+		building() {
+			cd src/api/python || die
+			emake \
+				pyexecdir="$(python_get_sitedir)" \
+				pythondir="$(python_get_sitedir)"
+		}
+		python_foreach_impl run_in_build_dir building
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc ANNOUNCE AUTHORS BUGS FAQ NEWS README*
+
+	prune_libtool_files --all
+
+	if use python; then
+		installation() {
+			cd src/api/python || die
+			emake \
+				DESTDIR="${D}" \
+				pyexecdir="$(python_get_sitedir)" \
+				pythondir="$(python_get_sitedir)" \
+				install
+		}
+		python_foreach_impl run_in_build_dir installation
+		python_replicate_script "${ED}"/usr/bin/spd-conf
+	fi
+}
+
+pkg_postinst() {
+	local editconfig="n"
+	if ! use espeak; then
+		ewarn "You have disabled espeak, which is speech-dispatcher's"
+		ewarn "default speech synthesizer."
+		ewarn
+		editconfig="y"
+	fi
+	if ! use pulseaudio; then
+		ewarn "You have disabled pulseaudio support."
+		ewarn "pulseaudio is speech-dispatcher's default audio subsystem."
+		ewarn
+		editconfig="y"
+	fi
+	if [[ "${editconfig}" == "y" ]]; then
+		ewarn "You must edit ${EROOT}/etc/speech-dispatcher/speechd.conf"
+		ewarn "and make sure the settings there match your system."
+		ewarn
+	fi
+	elog "For festival support, you need to"
+	elog "install app-accessibility/festival-freebsoft-utils."
+}