gentoo auto-resync : 27:01:2024 - 12:56:47

2 files changed, 0 insertions, 304 deletions

diff --git a/app-cdr/cdrtools/Manifest b/app-cdr/cdrtools/Manifest
index 64159598e9ff..27ecd340f6e7 100644
--- a/app-cdr/cdrtools/Manifest
+++ b/app-cdr/cdrtools/Manifest
@@ -1,5 +1,4 @@
 DIST cdrtools-3.02a09.tar.bz2 2156745 BLAKE2B 3e7a7ed65faffc67d53df8dff78562dd28f2e71bb01c36f9c57c033a4a812e6a5579a212322a15c8abb5c8005d38e6e9ba5a5bfab46d9a729a673aa8ce3425e7 SHA512 59c31186f163c7aaa96083efeb0bc31e697c5d53d3343ec487eddd90dc8df6cfee50a69859a64a7004585c73a081cc453cc647c563b32ef74070d075039342d4
 EBUILD cdrtools-3.02_alpha09-r3.ebuild 8147 BLAKE2B 71ed8d1208439b18d98690015095b7da8fc2f5b146a42353e292561c8603453eca738aa77b81c4a367554c2c1d4c81b7480c7fe258ac90ff52bf5ee829b438c4 SHA512 2c22f53c3dd997836350788eec396f90abe04bb6ce77397488fc2256d2ec83f33391575a88c4e9b81daa47f9df493bcd5718c15a6fd03b13af0ffa2b493faa51
-EBUILD cdrtools-3.02_alpha09-r4.ebuild 8978 BLAKE2B 8cd3771a41b785e1d9197c5ac2c311bf763d963d1aa2dffffab215e91eaf3e3cceb341bf452a84e99fe26cacd504c618d8603c515fcd0f1f64968b189bb156e9 SHA512 7e4261758b4710c85032397364b0066d8842b932f4faff6de655ad43b08575b6a48c18565e466ed34abbf94a7a122a23526405f8c3845368a604c8752d15d6c2
 EBUILD cdrtools-3.02_alpha09-r5.ebuild 9159 BLAKE2B 79a1da420177854fe22972b8a56dc162cd3b492c998144ed486482af1df948c4122b8d1e38ab9833be59c04d63003006ccba795ded28360a81563d5b6dc957fe SHA512 912b3df17ad0eff70705b8b18a41f9b5016510abe3d94b70c1576d0af8c0d039883cbc625c2dcdb3eae8a24fdc5d28a3031b611cba3e4601f6953e82ecc1142d
 MISC metadata.xml 445 BLAKE2B 43f12bca87633d1b039beed2fb401b652eafb937afc8a27d9d84885d306636bc29978beb17426dc782cb7c2e7ba9333b9346b6455fa72db2b778800f39995476 SHA512 c552eae00d8560d482fcb02799f064f5481e67ec12107760c841620db2d3023826377e186f5dc1b3555eea9b40964b4c7020b1deb82574ff1ff3ad7fd957bde9
