gentoo auto-resync : 01:10:2022 - 19:11:24

4 files changed, 199 insertions, 0 deletions

diff --git a/app-crypt/Manifest.gz b/app-crypt/Manifest.gz
index 10fce955f373..58523c9e02cd 100644
--- a/app-crypt/Manifest.gz
+++ b/app-crypt/Manifest.gz
diff --git a/app-crypt/gcr/Manifest b/app-crypt/gcr/Manifest
index 3c8ccc655bb6..b4f999bbece2 100644
--- a/app-crypt/gcr/Manifest
+++ b/app-crypt/gcr/Manifest
@@ -3,6 +3,9 @@ AUX gcr-3.40.0-meson-0.61-build.patch 1634 BLAKE2B 99593b9614831a4a2a47ff4890d1f
 AUX gcr-3.41.0-Unbreak-build-without-systemd.patch 766 BLAKE2B 005ba225708f0a676be937e809511e7e478ec16610d1bf068ca9e01c210e3d2567e8a3cdbf513c51b3cff57ad0834526e22f17490432dd7c6fa80a16dec4351a SHA512 2192e3556fb134ebbf0bab7e23f6d3b12da601286532e8a5c8fa52d69ac31a1ec3d8e941ff4d5d91737001306aa594996de58449498b2c93d07f53dec83a8401
 DIST gcr-3.41.0.tar.xz 1039744 BLAKE2B c646a04168310051d5b582a9d2f7ab9da89eef095e856e56b8d730600debead051ad8bb40eddb7457b1be2be3e092227dd886f647258a9c6a81d4bab728245f7 SHA512 455acc40ed77feeb35f9845b00229f468b322b7eda0b1b5abb0153f0a6ba29f3d0364df22225143f4caf130254a1258b3c7f934370e5142f2f64e1c3084b6f6e
 DIST gcr-3.41.1.tar.xz 1030368 BLAKE2B 9d254b7f2ad864c45200e58b685db97c1ffbc83d29ba8cbda94d30ec565aa3dc5a2535305dc63b3264131b68ec9e48f37ac30d5ba08d0ce156f3b6091cd62dc1 SHA512 dd70d41636ede863d05824b26823a8f572902f7a9b6f09b0c70586ef0d4c046864e6956130b9231850a515a9fbfcd56faf20354c1cf8f697f005827c048a2325
+DIST gcr-3.92.0.tar.xz 719608 BLAKE2B 770946582ada19d4282b0adfe77c4eabf08439430b89397a16829259162a940df44a5abf7e2dddd6e13c075449c7b4e5529dd95b781f67b4437246bca8989100 SHA512 bd566c8846e1ee99f82eefd9f7fbc5959c09bf383fef9c7bdc82b6c2c9c7634faaddcf6d91b0eca10b69a99e8f954272c3decf0594864351a48a5473e2bb5db3
 EBUILD gcr-3.41.0.ebuild 2005 BLAKE2B 82b8133aac42ef6a0e17b431b4509043280eba6bccbf3df3a39901a7b8921dc54c01541f6cd943e8a88ac3c55071c9115337a2504387bca72d5b9735c2aea71b SHA512 596f577056f7dff17eded2334a6a44d0c94d26faca0aca047d4cd568b4bed6f3d8ea90ba93ddca2972211cdf80028648aa16fc36f24c27b803b2faafa3558345
+EBUILD gcr-3.41.1-r1.ebuild 2301 BLAKE2B afe43d2cd564f00802cc6c5a756b64b69caa2b58f15007b27721bd954e72a9ed2c726fa0f9c1cae5f2f91deca06a72eb3f934a34b2b17fea85274ad1ebcce746 SHA512 bb82057a82d8fe890d8d8fbe368b8c73ead8423f86a07eff3a7a2dd8baf63313d0204cfa12e4ff66a7e1cdf6107ae5d947f3cc9049c87f46fb5d80796e302c1f
 EBUILD gcr-3.41.1.ebuild 2093 BLAKE2B 0790692215e78f89bdbbd7c88cc6be3745f9089f860ff8d3418e45b8b53548ec5261c4b3118d4eca4fb6348be0a89b17e7aaf1e7fd1abb57f2d1731d86f17c97 SHA512 d53bda6a7bc7ed1e9bc35be40c725722ea0b0137b3010788a98ca01b38777a32c40454aa3439f4b429fb0f05941c9d4f67b8ca8793f85cf3783bb5641da51c4a
