gentoo auto-resync : 21:03:2023 - 00:38:34

4 files changed, 230 insertions, 2 deletions

diff --git a/app-admin/Manifest.gz b/app-admin/Manifest.gz
index ab575bce33a6..aaa015d103b8 100644
--- a/app-admin/Manifest.gz
+++ b/app-admin/Manifest.gz
diff --git a/app-admin/conky/Manifest b/app-admin/conky/Manifest
index 0c35ad7e19d9..8c3a6cc820d3 100644
--- a/app-admin/conky/Manifest
+++ b/app-admin/conky/Manifest
@@ -1,7 +1,9 @@
 DIST conky-1.13.1.tar.gz 2443276 BLAKE2B e51610172e830d0368e8c9a48ea056285efe48275364c4d0c973da6467ea044303d75f94cc0b963c3b423a7ec61d8eff26da30c102c557ccd5a4e8cf984db4f6 SHA512 3ee0e14f6ff2bac39404c272790055ac1106f47a00e8298da909a0febf6de0661486e8ce23f34e8c5050e364168b2efcefd0b28736cbd0bc135e1362f0dc5516
 DIST conky-1.17.0.tar.gz 1699311 BLAKE2B 9aead9e1e9bf4bf61c1b3e09c6e319135ccce19c43740c1bb3c6142c936c2a045820078f4684ea037fc26a8b02343e11b5372f74258fdf2c5386459410498cc9 SHA512 4da55ba3835e8ff42747f2bc01c34a94b2819e08eb74ddb913fd34bf4b682d75331119745ee006d842d3d2142fc53eeada16afdf698a60f37b566f55896aa2db
 DIST conky-1.18.1.tar.gz 1703018 BLAKE2B ba3c0f9624bfcf229de4376a9446ad05285db4241d1caf4a7a8ac92971f57d022192504c9831a786e3c02db140d70f10cf34d7e146c8647cb2a2b923e6acc2cc SHA512 e390d2aa8a3f3b570b2e3dc43ef71ff0001e36f3b42ce5a9c01b8dca656a23b1af80ee2ee138f38b12b4581dd03711562445fb53e23ca0f26e8b8af878aa2ba1
+DIST conky-1.18.3.tar.gz 1710600 BLAKE2B 5664c504bab8ddda14e4442fce3c4bda70033b8b1efb0642901f154306adee300673756a776e304a151214fc9a3d7dd8277336ffd13305ff1d86c4d65819cfb4 SHA512 702932bad88265619cb6de60b2fe86e834e7828343f31e966df1838c6742d5da2998aab71704bb22e4b0bdc3d05e3c082c9ab6231124b310e8c14c89bd80ad52
 EBUILD conky-1.13.1.ebuild 4795 BLAKE2B daff0445b97281fcd8fd737b681b862fae0570c15bbdcd9dd25fbaf5db825e8b6e0eeba771b34d09329ca338e869d341cd83b3ace80f31b28ccc103d59a66829 SHA512 75bd14e46fb12acc2d31b933adcfccf3a25e0202c8a40238bc585c9275c875e145833ae5e9870a9d0697bcf2b04b1ae5bbbb680fcd3c023ca21350fd6ead6e7f
 EBUILD conky-1.17.0.ebuild 5305 BLAKE2B e8e3480f4c13c1eb939154ec9019bd66821d433719accf6bafc3763fb29b8bd8ce1e6ac656010959855f43e32977263a31da19185a6abf0a8b1f6545d9afbc65 SHA512 4ff429e7766ae867daf3a23e962996be1d85a53d8cd5110b9ce07c1245d856f06f981295660b86b23b2d23fc12cce648fdcc75fd370db1ff8b458c82b7ce2947
-EBUILD conky-1.18.1.ebuild 5443 BLAKE2B e90677a3ea0cb529aaf27a9bc29852129f88e940f4b0dbbccbfebe2694c2d5f4a61a062987ccb79a7c2d4ae2178fdb6d2f6427c240b5cb1124b4a4f932cd9eb3 SHA512 f40b45c43dede63420b63e2e53e623b319df66883dcf6424f986f38a9d6794969eaad3145a74454844025696437c728a979118ebb0a7441014c5d7a890487e39
+EBUILD conky-1.18.1.ebuild 5458 BLAKE2B 37661e86b290cfcc889f0da5bade56c886ae506daa423812d4148fc4ae3836105fbd0c78565d47c7db9bf110dea3015b6bcc2f18cf5908169b395f93169a9cf5 SHA512 44dc89ed780c179e33344ff3907c493614e162bb14305376e158a9a73c023147d94b72e2415595ce612f617e2db0cd2d874928d91f572efe51b1269728c9d21f
+EBUILD conky-1.18.3.ebuild 5446 BLAKE2B a8256a09de877bbcf176775ab65e7a6a9a87a70f3e7eb397a6646fc0dd18828aab778bf2b471c2b95400f9dcacd6e1bcd2ac44b2686351ecec78bce9ca344099 SHA512 b3ffb447b2dbf8de69e7b0a400b6541e41ff64beb237ca15a7493a8ae30c96daa1738166708d0872d202272e71a05edc8b809e218234b9f9c990a7eec012fb62
 MISC metadata.xml 2576 BLAKE2B 428d10d3666770317f470e6898d103180370866abdfcc55c81450c3df58a7c0eef5a2cf4d4980a36d22803479af7f10aaf3a4245041f729fefe26ccb0a29a516 SHA512 6db4ad92cf3d3afc81b7047c8f23d157d1efc6cf02aa5e4ab435c8785355445d6929e314fcadb007b2d084560c0f1afeff8889ff390852846fad8f52c29d8e48
