gentoo auto-resync : 16:12:2023 - 14:53:46

3 files changed, 289 insertions, 0 deletions

diff --git a/app-admin/Manifest.gz b/app-admin/Manifest.gz
index 4941bab76a7b..0a8013aaca3a 100644
--- a/app-admin/Manifest.gz
+++ b/app-admin/Manifest.gz
diff --git a/app-admin/sudo/Manifest b/app-admin/sudo/Manifest
index 36119f4b5244..2a90f1fa1754 100644
--- a/app-admin/sudo/Manifest
+++ b/app-admin/sudo/Manifest
@@ -4,8 +4,11 @@ DIST sudo-1.9.15p2.tar.gz 5303642 BLAKE2B 002f820d6d82b3384a9206545a999765c2924b
 DIST sudo-1.9.15p2.tar.gz.sig 566 BLAKE2B e526f608c11abdf2e762dd273106e5934273a42596f00afaa64826f6f56714ff8186f7e1d9233b56cae8d2aed657565f87c976437727880f674e2ef42f93560a SHA512 1b0692a19966e3a2db82d064a17312bfcab454bc9eba0e9fe7ce3dcee0507704767655c30443cb87e0b7d2015317fd38d990ccf66cd18bb47fdf6e43494d6d8e
 DIST sudo-1.9.15p3.tar.gz 5305025 BLAKE2B 4d0bd14d2b1d3921609b6babfdf1df82fd849ca00db2dc6ebfa1716845240743c4213cdcc9a76cbdf1c7d41cbf425cd72774fb078cf24fdd8a688cfff56aa67a SHA512 1b1c24d67e089564b50090e586c1a03bcc01d6c8798c5383d34b244bb13b06e134e189ea1bef37f750108e064bd569cb4d2ccdc7409573ef20eb2768c716b618
 DIST sudo-1.9.15p3.tar.gz.sig 566 BLAKE2B cee15a95657ff560373b8827cdf06210866ae1cac82ba95831d89b27822149daf308023f74eb52e02ed68c0c16e81c65724986232fcc83550623814f9189e315 SHA512 9b18da7d840123f738731d9482b0816c00b055edcc690920eab8e382465b7f8fbcb60fb01316ddb6a1c5867de8668ed94199806707038f1171d656e0ddc39394
+DIST sudo-1.9.15p4.tar.gz 5304804 BLAKE2B 011d8ee099bfc16cff141dabffd0ce2befa7fdc834108759e9fdc3c2c11c3bca02eb0c410915394b1b3e3725fbb08544f98ffa584299dbce0db2b49234c0550a SHA512 db7e2270a7303b60ecd782605c24c4b4ba6478a145a5eed1084af6202ad30c0c93725b6690ae46ff484efcfa34437991a40d7d5699fdb84af1e4c5a2aa99194f
+DIST sudo-1.9.15p4.tar.gz.sig 566 BLAKE2B 79ac7e75a3d6d9bc4559611bc98a1fcdc4e34472dc16942ec9cf9c4614d8bdace5ff16689ed067b139a40d3d01cc6c1794d9e511afe4a75c8b50401e158d4a72 SHA512 1ec52c8f2a0e50a0cfa622ce58fcbb68f05d93972d84cc08733eb88b66914022b211e740eef3a44452e0a30f498563573c8d96a6422b1211c9c8f50e58837195
 EBUILD sudo-1.9.14_p3.ebuild 7386 BLAKE2B 28a263886399e55e1e970a96127e43ec85db93d4bbd8e24e12c7d80f673f5ce5548882de352b62f3a293ccf2f645d39a5b065bf9dd1a35d149968a42f9a9f98e SHA512 dc41bfc198822d3c483bac38a1ce62fd9be0c331537966b9e4bd7aca4409d1a899e5aaafd2ea2815ab785fa29961e4c4347b287e5cb0015653a4d00c0b455303
 EBUILD sudo-1.9.15_p2.ebuild 7388 BLAKE2B 15a00f1d3226ab6ae18bfc54ac62b9c38913e9a0cb420399872f56aeb0819cdd198919925ace64d30cf598b5ede83a897828478da2ac87a51d29785df98b28a7 SHA512 ef9224834b89afa825b02912472b86b8352c96120be05e8f50b3ad8706c6613af4f33f02852de4675f857c456858282662a2d50700461abb1d33c5db55af4636
 EBUILD sudo-1.9.15_p3.ebuild 7394 BLAKE2B 782703a4378833156c286923c48b8380c8bca5bf534f02abd82406790dbaa3c72be88b2d50d6c8b0f650639f66f83e03a290f1d7d0f9962fb0dfb8003ca7cd05 SHA512 c67aab68415495e4b3d45fd356c77b83a1769425d829aa0601e9068629fd835fc65889f98d017312963ad53058407d4835942ef042cf46c970f6c2213e624bc2