+EBUILD gcr-3.92.0.ebuild 2083 BLAKE2B 84888a6b93a722ce344e0ced8969dccccdced9dd3e3febf64699ad3d864ede72be30a648aa38aa0daf192b91c2fb651a557725e143ef6fbd33098e3f43c8a59d SHA512 057e0655d7037e99c0c0999b1e1345be6f4f0574c5a9b46d8e0290d2450441aeaaf211468effc608b90d45cbcb1d6ba25d1535b822fcd4659b7ab1e1168a4616
 MISC metadata.xml 250 BLAKE2B 8f7f0fe023d43e380e7861e897e6afcb5de4baefb42ea9c65a57dfc0d204c6f787a99295141832e732ebb08be218da56ba77e2dd9639e4e3aabf718ce4db1d0c SHA512 2684e772dd6d83e4b49f08f2ba22d8a0a753e7b46863489eff1b5d1f2f147ad80ffd93245ca405ac4c747249bc1b754454ec9865fe16da70f9b257051e105fd8
diff --git a/app-crypt/gcr/gcr-3.41.1-r1.ebuild b/app-crypt/gcr/gcr-3.41.1-r1.ebuild
new file mode 100644
index 000000000000..ee7f1a92c62d
--- /dev/null
+++ b/app-crypt/gcr/gcr-3.41.1-r1.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gcr"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/1" # subslot = suffix of libgcr-base-3 and co
+
+IUSE="gtk gtk-doc +introspection systemd test +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+DEPEND="
+	>=dev-libs/glib-2.44.0:2
+	>=dev-libs/libgcrypt-1.2.2:0=
+	>=app-crypt/p11-kit-0.19.0
+	>=app-crypt/libsecret-0.20
+	systemd? ( sys-apps/systemd:= )
+	gtk? ( >=x11-libs/gtk+-3.22:3[introspection?] )
+	>=sys-apps/dbus-1
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+"
+RDEPEND="${DEPEND}"
+PDEPEND="app-crypt/gnupg"
+BDEPEND="
+	${PYTHON_DEPS}
+	gtk? ( dev-libs/libxml2:2 )
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gi-docgen )
+	>=sys-devel/gettext-0.19.8
+	test? ( app-crypt/gnupg )
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+PATCHES=(
+	"${FILESDIR}"/3.38.0-optional-vapi.patch
+)
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use introspection)
+		$(meson_use gtk)
+		$(meson_use gtk-doc gtk_doc)
+		-Dgpg_path="${EPREFIX}"/usr/bin/gpg
+		-Dssh_agent=true
+		$(meson_feature systemd)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+src_install() {
+	meson_src_install
+
+	# These files are installed by gcr:4
+	rm \
+		"${ED}"/usr/libexec/gcr-ssh-agent \
+		"${ED}"/usr/lib/systemd/user/gcr-ssh-agent.service \
+		"${ED}"/usr/lib/systemd/user/gcr-ssh-agent.socket \
+		|| die
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/{gck-1,gcr-3,gcr-ui-3} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
diff --git a/app-crypt/gcr/gcr-3.92.0.ebuild b/app-crypt/gcr/gcr-3.92.0.ebuild
new file mode 100644
index 000000000000..fddcb8011df7
--- /dev/null
+++ b/app-crypt/gcr/gcr-3.92.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gcr"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="4/gcr4.3-gck2.1" # subslot = soname and soversion of libgcr and libgck
+
+IUSE="gtk gtk-doc +introspection systemd test +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+DEPEND="
+	>=dev-libs/glib-2.68.0:2
+	>=dev-libs/libgcrypt-1.2.2:0=
+	>=app-crypt/p11-kit-0.19.0
+	>=app-crypt/libsecret-0.20
+	systemd? ( sys-apps/systemd:= )
+	gtk? ( gui-libs/gtk:4[introspection?] )
+	>=sys-apps/dbus-1
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+	!<app-crypt/gcr-3.41.1-r1
+"
+RDEPEND="${DEPEND}"
+PDEPEND="app-crypt/gnupg"
+BDEPEND="
+	${PYTHON_DEPS}
+	gtk? ( dev-libs/libxml2:2 )
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gi-docgen )
+	>=sys-devel/gettext-0.19.8
+	test? ( app-crypt/gnupg )
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use introspection)
+		$(meson_use gtk gtk4)
+		$(meson_use gtk-doc gtk_doc)
+		-Dgpg_path="${EPREFIX}"/usr/bin/gpg
+		-Dssh_agent=true
+		$(meson_feature systemd)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/{gck-2,gcr-4} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}