diff --git a/app-admin/conky/conky-1.18.1.ebuild b/app-admin/conky/conky-1.18.1.ebuild
index 44dd8a64799f..f60c0ae116e7 100644
--- a/app-admin/conky/conky-1.18.1.ebuild
+++ b/app-admin/conky/conky-1.18.1.ebuild
@@ -38,7 +38,6 @@ COMMON_DEPEND="
 	truetype? ( x11-libs/libXft >=media-libs/freetype-2 )
 	wayland? (
 		dev-libs/wayland
-		dev-libs/wayland-protocols
 		x11-libs/pango
 	)
 	wifi? ( net-wireless/wireless-tools )
@@ -66,6 +65,9 @@ RDEPEND="
 "
 DEPEND="
 	${COMMON_DEPEND}
+	wayland? (
+		dev-libs/wayland-protocols
+	)
 "
 BDEPEND="
 	doc? (
diff --git a/app-admin/conky/conky-1.18.3.ebuild b/app-admin/conky/conky-1.18.3.ebuild
new file mode 100644
index 000000000000..ff1244c36105
--- /dev/null
+++ b/app-admin/conky/conky-1.18.3.ebuild
@@ -0,0 +1,224 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-4 )
+PYTHON_COMPAT=( python{3_9,3_10,3_11} )
+
+inherit cmake linux-info lua-single python-any-r1 readme.gentoo-r1 xdg
+
+DESCRIPTION="An advanced, highly configurable system monitor for X"
+HOMEPAGE="https://github.com/brndnmtthws/conky"
+SRC_URI="https://github.com/brndnmtthws/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3 BSD LGPL-2.1 MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="apcupsd bundled-toluapp cmus curl doc extras hddtemp ical iconv imlib
+	intel-backlight iostats irc lua-cairo lua-imlib lua-rsvg math moc mpd
+	mysql ncurses nvidia +portmon pulseaudio rss systemd thinkpad truetype
+	wayland webserver wifi X xinerama xmms2"
+
+COMMON_DEPEND="
+	curl? ( net-misc/curl )
+	ical? ( dev-libs/libical:= )
+	iconv? ( virtual/libiconv )
+	imlib? ( media-libs/imlib2[X] )
+	irc? ( net-libs/libircclient )
+	lua-cairo? ( x11-libs/cairo[X] )
+	lua-imlib? ( media-libs/imlib2[X] )
+	lua-rsvg? ( gnome-base/librsvg )
+	mysql? ( dev-db/mysql-connector-c )
+	ncurses? ( sys-libs/ncurses:= )
+	nvidia? ( x11-drivers/nvidia-drivers[tools,static-libs] )
+	pulseaudio? ( media-libs/libpulse )
+	rss? ( dev-libs/libxml2 net-misc/curl dev-libs/glib:2 )
+	systemd? ( sys-apps/systemd )
+	truetype? ( x11-libs/libXft >=media-libs/freetype-2 )
+	wayland? (
+		dev-libs/wayland
+		x11-libs/pango
+	)
+	wifi? ( net-wireless/wireless-tools )
+	webserver? ( net-libs/libmicrohttpd )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXdamage
+		x11-libs/libXfixes
+		x11-libs/libXext
+	)
+	xinerama? ( x11-libs/libXinerama )
+	xmms2? ( media-sound/xmms2 )
+	${LUA_DEPS}
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	apcupsd? ( sys-power/apcupsd )
+	cmus? ( media-sound/cmus )
+	hddtemp? ( app-admin/hddtemp )
+	moc? ( media-sound/moc )
+	extras? (
+		app-editors/nano
+		|| ( app-editors/vim app-editors/gvim )
+		)
+"
+DEPEND="
+	${COMMON_DEPEND}
+	wayland? (
+		dev-libs/wayland-protocols
+	)
+"
+BDEPEND="
+	doc? (
+		virtual/pandoc
+		$(python_gen_any_dep '
+			dev-python/pyyaml[${PYTHON_USEDEP}]
+			dev-python/jinja[${PYTHON_USEDEP}]
+		')
+	)
+	extras? (
+		$(python_gen_any_dep '
+			dev-python/pyyaml[${PYTHON_USEDEP}]
+			dev-python/jinja[${PYTHON_USEDEP}]
+		')
+	)
+	wayland? ( dev-util/wayland-scanner )
+"
+
+python_check_deps() {
+	use doc || use extras || return 0
+	python_has_version -b "dev-python/pyyaml[${PYTHON_USEDEP}]" &&
+	python_has_version -b "dev-python/jinja[${PYTHON_USEDEP}]"
+}
+
+REQUIRED_USE="
+	imlib? ( X )
+	lua-cairo? ( X  bundled-toluapp )
+	lua-imlib? ( X  bundled-toluapp )
+	lua-rsvg? ( X  bundled-toluapp )
+	nvidia? ( X )
+	truetype? ( X )
+	xinerama? ( X )
+"
+
+CONFIG_CHECK="~IPV6"
+
+DOCS=( README.md AUTHORS )
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="You can find sample configurations at ${ROOT}/usr/share/doc/${PF}.
+To customize, copy to \${XDG_CONFIG_HOME}/conky/conky.conf and edit it to your liking.
+
+There are pretty html docs available at https://conky.cc/.
+
+Also see https://github.com/brndnmtthws/conky/wiki or https://wiki.gentoo.org/wiki/Conky"
+
+pkg_setup() {
+	linux-info_pkg_setup
+	lua-single_pkg_setup
+	if use doc || use extras; then
+		python-any-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	# pin lua 5.4
+	sed -i -e 's|Lua "5.3" REQUIRED|Lua "5.4" EXACT|g' \
+		cmake/ConkyPlatformChecks.cmake || die "ConkyPlatformChecks.cmake"
+
+	cmake_src_prepare
+	xdg_environment_reset
+}
+
+src_configure() {
+	local mycmakeargs=()
+
+	if use X; then
+		mycmakeargs+=(
+			-DBUILD_ARGB=yes
+			-DBUILD_X11=yes
+			-DBUILD_XDAMAGE=yes
+			-DBUILD_XDBE=yes
+			-DBUILD_XSHAPE=yes
+			-DBUILD_MOUSE_EVENTS=yes
+			-DOWN_WINDOW=yes
+		)
+	else
+		mycmakeargs+=(
+			-DBUILD_X11=no
+		)
+	fi
+
+	mycmakeargs+=(
+		-DBUILD_APCUPSD=$(usex apcupsd)
+		-DBUILD_AUDACIOUS=no
+		-DBUILD_BUILTIN_CONFIG=yes
+		-DBUILD_CMUS=$(usex cmus)
+		-DBUILD_CURL=$(usex curl)
+		-DBUILD_DOCS=$(usex doc)
+		-DBUILD_EXTRAS=$(usex extras)
+		-DBUILD_HDDTEMP=$(usex hddtemp)
+		-DBUILD_HTTP=$(usex webserver)
+		-DBUILD_I18N=yes
+		-DBUILD_IBM=$(usex thinkpad)
+		-DBUILD_ICAL=$(usex ical)
+		-DBUILD_ICONV=$(usex iconv)
+		-DBUILD_IMLIB2=$(usex imlib)
+		-DBUILD_INTEL_BACKLIGHT=$(usex intel-backlight)
+		-DBUILD_IOSTATS=$(usex iostats)
+		-DBUILD_IPV6=yes
+		-DBUILD_IRC=$(usex irc)
+		-DBUILD_JOURNAL=$(usex systemd)
+		-DBUILD_LUA_CAIRO=$(usex lua-cairo)
+		-DBUILD_LUA_IMLIB2=$(usex lua-imlib)
+		-DBUILD_LUA_RSVG=$(usex lua-rsvg)
+		-DBUILD_MATH=$(usex math)
+		-DBUILD_MOC=$(usex moc)
+		-DBUILD_MPD=$(usex mpd)
+		-DBUILD_MYSQL=$(usex mysql)
+		-DBUILD_NCURSES=$(usex ncurses)
+		-DBUILD_NVIDIA=$(usex nvidia)
+		-DBUILD_OLD_CONFIG=yes
+		-DBUILD_PORT_MONITORS=$(usex portmon)
+		-DBUILD_PULSEAUDIO=$(usex pulseaudio)
+		-DBUILD_RSS=$(usex rss)
+		-DBUILD_WAYLAND=$(usex wayland)
+		-DBUILD_WLAN=$(usex wifi)
+		-DBUILD_XFT=$(usex truetype)
+		-DBUILD_XINERAMA=$(usex xinerama)
+		-DBUILD_XMMS2=$(usex xmms2)
+		-DDOC_PATH=/usr/share/doc/${PF}
+		-DMAINTAINER_MODE=no
+		-DRELEASE=yes
+	)
+
+	if use doc || use extras; then
+		mycmakeargs+=( -DPython3_EXECUTABLE="${PYTHON}" )
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use extras; then
+		insinto /usr/share/vim/vimfiles/ftdetect
+		doins "${S}"/extras/vim/ftdetect/conkyrc.vim
+
+		insinto /usr/share/vim/vimfiles/syntax
+		doins "${BUILD_DIR}"/extras/vim/syntax/conkyrc.vim
+
+		insinto /usr/share/nano/
+		doins "${BUILD_DIR}"/extras/nano/conky.nanorc
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	xdg_pkg_postinst
+}