gentoo auto-resync : 09:12:2023 - 05:13:51

1 files changed, 53 insertions, 0 deletions

diff --git a/app-backup/borgbackup/borgbackup-1.2.7.ebuild b/app-backup/borgbackup/borgbackup-1.2.7.ebuild
new file mode 100644
index 000000000000..f941a77dae56
--- /dev/null
+++ b/app-backup/borgbackup/borgbackup-1.2.7.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit bash-completion-r1 distutils-r1 pypi
+
+DESCRIPTION="Deduplicating backup program with compression and authenticated encryption"
+HOMEPAGE="https://borgbackup.readthedocs.io/"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+# "import file mismatch" when in S, "attempted relative import with no
+# known parent package" when in BUILD_DIR/install/.../borg/testsuite.
+# Needs work.
+RESTRICT="test"
+
+DEPEND="app-arch/lz4
+	app-arch/zstd
+	dev-libs/openssl:0=
+	>=dev-libs/xxhash-0.8.1
+	virtual/acl"
+# borgbackup is *very* picky about which msgpack it work with,
+# check setup.py on bumps.
+RDEPEND="${DEPEND}
+	~dev-python/msgpack-1.0.7[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pyfuse3[${PYTHON_USEDEP}]"
+
+BDEPEND="dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+src_install() {
+	distutils-r1_src_install
+	doman docs/man/*
+
+	dobashcomp scripts/shell_completions/bash/borg
+
+	insinto /usr/share/zsh/site-functions
+	doins scripts/shell_completions/zsh/_borg
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins scripts/shell_completions/fish/borg.fish
+}