gentoo resync : 16.06.2019

3 files changed, 191 insertions, 4 deletions

diff --git a/app-crypt/heimdal/Manifest b/app-crypt/heimdal/Manifest
index 5b19322c2393..a07cfd2f3040 100644
--- a/app-crypt/heimdal/Manifest
+++ b/app-crypt/heimdal/Manifest
@@ -14,6 +14,8 @@ AUX heimdal_tinfo.patch 711 BLAKE2B 730ef4b1ba79d80c7257d1bd04783584cf616b2e51d6
 AUX krb5.conf 424 BLAKE2B 49b8a0aab6e0dacb70b91e030bb5f2b8bdfe4253026f85e2c9d16bdf6f554c585572ed9d3835bed976c8953fc92d0f42270c6a0767e943ec5efa5b79f6f4cf89 SHA512 4dad6837344e30c6988355551b5b82bce748dad7aa7648204ba7852540ad3a546b5344926789d60e78d57ff20dff87b680b790dc8d86c8dec1008feb0d809e38
 DIST heimdal-7.5.0.tar.gz 10071281 BLAKE2B 917f5855248c333e5ec35bf992973d8b5fb84581b9c3bc8d42c328e5f878ce24c5596c5a1e3fbca786a71be04984068efbb817f7336135056d1feae38895758f SHA512 6d1ad77e795df786680b5e68e2bfefee27bd0207eab507295d7af7053135de9c9ebb517d2c0235bc3a7d50945e18044515f0d76c0899b6b74aa839f1f3e5b131
 DIST heimdal-7.6.0.tar.gz 10186832 BLAKE2B 456b495a3d0a196cf02d6042c6db72c772327545fbc84f7bb758f55f3fca025432bf319fc33e9e0b5fe5ca78b83aea9dc47d77bf1f5b69ae88f1286a22c41263 SHA512 3f7ce090cf8da91f19675a1d9f6bd65c83b3a847337739481506f09d74001cb44283b103ba684dac8a5f11ec48605b5476240c534f6fc36442fb874b73680200
+DIST heimdal-7.7.0.tar.gz 10189293 BLAKE2B db9cdd1861dc9214a7f76b3d8b9656cfc0bad11cb6eadffa4fa29ea7f9aabd4c3d1b628c510644ec9abe1b3bf27a413ccf8cd590d602c4a4ac54ba3deb4cedc4 SHA512 6660939b5a36ce36310721a08a089fb671d1e3d2e8ac74ea4775bfa5f8f772d32de805551456200fe96cc486c092c44beb84f5dd877008bc305490ee971bbf99
 EBUILD heimdal-7.5.0.ebuild 4334 BLAKE2B 33303601d32d3b2c6f54a3681012f854b6addc55b09c65e6d0cea74e8ac91c12de09624e37f3d4f9933c54dbe8de3cf7f258bb99d33d26a25a0c280288777b44 SHA512 6d40e8a30e74b95c918e7ee5bf10b3d017178bd4775bba707ff2dfc02d208c121426b66ebdbb50df09a96f4caa5c55b35f2e8d53cad9eac4f8ebf46b0f6de266
-EBUILD heimdal-7.6.0.ebuild 4576 BLAKE2B 1a4c611877289ef50e936fb206cf56eb808842378fcbf9a98807cc0997f69695ad6818ab19048e5c35e07d2296449aa474f7bee9a5f34dc50f354d10a545049a SHA512 63877dd267dbf0640a7ef3586200ce4094aa43fd514611f13d2412e93305f88d4cf9279aff0a1e5e0ec5ef0b07c594e9df9b3b11c14dfff4b449508ed5633d00
+EBUILD heimdal-7.6.0.ebuild 4544 BLAKE2B 075588a581df502f47515cf1652bf7570fc39388f73bf8ab3768050b478b1a71821eedfc05a17a178c5f69095dd5ce8316243e2f588ac9777908f8f5c52c6b09 SHA512 796c5e38057bba437fe2cc70b71de0346261005ce71cd7d18bf6bb0d6cb99e0d6775b64aa249ebdb2073fa1fca49021a50bcf0aacdff9cf4de9c7bc660425370
+EBUILD heimdal-7.7.0-r1.ebuild 4536 BLAKE2B 758d3177cccbfa83ad69239536b207a218fcbfd0c85f6a943ece3722534b4bdd34d6d0a95de4c04d95f3273198463424117999acbf38f8b7248b62afd8cead59 SHA512 8fde4dc3b338d67c998eafe5122138b49d5d188acdceff1c7455fc02ecd6806794592d9e0b97ca6587b0bfe96e4f7e63996c6d1c9c0e843d17729fe0da84ff0e
 MISC metadata.xml 722 BLAKE2B 9ec2bb074bf4932b0bb2f949eb3c33c8ed8b82305d6641a6954084120c658005cecc2cac57ad85a1df520f5bfd115deef57f80d874ba850d857a813b5a87c139 SHA512 5f3c28c222eb668e3c1d3b7fe24ae3622c82f94b6008a4c3458aa76afac9508d6e7f150de0f06e4845a5b0653ea04112fe0c2b421f199b5feb9ef771ab0b0b28
