reinit the tree, so we can have metadata

3 files changed, 89 insertions, 0 deletions

diff --git a/app-crypt/gcr/Manifest b/app-crypt/gcr/Manifest
new file mode 100644
index 000000000000..6a3708bb33c6
--- /dev/null
+++ b/app-crypt/gcr/Manifest
@@ -0,0 +1,5 @@
+DIST gcr-3.20.0.tar.xz 1324216 SHA256 90572c626d8a708225560c42b4421f7941315247fa1679d4ef569bde7f4bb379 SHA512 0acd0fb085a38507b1cc895ac773f91c6f4e14d2ea7e27b8e74c85ef78426597b6ea08ebee696452b0651939ec4a0d8a4a2523c41b3a8a0bd1b0d7b338b1d9c7 WHIRLPOOL f9872c7c0f2480b868451775b5a7c63f7cba0d00702660417b738c6260706c8144bf73d36ddd0339b3acbfc010b4ceddef080a3dc1570de875b061e2053ba46f
+EBUILD gcr-3.20.0.ebuild 1862 SHA256 ee01fe7167201d6c6def0643e2f2949e759a54e8f65fb4894309964a19ebde36 SHA512 b66e96c94fa8a8d19f3c4fb26b5c3902a56baffd21fd883fb4971a88341ca2c62257db86679c3d2eaf054ea40ec284929adba5b174dc566471965e162d589713 WHIRLPOOL d1ed9c318bbe88335342f12b3a4c3f5740b399f23a65f9b5f7676568321ec54c436fabecdd9963926df607f3163aaeec5f1f88ddaf3a0cbcb44947ed68c3482c
+MISC ChangeLog 6905 SHA256 1bbb562085db923fe464f7a4804ba8e08073bb20c5e46f83f7dd34f2c59b68ee SHA512 647155bdef05a106218cd64911dee1592994c9f06e5203dc14987cba7f1eada11c7a5efcd6d983369a5fb18288556f22a2279c577a2c34eca662b60a4830777f WHIRLPOOL 9b5645daac029e22e208ba72c6410078d9d632a78610754e16a7b5223d23b0b8922bb506bb4320c2e90987bf3f0bc1a53828f4bcd38fb324d32e9929bfd36b31
+MISC ChangeLog-2015 7761 SHA256 ee08f4e34701a75188db4b766fc2cac926c786ae8606e83b2a3dd40faf2e45d3 SHA512 c3c262c149a64dd69391189ed59a4f8021c570b18d8e8b49e5b6d6c60e1fce723ac0c173b2dd0a210c877a446c41022f77cbeadabaa8aaad15deece69c8a6f3a WHIRLPOOL bfa2fd98ce20e97e97f462e1269f539c5b8aaa66c23f17d0a3cf19bacae0d3d45032f0972908337b6168badc20e9b09080aa89fe9d1197b4a97d1460a78d1b79
+MISC metadata.xml 249 SHA256 4505b0bfeadff287958620b7dc7b7209699065a8f17139a237a5dd409a726a97 SHA512 c40662134899a5c9f0369a1017806f35adf3280a0b3c91726f7a8ca6012a073a8b471583f5bfb6fe95faac1dcf607e8e2e43f8c91d48ec46f4a8824e2f551506 WHIRLPOOL 333a938ee1d2124595596c572697bf5ebad523a92ba12005cfb12e6bb6270881a94a911f0cc9c1cf2bb571559e8271e07dfd307dabe50058236dbe7103562b92
diff --git a/app-crypt/gcr/gcr-3.20.0.ebuild b/app-crypt/gcr/gcr-3.20.0.ebuild
new file mode 100644
index 000000000000..b5dec6d72c6a
--- /dev/null
+++ b/app-crypt/gcr/gcr-3.20.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://git.gnome.org/browse/gcr"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/1" # subslot = suffix of libgcr-3
+
+IUSE="debug gtk +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+COMMON_DEPEND="
+	>=app-crypt/p11-kit-0.19
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/libgcrypt-1.2.2:0=
+	>=dev-libs/libtasn1-1:=
+	>=sys-apps/dbus-1
+	gtk? ( >=x11-libs/gtk+-3.12:3[X,introspection?] )
+	introspection? ( >=dev-libs/gobject-introspection-1.34:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-base/gnome-keyring-3.3
+"
+# gcr was part of gnome-keyring until 3.3
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	dev-libs/gobject-introspection-common
+	dev-libs/libxslt
+	dev-libs/vala-common
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+# eautoreconf needs:
+#	dev-libs/gobject-introspection-common
+#	dev-libs/vala-common
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# Disable stupid flag changes
+	sed -e 's/CFLAGS="$CFLAGS -g"//' \
+		-e 's/CFLAGS="$CFLAGS -O0"//' \
+		-i configure.ac configure || die
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_with gtk) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(usex debug --enable-debug=yes --enable-debug=default) \
+		--disable-update-icon-cache \
+		--disable-update-mime
+}
+
+src_test() {
+	virtx emake check
+}
diff --git a/app-crypt/gcr/metadata.xml b/app-crypt/gcr/metadata.xml
new file mode 100644
index 000000000000..39980802b1da
--- /dev/null
+++ b/app-crypt/gcr/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>gnome@gentoo.org</email>
+	<name>Gentoo GNOME Desktop</name>
+</maintainer>
+</pkgmetadata>