+EBUILD sudo-1.9.15_p4.ebuild 7394 BLAKE2B 782703a4378833156c286923c48b8380c8bca5bf534f02abd82406790dbaa3c72be88b2d50d6c8b0f650639f66f83e03a290f1d7d0f9962fb0dfb8003ca7cd05 SHA512 c67aab68415495e4b3d45fd356c77b83a1769425d829aa0601e9068629fd835fc65889f98d017312963ad53058407d4835942ef042cf46c970f6c2213e624bc2
 EBUILD sudo-9999.ebuild 7394 BLAKE2B 782703a4378833156c286923c48b8380c8bca5bf534f02abd82406790dbaa3c72be88b2d50d6c8b0f650639f66f83e03a290f1d7d0f9962fb0dfb8003ca7cd05 SHA512 c67aab68415495e4b3d45fd356c77b83a1769425d829aa0601e9068629fd835fc65889f98d017312963ad53058407d4835942ef042cf46c970f6c2213e624bc2
 MISC metadata.xml 1107 BLAKE2B a18b1d280445ea98ba686021abf08ab47a5ac590795018c125008f2a8e44f7ea45e256e32a737781030960cb984bc16d8fd23175fd1e88b294e5036c86085367 SHA512 8cacbd9a1a23fc7734c5ad8b95c769b8506ec35490b5e3f69439bf71bd51d1eaf04fe699a82cbb3ac56182195fff570d75e3b20c33d86774480a2939122752a6