diff --git a/app-cdr/cdrtools/cdrtools-3.02_alpha09-r4.ebuild b/app-cdr/cdrtools/cdrtools-3.02_alpha09-r4.ebuild
deleted file mode 100644
index a5ba82f4c1d3..000000000000
--- a/app-cdr/cdrtools/cdrtools-3.02_alpha09-r4.ebuild
+++ /dev/null
@@ -1,303 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit fcaps toolchain-funcs flag-o-matic gnuconfig
-
-MY_P="${P/_alpha/a}"
-
-DESCRIPTION="A set of tools for CD/DVD reading and recording, including cdrecord"
-HOMEPAGE="https://sourceforge.net/projects/cdrtools/"
-SRC_URI="mirror://sourceforge/${PN}/$([[ -z ${PV/*_alpha*} ]] && echo 'alpha')/${MY_P}.tar.bz2"
-
-LICENSE="GPL-2 LGPL-2.1 CDDL-Schily"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
-IUSE="acl caps nls unicode selinux"
-
-BDEPEND="
-	nls? ( >=sys-devel/gettext-0.18.1.1 )
-	x11-misc/makedepend
-"
-RDEPEND="
-	acl? ( virtual/acl )
-	caps? ( sys-libs/libcap )
-	nls? ( virtual/libintl )
-	selinux? ( sec-policy/selinux-cdrecord )
-"
-DEPEND="
-	${RDEPEND}
-"
-
-S=${WORKDIR}/${P/_alpha[0-9][0-9]}
-
-FILECAPS=(
-	cap_sys_resource,cap_dac_override,cap_sys_admin,cap_sys_nice,cap_net_bind_service,cap_ipc_lock,cap_sys_rawio+ep usr/bin/cdrecord --
-	cap_dac_override,cap_sys_admin,cap_sys_nice,cap_net_bind_service,cap_sys_rawio+ep usr/bin/cdda2wav --
-	cap_dac_override,cap_sys_admin,cap_net_bind_service,cap_sys_rawio+ep usr/bin/readcd
-)
-
-cdrtools_os() {
-	local os="linux"
-	[[ ${CHOST} == *-darwin* ]] && os="mac-os10"
-	echo "${os}"
-}
-
-symlink_build_rules() {
-	local cputype="$1"
-	pushd "${S}"/RULES > /dev/null || die
-	ln -sf i586-linux-cc.rul       "${cputype}"-linux-cc.rul      || die
-	ln -sf i586-linux-clang.rul    "${cputype}"-linux-clang.rul   || die
-	ln -sf i586-linux-clang32.rul  "${cputype}"-linux-clang32.rul || die
-	ln -sf i586-linux-clang64.rul  "${cputype}"-linux-clang64.rul || die
-	ln -sf i586-linux-gcc.rul      "${cputype}"-linux-gcc.rul     || die
-	ln -sf i586-linux-gcc32.rul    "${cputype}"-linux-gcc32.rul   || die
-	ln -sf i586-linux-gcc64.rul    "${cputype}"-linux-gcc64.rul   || die
-	popd > /dev/null || die
-}
-
-src_prepare() {
-	default
-
-	gnuconfig_update
-
-	# Remove profiled make files.
-	find -name '*_p.mk' -delete || die "delete *_p.mk"
-
-	# Adjusting hardcoded paths.
-	sed -i -e "s|opt/schily|usr|" \
-		$(find ./ -type f -name \*.[0-9ch] -exec grep -l 'opt/schily' '{}' '+') \
-		|| die "sed opt/schily"
-
-	sed -i -e "s|\(^INSDIR=\t\tshare/doc/\)|\1${PF}/|" \
-		$(find ./ -type f -exec grep -l '^INSDIR.\+doc' '{}' '+') \
-		|| die "sed doc"
-
-	# Respect libdir.
-	sed -i -e "s|\(^INSDIR=\t\t\)lib|\1$(get_libdir)|" \
-		$(find ./ -type f -exec grep -l '^INSDIR.\+lib\(/siconv\)\?$' '{}' '+') \
-		|| die "sed multilib"
-
-	# Do not install static libraries.
-	sed -i -e "s|include\t\t.*rules.lib||" \
-		$(find ./ -type f -exec grep -l '^include.\+rules\.lib' '{}' '+') \
-		|| die "sed rules"
-
-	# Don't quote $(MAKE)
-	sed -i -e 's|"$(MAKE)"|$(MAKE)|' \
-		$(find ./RULES -type f -exec grep -l '"$(MAKE)"' '{}' '+') \
-		|| die "sed RULES/"
-
-	# Enable verbose build.
-	sed -i -e '/@echo.*==>.*;/s:@echo[^;]*;:&set -x;:' \
-		RULES/*.rul RULES/rules.prg RULES/rules.inc \
-		|| die "sed verbose rules"
-
-	# Respect CC/CXX variables.
-	cd "${S}"/RULES || die
-	local tcCC="$(tc-getCC)"
-	local tcCXX="$(tc-getCXX)"
-
-	sed -i -e "/cc-config.sh/s|\$(C_ARCH:%64=%) \$(CCOM_DEF)|${tcCC} ${tcCC}|" \
-		rules1.top || die "sed rules1.top"
-	sed -i -e "/^CC_COM_DEF=/s|gcc|${tcCC}|" \
-		-e "/^CC++_COM_DEF=/s|g++|${tcCXX}|" \
-		-e "/COPTOPT=/s|-O||" \
-		-e 's|$(GCCOPTOPT)||' \
-		cc-gcc.rul || die "sed cc-gcc.rul"
-	sed -i -e "s|^#\(CONFFLAGS +=\).*|\1\t-cc=${tcCC}|" \
-		rules.cnf || die "sed rules.cnf"
-
-	# Add support for arm64
-	symlink_build_rules aarch64_be
-
-	# fix RISC-V build err, bug 811375
-	symlink_build_rules riscv
-	symlink_build_rules riscv64
-
-	# Add support for loong
-	symlink_build_rules loongarch64
-
-	# Schily make setup.
-	cd "${S}"/DEFAULTS || die
-	local os=$(cdrtools_os)
-
-	sed -i \
-		-e "s|^\(DEFLINKMODE=\).*|\1\tdynamic|" \
-		-e "s|^\(LINUX_INCL_PATH=\).*|\1|" \
-		-e "s|^\(LDPATH=\).*|\1|" \
-		-e "s|^\(RUNPATH=\).*|\1|" \
-		-e "s|^\(INS_BASE=\).*|\1\t${ED}/usr|" \
-		-e "s|^\(INS_RBASE=\).*|\1\t${ED}|" \
-		-e "s|^\(DEFINSGRP=\).*|\1\t0|" \
-		-e '/^DEFUMASK/s,002,022,g' \
-		Defaults.${os} || die "sed Schily make setup"
-	# re DEFUMASK above:
-	# bug 486680: grsec TPE will block the exec if the directory is
-	# group-writable. This is painful with cdrtools, because it makes a bunch of
-	# group-writable directories during build. Change the umask on their
-	# creation to prevent this.
-}
-
-ac_cv_sizeof() {
-	cat <<-EOF >"${T}"/test.c
-	#include <inttypes.h>
-	#include <stddef.h>
-	#include <stdint.h>
-	#include <sys/types.h>
-	int main () {
-		static int test_array [1 - 2 * !((sizeof(TYPE)) == LEN)];
-		test_array [0] = 0;
-		return test_array [0];
-	}
-	EOF
-
-	local i=1
-	while [[ ${i} -lt 20 ]] ; do
-		if ${CC} ${CPPFLAGS} ${CFLAGS} -c "${T}"/test.c -o /dev/null -DTYPE="$1" -DLEN=$i 2>/dev/null; then
-			echo ${i}
-			return 0
-		fi
-		: $(( i += 1 ))
-	done
-	return 1
-}
-
-src_configure() {
-	use acl || export ac_cv_header_sys_acl_h="no"
-	use caps || export ac_cv_lib_cap_cap_get_proc="no"
-	export ac_cv_header_pulse_pulseaudio_h="no"
-	export ac_cv_header_alsa_asoundlib_h="no"
-	export ac_cv_lib_asound_snd_pcm_open="no"
-
-	# skip obsolete configure script
-	if tc-is-cross-compiler ; then
-		# Cache known values for targets. #486680
-
-		tc-export CC
-		local var val t types=(
-			char "short int" int "long int" "long long"
-			"unsigned char" "unsigned short int" "unsigned int"
-			"unsigned long int" "unsigned long long"
-			float double "long double" size_t ssize_t ptrdiff_t
-			mode_t uid_t gid_t pid_t dev_t time_t wchar_t
-			"char *" "unsigned char *"
-		)
-		for t in "${types[@]}" ; do
-			var="ac_cv_sizeof_${t// /_}"
-			var=${var//[*]/p}
-			val=$(ac_cv_sizeof "${t}") || die "could not compute ${t}"
-			export "${var}=${val}"
-			einfo "Computing sizeof(${t}) as ${val}"
-		done
-		# We don't have these types.
-		export ac_cv_sizeof___int64=0
-		export ac_cv_sizeof_unsigned___int64=0
-		export ac_cv_sizeof_major_t=${ac_cv_sizeof_dev_t}
-		export ac_cv_sizeof_minor_t=${ac_cv_sizeof_dev_t}
-		export ac_cv_sizeof_wchar=${ac_cv_sizeof_wchar_t}
-
-		export ac_cv_type_prototypes="yes"
-		export ac_cv_func_mlock{,all}="yes"
-		export ac_cv_func_{e,f,g}cvt=$(usex elibc_glibc)
-		export ac_cv_func_dtoa_r="no"
-		export ac_cv_func_sys_siglist{,_def}="no"
-		export ac_cv_func_printf_{j,ll}="yes"
-		export ac_cv_realloc_null="yes"
-		export ac_cv_no_user_malloc="no"
-		export ac_cv_var_timezone="yes"
-		export ac_cv_var___progname{,_full}="yes"
-		export ac_cv_fnmatch_igncase="yes"
-		export ac_cv_file__dev_{fd_{0,1,2},null,std{err,in,out},tty,zero}="yes"
-		export ac_cv_file__usr_src_linux_include="no"
-
-		case $(cdrtools_os) in
-		linux)
-			export ac_cv_func_bsd_{g,s}etpgrp="no"
-			export ac_cv_hard_symlinks="yes"
-			export ac_cv_link_nofollow="yes"
-			export ac_cv_access_e_ok="no"
-
-			export ac_cv_dev_minor_noncontig="yes"
-			case ${ac_cv_sizeof_long_int} in
-			4) export ac_cv_dev_minor_bits="32";;
-			8) export ac_cv_dev_minor_bits="44";;
-			esac
-
-			cat <<-EOF >"${T}"/test.c
-			struct {
-				char start[6];
-				unsigned char x1:4;
-				unsigned char x2:4;
-				char end[5];
-			} a = {
-				.start = {'S', 't', 'A', 'r', 'T', '_'},
-				.x1 = 5,
-				.x2 = 4,
-				.end = {'_', 'e', 'N', 'd', 'X'},
-			};
-			EOF
-			${CC} ${CPPFLAGS} ${CFLAGS} -c "${T}"/test.c -o "${T}"/test.o
-			if grep -q 'StArT_E_eNdX' "${T}"/test.o ; then
-				export ac_cv_c_bitfields_htol="no"
-			elif grep -q 'StArT_T_eNdX' "${T}"/test.o ; then
-				export ac_cv_c_bitfields_htol="yes"
-			fi
-			;;
-		esac
-	fi
-}
-
-src_compile() {
-	if use unicode; then
-		local flags="$(test-flags -finput-charset=ISO-8859-1 -fexec-charset=UTF-8)"
-		if [[ -n ${flags} ]]; then
-			append-flags ${flags}
-		else
-			ewarn "Your compiler does not support the options required to build"
-			ewarn "cdrtools with unicode in USE. unicode flag will be ignored."
-		fi
-	fi
-
-	# If not built with -j1, "sometimes" cdda2wav will not be built.
-	emake -j1 CPPOPTX="${CPPFLAGS}" COPTX="${CFLAGS}" C++OPTX="${CXXFLAGS}" \
-		LDOPTX="${LDFLAGS}" GMAKE_NOWARN="true"
-}
-
-src_install() {
-	# If not built with -j1, "sometimes" manpages are not installed.
-	emake -j1 CPPOPTX="${CPPFLAGS}" COPTX="${CFLAGS}" C++OPTX="${CXXFLAGS}" \
-		LDOPTX="${LDFLAGS}" GMAKE_NOWARN="true" install
-
-	# These symlinks are for compat with cdrkit.
-	dosym schily /usr/include/scsilib
-	dosym ../scg /usr/include/schily/scg
-
-	dodoc ABOUT Changelog* CONTRIBUTING PORTING README.linux-shm READMEs/README.linux
-
-	cd "${S}"/cdda2wav || die
-	docinto cdda2wav
-	dodoc Changelog FAQ Frontends HOWTOUSE NEEDED README THANKS TODO
-
-	cd "${S}"/mkisofs || die
-	docinto mkisofs
-	dodoc ChangeLog* TODO
-
-	# Remove man pages related to the build system
-	rm -rvf "${ED}"/usr/share/man/man5 || die
-}
-
-pkg_postinst() {
-	fcaps_pkg_postinst
-
-	if [[ ${CHOST} == *-darwin* ]] ; then
-		einfo
-		einfo "Darwin/OS X use the following device names:"
-		einfo
-		einfo "CD burners: (probably) ./cdrecord dev=IOCompactDiscServices"
-		einfo
-		einfo "DVD burners: (probably) ./cdrecord dev=IODVDServices"
-		einfo
-	fi
-}