diff --git a/app-crypt/heimdal/heimdal-7.6.0.ebuild b/app-crypt/heimdal/heimdal-7.6.0.ebuild
index c3ee68bd68e4..9e6de52ac1f2 100644
--- a/app-crypt/heimdal/heimdal-7.6.0.ebuild
+++ b/app-crypt/heimdal/heimdal-7.6.0.ebuild
@@ -16,7 +16,7 @@ SRC_URI="https://github.com/${PN}/${PN}/releases/download/${P}/${P}.tar.gz"
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ~ppc ~ppc64 s390 ~sh ~sparc x86 ~amd64-fbsd"
-IUSE="afs +berkdb caps gdbm hdb-ldap ipv6 libressl +lmdb otp +pkinit selinux ssl static-libs test X"
+IUSE="afs +berkdb caps gdbm hdb-ldap ipv6 libressl +lmdb otp selinux ssl static-libs test X"
 
 CDEPEND="
 	ssl? (
@@ -96,12 +96,12 @@ multilib_src_configure() {
 		--with-sqlite3="${EPREFIX}"/usr
 		--libexecdir="${EPREFIX}"/usr/sbin
 		--enable-pthread-support
+		--enable-kx509
+		--enable-pk-init
 		$(use_enable afs afs-support)
 		$(use_enable gdbm ndbm-db)
 		$(use_enable lmdb mdb-db)
 		$(use_enable otp)
-		$(use_enable pkinit kx509)
-		$(use_enable pkinit pk-init)
 		$(use_enable static-libs static)
 		$(multilib_native_use_with caps capng)
 		$(multilib_native_use_with hdb-ldap openldap "${EPREFIX}"/usr)
diff --git a/app-crypt/heimdal/heimdal-7.7.0-r1.ebuild b/app-crypt/heimdal/heimdal-7.7.0-r1.ebuild
new file mode 100644
index 000000000000..6fe1ad2703ed
--- /dev/null
+++ b/app-crypt/heimdal/heimdal-7.7.0-r1.ebuild
@@ -0,0 +1,185 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+VIRTUALX_REQUIRED="manual"
+
+inherit autotools db-use multilib multilib-minimal python-any-r1 virtualx flag-o-matic
+
+MY_P="${P}"
+DESCRIPTION="Kerberos 5 implementation from KTH"
+HOMEPAGE="http://www.h5l.org/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${P}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd"
+IUSE="afs +berkdb caps gdbm hdb-ldap libressl +lmdb otp selinux ssl static-libs test X"
+
+CDEPEND="
+	ssl? (
+		!libressl? ( >=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}] )
+		libressl? ( dev-libs/libressl:=[${MULTILIB_USEDEP}] )
+	)
+	berkdb? ( >=sys-libs/db-4.8.30-r1:*[${MULTILIB_USEDEP}] )
+	gdbm? ( >=sys-libs/gdbm-1.10-r1:=[${MULTILIB_USEDEP}] )
+	lmdb? ( dev-db/lmdb )
+	caps? ( sys-libs/libcap-ng )
+	>=dev-db/sqlite-3.8.2[${MULTILIB_USEDEP}]
+	>=sys-libs/e2fsprogs-libs-1.42.9[${MULTILIB_USEDEP}]
+	sys-libs/ncurses:0=
+	>=sys-libs/readline-6.2_p5-r1:0=[${MULTILIB_USEDEP}]
+	afs? ( net-fs/openafs )
+	hdb-ldap? ( >=net-nds/openldap-2.3.0 )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXau
+		x11-libs/libXt
+	)
+	!!app-crypt/mit-krb5
+	!!app-crypt/mit-krb5-appl"
+
+DEPEND="${CDEPEND}
+	${PYTHON_DEPS}
+	dev-perl/JSON
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	>=sys-devel/autoconf-2.62
+	test? ( X? ( ${VIRTUALX_DEPEND} ) )"
+
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-kerberos )"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/krb5-types.h
+	/usr/include/cms_asn1.h
+	/usr/include/digest_asn1.h
+	/usr/include/hdb_asn1.h
+	/usr/include/krb5_asn1.h
+	/usr/include/pkcs12_asn1.h
+	/usr/include/pkinit_asn1.h
+	/usr/include/rfc2459_asn1.h
+)
+
+MULTILIB_CHOST_TOOLS=(
+	/usr/bin/krb5-config
+)
+
+PATCHES=(
+	"${FILESDIR}/heimdal_disable-check-iprop.patch"
+	"${FILESDIR}/heimdal_tinfo.patch"
+	"${FILESDIR}/heimdal_hcrypto.patch"
+	"${FILESDIR}/heimdal_build-headers-before-use.patch"
+	"${FILESDIR}/heimdal_fix-db60.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# QA
+	append-flags -fno-strict-aliasing
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-kcm
+		--disable-osfc2
+		--enable-shared
+		--with-libintl="${EPREFIX}"/usr
+		--with-readline="${EPREFIX}"/usr
+		--with-sqlite3="${EPREFIX}"/usr
+		--libexecdir="${EPREFIX}"/usr/sbin
+		--enable-pthread-support
+		--enable-kx509
+		--enable-pk-init
+		--with-ipv6
+		$(use_enable afs afs-support)
+		$(use_enable gdbm ndbm-db)
+		$(use_enable lmdb mdb-db)
+		$(use_enable otp)
+		$(use_enable static-libs static)
+		$(multilib_native_use_with caps capng)
+		$(multilib_native_use_with hdb-ldap openldap "${EPREFIX}"/usr)
+		$(use_with ssl openssl "${EPREFIX}"/usr)
+		$(multilib_native_use_with X x)
+	)
+	if use berkdb; then
+		myeconfargs+=(
+			--with-berkeley-db
+			--with-berkeley-db-include="$(db_includedir)"
+		)
+	else
+		myeconfargs+=(
+			--without-berkeley-db
+		)
+	fi
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_compile() {
+	if multilib_is_native_abi; then
+		emake
+	else
+		emake -C include
+		emake -C lib
+		emake -C kdc
+		emake -C tools
+		emake -C tests/plugin
+	fi
+}
+
+multilib_src_test() {
+	multilib_is_native_abi && emake -j1 check
+}
+
+multilib_src_install() {
+	if multilib_is_native_abi; then
+		INSTALL_CATPAGES="no" emake DESTDIR="${D}" install
+	else
+		emake -C include DESTDIR="${D}" install
+		emake -C lib DESTDIR="${D}" install
+		emake -C kdc DESTDIR="${D}" install
+		emake -C tools DESTDIR="${D}" install
+		emake -C tests/plugin DESTDIR="${D}" install
+	fi
+}
+
+multilib_src_install_all() {
+	dodoc ChangeLog* README NEWS TODO
+
+	# client rename
+	mv "${ED%/}"/usr/share/man/man1/{,k}su.1
+	mv "${ED%/}"/usr/bin/{,k}su
+
+	newinitd "${FILESDIR}"/heimdal-kdc.initd-r2 heimdal-kdc
+	newinitd "${FILESDIR}"/heimdal-kadmind.initd-r2 heimdal-kadmind
+	newinitd "${FILESDIR}"/heimdal-kpasswdd.initd-r2 heimdal-kpasswdd
+	newinitd "${FILESDIR}"/heimdal-kcm.initd-r1 heimdal-kcm
+
+	newconfd "${FILESDIR}"/heimdal-kdc.confd heimdal-kdc
+	newconfd "${FILESDIR}"/heimdal-kadmind.confd heimdal-kadmind
+	newconfd "${FILESDIR}"/heimdal-kpasswdd.confd heimdal-kpasswdd
+	newconfd "${FILESDIR}"/heimdal-kcm.confd heimdal-kcm
+
+	insinto /etc
+	newins "${S}"/krb5.conf krb5.conf.example
+
+	if use hdb-ldap; then
+		insinto /etc/openldap/schema
+		doins "${S}/lib/hdb/hdb.schema"
+	fi
+
+	if ! use static-libs ; then
+		find "${ED}" -name "*.la" -delete || die
+	fi
+
+	# default database dir
+	keepdir /var/heimdal
+}