diff --git a/app-admin/sudo/sudo-1.9.15_p4.ebuild b/app-admin/sudo/sudo-1.9.15_p4.ebuild
new file mode 100644
index 000000000000..fa89a2f25d3d
--- /dev/null
+++ b/app-admin/sudo/sudo-1.9.15_p4.ebuild
@@ -0,0 +1,286 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit pam libtool tmpfiles toolchain-funcs
+
+MY_P="${P/_/}"
+MY_P="${MY_P/beta/b}"
+
+DESCRIPTION="Allows users or groups to run commands as other users"
+HOMEPAGE="https://www.sudo.ws/"
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit mercurial
+	EHG_REPO_URI="https://www.sudo.ws/repos/sudo"
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/sudo.ws.asc
+	inherit verify-sig
+
+	uri_prefix=
+	case ${P} in
+		*_beta*|*_rc*) uri_prefix=beta/ ;;
+	esac
+
+	SRC_URI="
+		https://www.sudo.ws/sudo/dist/${uri_prefix}${MY_P}.tar.gz
+		ftp://ftp.sudo.ws/pub/sudo/${uri_prefix}${MY_P}.tar.gz
+		verify-sig? (
+			https://www.sudo.ws/sudo/dist/${uri_prefix}${MY_P}.tar.gz.sig
+			ftp://ftp.sudo.ws/pub/sudo/${uri_prefix}${MY_P}.tar.gz.sig
+		)
+	"
+
+	if [[ ${PV} != *_beta* && ${PV} != *_rc* ]] ; then
+		KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+	fi
+
+	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-sudo )"
+fi
+
+S="${WORKDIR}/${MY_P}"
+
+# Basic license is ISC-style as-is, some files are released under
+# 3-clause BSD license
+LICENSE="ISC BSD"
+SLOT="0"
+IUSE="gcrypt ldap nls offensive pam sasl +secure-path selinux +sendmail skey ssl sssd"
+
+DEPEND="
+	sys-libs/zlib:=
+	virtual/libcrypt:=
+	gcrypt? ( dev-libs/libgcrypt:= )
+	ldap? (
+		>=net-nds/openldap-2.1.30-r1:=
+		sasl? (
+			dev-libs/cyrus-sasl
+			net-nds/openldap:=[sasl]
+		)
+	)
+	pam? ( sys-libs/pam )
+	sasl? ( dev-libs/cyrus-sasl )
+	selinux? ( sys-libs/libselinux )
+	skey? ( >=sys-auth/skey-1.1.5-r1 )
+	ssl? ( dev-libs/openssl:= )
+	sssd? ( sys-auth/sssd[sudo] )
+"
+RDEPEND="
+	${DEPEND}
+	>=app-misc/editor-wrapper-3
+	virtual/editor
+	ldap? ( dev-lang/perl )
+	pam? ( sys-auth/pambase )
+	selinux? ( sec-policy/selinux-sudo )
+	sendmail? ( virtual/mta )
+"
+BDEPEND+="
+	sys-devel/bison
+	virtual/pkgconfig
+"
+
+REQUIRED_USE="
+	?? ( pam skey )
+	?? ( gcrypt ssl )
+"
+
+MAKEOPTS+=" SAMPLES="
+
+src_prepare() {
+	default
+
+	elibtoolize
+}
+
+set_secure_path() {
+	# First extract the default ROOTPATH from build env
+	SECURE_PATH=$(unset ROOTPATH; . "${EPREFIX}"/etc/profile.env; echo "${ROOTPATH}")
+
+	case "${SECURE_PATH}" in
+		*/usr/sbin*)
+			;;
+		*)
+			SECURE_PATH=$(unset PATH; . "${EPREFIX}"/etc/profile.env; echo "${PATH}")
+			;;
+	esac
+
+	if [[ -z ${SECURE_PATH} ]] ; then
+		ewarn "	Failed to detect SECURE_PATH, please report this"
+	fi
+
+	# Then remove duplicate path entries
+	cleanpath() {
+		local newpath thisp IFS=:
+		for thisp in $1 ; do
+			if [[ :${newpath}: != *:${thisp}:* ]] ; then
+				newpath+=:${thisp}
+			else
+				einfo "   Duplicate entry ${thisp} removed..."
+			fi
+		done
+		SECURE_PATH=${newpath#:}
+	}
+	cleanpath /usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin:/opt/bin${SECURE_PATH:+:${SECURE_PATH}}
+
+	# Finally, strip gcc paths, bug #136027
+	rmpath() {
+		local e newpath thisp IFS=:
+		for thisp in ${SECURE_PATH} ; do
+			for e ; do
+				[[ ${thisp} == ${e} ]] && continue 2 ;
+			done
+			newpath+=:${thisp}
+		done
+		SECURE_PATH=${newpath#:}
+	}
+	rmpath '*/gcc-bin/*' '*/gnat-gcc-bin/*' '*/gnat-gcc/*'
+}
+
+src_configure() {
+	local SECURE_PATH
+
+	set_secure_path
+
+	# bug #767712
+	tc-export PKG_CONFIG
+
+	# - audit: somebody got to explain me how I can test this before I
+	# enable it.. - Diego
+	# - plugindir: autoconf code is crappy and does not delay evaluation
+	# until `make` time, so we have to use a full path here rather than
+	# basing off other values.
+	local myeconfargs=(
+		# We set all of the relevant options by ourselves (patched
+		# into the toolchain) and setting these in the build system
+		# actually causes a downgrade when using e.g. -D_FORTIFY_SOURCE=3
+		# (it'll downgrade to =2). So, this has no functional effect on
+		# the hardening for users. It's safe.
+		--disable-hardening
+
+		# requires some python eclass
+		--disable-python
+		--enable-tmpfiles.d="${EPREFIX}"/usr/lib/tmpfiles.d
+		--enable-zlib=system
+		--with-editor="${EPREFIX}"/usr/libexec/editor
+		--with-env-editor
+		--with-plugindir="${EPREFIX}"/usr/$(get_libdir)/sudo
+		--with-rundir="${EPREFIX}"/run/sudo
+		--with-vardir="${EPREFIX}"/var/db/sudo
+		--without-linux-audit
+		--without-opie
+		$(use_enable gcrypt)
+		$(use_enable nls)
+		$(use_enable sasl)
+		$(use_enable ssl openssl)
+		$(use_with ldap)
+		$(use_with ldap ldap_conf_file /etc/ldap.conf.sudo)
+		$(use_with offensive insults)
+		$(use_with offensive all-insults)
+		$(use_with pam)
+		$(use_with pam pam-login)
+		$(use_with secure-path secure-path "${SECURE_PATH}")
+		$(use_with selinux)
+		$(use_with sendmail)
+		$(use_with skey)
+		$(use_with sssd)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if use ldap ; then
+		dodoc README.LDAP.md
+
+		cat <<-EOF > "${T}"/ldap.conf.sudo
+		# See ldap.conf(5) and README.LDAP.md for details
+		# This file should only be readable by root
+
+		# supported directives: host, port, ssl, ldap_version
+		# uri, binddn, bindpw, sudoers_base, sudoers_debug
+		# tls_{checkpeer,cacertfile,cacertdir,randfile,ciphers,cert,key}
+		EOF
+
+		if use sasl ; then
+			cat <<-EOF >> "${T}"/ldap.conf.sudo
+
+			# SASL directives: use_sasl, sasl_mech, sasl_auth_id
+			# sasl_secprops, rootuse_sasl, rootsasl_auth_id, krb5_ccname
+			EOF
+		fi
+
+		insinto /etc
+		doins "${T}"/ldap.conf.sudo
+		fperms 0440 /etc/ldap.conf.sudo
+
+		insinto /etc/openldap/schema
+		newins docs/schema.OpenLDAP sudo.schema
+	fi
+
+	if use pam ; then
+		pamd_mimic system-auth sudo auth account session
+		pamd_mimic system-auth sudo-i auth account session
+	fi
+
+	keepdir /var/db/sudo/lectured
+	fperms 0700 /var/db/sudo/lectured
+	# bug #652958
+	fperms 0711 /var/db/sudo
+
+	# Don't install into /run as that is a tmpfs most of the time
+	# (bug #504854)
+	rm -rf "${ED}"/run || die
+
+	# bug #697812
+	find "${ED}" -type f -name "*.la" -delete || die
+}
+
+pkg_postinst() {
+	tmpfiles_process sudo.conf
+
+	# bug #652958
+	local sudo_db="${EROOT}/var/db/sudo"
+	if [[ "$(stat -c %a "${sudo_db}")" -ne 711 ]] ; then
+		chmod 711 "${sudo_db}" || die
+	fi
+
+	if use ldap ; then
+		ewarn
+		ewarn "sudo uses the ${ROOT}/etc/ldap.conf.sudo file for ldap configuration."
+		ewarn
+		if grep -qs '^[[:space:]]*sudoers:' "${ROOT}"/etc/nsswitch.conf ; then
+			ewarn "In 1.7 series, LDAP is no more consulted, unless explicitly"
+			ewarn "configured in ${ROOT}/etc/nsswitch.conf."
+			ewarn
+			ewarn "To make use of LDAP, add this line to your ${ROOT}/etc/nsswitch.conf:"
+			ewarn "  sudoers: ldap files"
+			ewarn
+		fi
+	fi
+	if use prefix ; then
+		ewarn
+		ewarn "To use sudo on Prefix, you need to change file ownership and permissions"
+		ewarn "with root privileges, as follows:"
+		ewarn
+		ewarn "  # chown root:root ${EPREFIX}/usr/bin/sudo"
+		ewarn "  # chown root:root ${EPREFIX}/usr/lib/sudo/sudoers.so"
+		ewarn "  # chown root:root ${EPREFIX}/etc/sudoers"
+		ewarn "  # chown root:root ${EPREFIX}/etc/sudoers.d"
+		ewarn "  # chown root:root ${EPREFIX}/var/db/sudo"
+		ewarn "  # chmod 4111 ${EPREFIX}/usr/bin/sudo"
+		ewarn
+	fi
+
+	elog "To use the -A (askpass) option, you need to install a compatible"
+	elog "password program from the following list. Starred packages will"
+	elog "automatically register for the use with sudo (but will not force"
+	elog "the -A option):"
+	elog ""
+	elog " [*] net-misc/ssh-askpass-fullscreen"
+	elog "     net-misc/x11-ssh-askpass"
+	elog ""
+	elog "You can override the choice by setting the SUDO_ASKPASS environmnent"
+	elog "variable to the program you want to use."
+}