gentoo auto-resync : 01:04:2025 - 01:33:27

5 files changed, 58 insertions, 626 deletions

diff --git a/app-editors/Manifest.gz b/app-editors/Manifest.gz
index a7884cfaed14..73dfd6bfebda 100644
--- a/app-editors/Manifest.gz
+++ b/app-editors/Manifest.gz
diff --git a/app-editors/emacs/Manifest b/app-editors/emacs/Manifest
index e2bb4b229ec5..0ce575aa9459 100644
--- a/app-editors/emacs/Manifest
+++ b/app-editors/emacs/Manifest
@@ -28,6 +28,5 @@ EBUILD emacs-29.4-r3.ebuild 20335 BLAKE2B 539450b46da289783b0e6948cd3b9e0e36ce87
 EBUILD emacs-29.4.ebuild 20313 BLAKE2B 1bed634eb42caf03b67df68474bf7d8b02b0f2086e8bbe820dd82096b81630af01fa184201fbc6c7b3797ff125ccf45b5dd465eae64443854781e9588acbd4d3 SHA512 d0ba494964d39737ed536e7e00a33212f215820971a449401ca6b60d7dc51715ae39f7fe6910e5673d7eba62683a1cc7d7dc20ef50e5dc5bb71c334f70387261
 EBUILD emacs-30.1-r1.ebuild 19587 BLAKE2B 134538ef6b6d7bc837405b741293bd143e7fa7d9ebdc47d7cc6605a5cbee4bfeba8c6e4b242a77fe40764d886b6c513b50b31d1c031f4463fe000f9b1fa34ece SHA512 d8788ec10905ec0cdbf9041a3f9be8a2cc96d5e4fc50fea4cf14c89de20ba1aba0d77c3ec5490ac6dc16a3d3abc4de0f5c3c360eb5f3cf5253bf71fcaa49b048
 EBUILD emacs-30.1.9999.ebuild 19435 BLAKE2B 39d7fd87b2fffde2843d143d6e5ad5176162e06679261621d27f41cc0708df0c344f264de4fae956b228560f32d89d155e50dc5bafcbeecf297107ab10789009 SHA512 e4411e8af1ca0ee8df44bde8b1c5ca06695dadc30ae781df998ba8b788778119cd591e20b960e11ab0761f2c626db542831af19d6f5c0f41a5ee8906aafb8de6
-EBUILD emacs-30.1.ebuild 19873 BLAKE2B 9523f49a91d7e36eb6f40a8e73b66f023613881a7f5528334423f92e7cdd3b7622feae3a3205503f83fb6a385eee32003f0d3c6893aa10642c480ee42ddc39a0 SHA512 678e9717c26187b9a6cbd30434e17f5ec74124c9c0d30ddb217b07cae45e826b28d1b5c643552007b053ab83fa5408083e2a1e569517b1328c2a9f4dbb93954f
 EBUILD emacs-31.0.9999.ebuild 19294 BLAKE2B 30c8751009b7540b9b7733eb5b0dbf050b97f9cc5f798f6809d5fb92c97d6c0671763a107d4c50ee9b18aeb5ee3caaec628e24c6e1b19062c991af0c605b65dc SHA512 a1a707b2e3a1ddd00c6966ca56fb1eebd87f2ab96043c02d21bdd1f7ba8098735cb13f00825a6dadf395330cf380ad70c38a2f521a9ba32a672b41440dd3321b
 MISC metadata.xml 3434 BLAKE2B aaeef31ce265ae3b3c67ddfe01b3b41724b6fed7353e83f3efa1fe401944707391f3160d7cfea423802c67e78830387e210966f5fdc03a5a0a20b0e38f493b6d SHA512 2ad8128bfe05cbef0cdf19840e809918331c5e98976fb1af14127e0cb7adfba597ff83457a45079d1facd571953210c1650eb11b87d9bce2352e9ca865ebcc38
diff --git a/app-editors/emacs/emacs-30.1.ebuild b/app-editors/emacs/emacs-30.1.ebuild
deleted file mode 100644
index 37393a545f4a..000000000000
--- a/app-editors/emacs/emacs-30.1.ebuild
+++ /dev/null
@@ -1,625 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools eapi9-pipestatus elisp-common flag-o-matic readme.gentoo-r1 toolchain-funcs
-
-if [[ ${PV##*.} = 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://git.savannah.gnu.org/git/emacs.git"
-	EGIT_BRANCH="emacs-30"
-	EGIT_CHECKOUT_DIR="${WORKDIR}/emacs"
-	S="${EGIT_CHECKOUT_DIR}"
-	SLOT="${PV%%.*}-vcs"
-else
-	# FULL_VERSION keeps the full version number, which is needed in
-	# order to determine some path information correctly for copy/move
-	# operations later on
-	FULL_VERSION="${PV%%_*}"
-	SRC_URI="mirror://gnu/emacs/${P}.tar.xz"
-	S="${WORKDIR}/emacs-${FULL_VERSION}"
-	# PV can be in any of the following formats:
-	# 27.1                 released version (slot 27)
-	# 27.1_rc1             upstream release candidate (27)
-	# 27.0.9999            live ebuild (slot 27-vcs)
-	# 27.0.90              upstream prerelease snapshot (27-vcs)
-	# 27.0.50_pre20191223  snapshot by Gentoo developer (27-vcs)
-	if [[ ${PV} == *_pre* ]]; then
-		SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
-		S="${WORKDIR}/emacs"
-	elif [[ ${PV//[0-9]} != "." ]]; then
-		SRC_URI="https://alpha.gnu.org/gnu/emacs/pretest/${PN}-${PV/_/-}.tar.xz"
-	fi
-	SLOT="${PV%%.*}"
-	[[ ${PV} == *.*.* ]] && SLOT+="-vcs"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
-fi
-
-DESCRIPTION="The extensible, customizable, self-documenting real-time display editor"
-HOMEPAGE="https://www.gnu.org/software/emacs/"
-
-LICENSE="GPL-3+ FDL-1.3+ BSD HPND MIT W3C unicode PSF-2"
-IUSE="acl alsa aqua athena cairo dbus dynamic-loading games gfile gif +gmp gpm gsettings gtk gui gzip-el harfbuzz imagemagick +inotify jit jpeg kerberos lcms libxml2 livecd m17n-lib mailutils motif png selinux sound source sqlite ssl svg systemd +threads tiff toolkit-scroll-bars tree-sitter valgrind webp wide-int +X xattr Xaw3d xft +xpm zlib"
-
-X_DEPEND="x11-libs/libICE
-	x11-libs/libSM
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libXi
-	x11-libs/libXinerama
-	x11-libs/libXrandr
-	x11-libs/libxcb
-	x11-libs/xcb-util
-	x11-misc/xbitmaps
-	xpm? ( x11-libs/libXpm )
-	xft? (
-		media-libs/fontconfig
-		media-libs/freetype
-		x11-libs/libXrender
-		cairo? ( >=x11-libs/cairo-1.12.18[X] )
-		!cairo? ( x11-libs/libXft )
-		harfbuzz? ( media-libs/harfbuzz:0= )
-		m17n-lib? (
-			>=dev-libs/libotf-0.9.4
-			>=dev-libs/m17n-lib-1.5.1
-		)
-	)
-	gtk? ( x11-libs/gtk+:3 )
-	!gtk? (
-		motif? (
-			>=x11-libs/motif-2.3:0
-			x11-libs/libXpm
-			x11-libs/libXmu
-			x11-libs/libXt
-		)
-		!motif? (
-			Xaw3d? (
-				x11-libs/libXaw3d
-				x11-libs/libXmu
-				x11-libs/libXt
-			)
-			!Xaw3d? ( athena? (
-				x11-libs/libXaw
-				x11-libs/libXmu
-				x11-libs/libXt
-			) )
-		)
-	)"
-
-RDEPEND="app-emacs/emacs-common[games?,gui(-)?]
-	sys-libs/ncurses:0=
-	acl? ( virtual/acl )
-	alsa? ( media-libs/alsa-lib )
-	dbus? ( sys-apps/dbus )
-	games? ( acct-group/gamestat )
-	gmp? ( dev-libs/gmp:0= )
-	gpm? ( sys-libs/gpm )
-	!inotify? ( gfile? ( >=dev-libs/glib-2.28.6 ) )
-	jit? (
-		sys-devel/gcc:=[jit(-)]
-		sys-libs/zlib
-	)
-	kerberos? ( virtual/krb5 )
-	lcms? ( media-libs/lcms:2 )
-	libxml2? ( >=dev-libs/libxml2-2.2.0 )
-	mailutils? ( net-mail/mailutils[clients] )
-	!mailutils? ( acct-group/mail net-libs/liblockfile )
-	selinux? ( sys-libs/libselinux )
-	sqlite? ( dev-db/sqlite:3 )
-	ssl? ( net-libs/gnutls:0= )
-	systemd? ( sys-apps/systemd )
-	tree-sitter? ( dev-libs/tree-sitter:= )
-	valgrind? ( dev-debug/valgrind )
-	xattr? ( sys-apps/attr )
-	zlib? ( sys-libs/zlib )
-	gui? (
-		gif? ( media-libs/giflib:0= )
-		jpeg? ( media-libs/libjpeg-turbo:0= )
-		png? ( >=media-libs/libpng-1.4:0= )
-		svg? ( >=gnome-base/librsvg-2.0 )
-		tiff? ( media-libs/tiff:= )
-		webp? ( media-libs/libwebp:0= )
-		imagemagick? ( media-gfx/imagemagick:0=[jpeg?,png?,svg?,tiff?] )
-		!aqua? (
-			gsettings? (
-				app-emacs/emacs-common[gsettings(-)]
-				>=dev-libs/glib-2.28.6
-			)
-			gtk? ( !X? (
-				media-libs/fontconfig
-				media-libs/freetype
-				>=x11-libs/cairo-1.12.18
-				x11-libs/gtk+:3
-				harfbuzz? ( media-libs/harfbuzz:0= )
-				m17n-lib? (
-					>=dev-libs/libotf-0.9.4
-					>=dev-libs/m17n-lib-1.5.1
-				)
-			) )
-			!gtk? ( ${X_DEPEND} )
-			X? ( ${X_DEPEND} )
-		)
-	)"
-
-DEPEND="${RDEPEND}
-	gui? ( !aqua? (
-		!gtk? ( x11-base/xorg-proto )
-		X? ( x11-base/xorg-proto )
-	) )"
-
-BDEPEND="sys-apps/texinfo
-	virtual/pkgconfig
-	gzip-el? ( app-arch/gzip )"
-
-IDEPEND="app-eselect/eselect-emacs"
-
-RDEPEND+=" ${IDEPEND}"
-
-EMACS_SUFFIX="emacs-${SLOT}"
-SITEFILE="20${EMACS_SUFFIX}-gentoo.el"
-
-# Suppress false positive QA warnings #898304 #925091
-QA_CONFIG_IMPL_DECL_SKIP=( malloc_{get,set}_state statvfs64 )
-
-src_prepare() {
-	if [[ ${PV##*.} = 9999 ]]; then
-		FULL_VERSION=$(sed -n 's/^AC_INIT([^,]*,[^0-9.]*\([0-9.]*\).*/\1/p' \
-			configure.ac)
-		[[ ${FULL_VERSION} ]] || die "Cannot determine current Emacs version"
-		einfo "Emacs branch: ${EGIT_BRANCH}"
-		einfo "Commit: ${EGIT_VERSION}"
-		einfo "Emacs version number: ${FULL_VERSION}"
-		[[ ${FULL_VERSION} =~ ^${PV%.*}(\..*)?$ ]] \
-			|| die "Upstream version number changed to ${FULL_VERSION}"
-	fi
-
-	default
-
-	if use jit; then
-		find lisp -type f -name "*.elc" -delete || die
-
-		# These files ignore LDFLAGS. We assign the variable here, because
-		# for live ebuilds FULL_VERSION doesn't exist in global scope
-		QA_FLAGS_IGNORED="usr/$(get_libdir)/emacs/${FULL_VERSION}/native-lisp/.*"
-
-		# The build system requires gcc for native compilation #874657
-		if ! tc-is-gcc; then
-			ewarn "Emacs must be built with gcc[jit] if USE=jit is enabled."
-			ewarn "Ignoring CC=$(tc-getCC) and forcing ${CHOST}-gcc"
-			export CC=${CHOST}-gcc AR=${CHOST}-gcc-ar NM=${CHOST}-gcc-nm \
-				RANLIB=${CHOST}-gcc-ranlib
-			tc-is-gcc || die "tc-is-gcc failed in spite of CC=${CC}"
-		fi
-
-		# gccjit doesn't play well with ccache or distcc #801580
-		# For now, work around the problem with an explicit LIBRARY_PATH
-		if has ccache ${FEATURES} || has distcc ${FEATURES} && tc-is-gcc; then
-			export LIBRARY_PATH=$("$(tc-getCC)" -print-search-dirs \
-				| sed -n '/^libraries:/{s:^[^/]*::;p}')
-		fi
-	fi
-
-	# Fix filename reference in redirected man page
-	sed -i -e "/^\\.so/s/etags/&-${EMACS_SUFFIX}/" doc/man/ctags.1 || die
-
-	# libseccomp is detected by configure but doesn't appear to have any
-	# effect on the installed image. Suppress it by supplying pkg-config
-	# with a wrong library name.
-	sed -i -e "/CHECK_MODULES/s/libseccomp/DiSaBlE&/" configure.ac || die
-
-	# Tests that use bubblewrap don't work in the sandbox:
-	# "bwrap: setting up uid map: Permission denied"
-	# So, disrupt the search for the bwrap executable.
-	sed -i -e 's/(executable-find "bwrap")/nil/' test/src/emacs-tests.el \
-		test/lisp/emacs-lisp/bytecomp-tests.el || die
-
-	AT_M4DIR=m4 eautoreconf
-}
-
-src_configure() {
-	replace-flags "-O[3-9]" -O2			#839405
-
-	# We want floating-point arithmetic to be correct #933380
-	replace-flags -Ofast -O2
-	append-flags -fno-fast-math -ffp-contract=off
-
-	# Prevents e.g. tests interfering with running Emacs.
-	unset EMACS_SOCKET_NAME
-
-	local myconf=(
-		--program-suffix="-${EMACS_SUFFIX}"
-		--includedir="${EPREFIX}"/usr/include/${EMACS_SUFFIX}
-		--infodir="${EPREFIX}"/usr/share/info/${EMACS_SUFFIX}
-		--localstatedir="${EPREFIX}"/var
-		--enable-locallisppath="${EPREFIX}/etc/emacs:${EPREFIX}${SITELISP}"
-		--without-compress-install
-		--without-hesiod
-		--without-pop
-		--with-file-notification=$(usev inotify || usev gfile || echo no)
-		--with-pdumper
-		$(use_enable acl)
-		$(use_enable xattr)
-		$(use_with dbus)
-		$(use_with dynamic-loading modules)
-		$(use_with games gameuser ":gamestat")
-		$(use_with gmp libgmp)
-		$(use_with gpm)
-		$(use_with jit native-compilation aot)
-		$(use_with kerberos) $(use_with kerberos kerberos5)
-		$(use_with lcms lcms2)
-		$(use_with libxml2 xml2)
-		$(use_with mailutils)
-		$(use_with selinux)
-		$(use_with sqlite sqlite3)
-		$(use_with ssl gnutls)
-		$(use_with systemd libsystemd)
-		$(use_with threads)
-		$(use_with tree-sitter)
-		$(use_with wide-int)
-	)
-
-	if use alsa; then
-		use sound || ewarn \
-			"USE flag \"alsa\" overrides \"-sound\"; enabling sound support."
-		myconf+=( --with-sound=alsa )
-	else
-		myconf+=( --with-sound=$(usex sound oss no) )
-	fi
-
-	if use jit; then
-		use zlib || ewarn \
-			"USE flag \"jit\" overrides \"-zlib\"; enabling zlib support."
-		myconf+=( --with-zlib )
-	else
-		myconf+=( $(use_with zlib) )
-	fi
-
-	# Emacs supports these window systems:
-	# X11, pure GTK (without X11), or Nextstep (Aqua/Cocoa).
-	# General GUI support is enabled by the "gui" USE flag, then
-	# the window system is selected as follows:
-	#   "aqua" -> Nextstep
-	#   "gtk -X" -> pure GTK
-	#   otherwise -> X11
-	# For X11 there is the further choice of toolkits GTK, Motif,
-	# Athena (Lucid), or no toolkit. They are enabled (in order of
-	# preference) with the "gtk", "motif", "Xaw3d", and "athena" flags.
-
-	if ! use gui; then
-		einfo "Configuring to build without window system support"
-		myconf+=(
-			--without-x --without-pgtk --without-ns
-		)
-	elif use aqua; then
-		einfo "Configuring to build with Nextstep (Macintosh Cocoa) support"
-		myconf+=(
-			--with-ns --disable-ns-self-contained
-			--without-x --without-pgtk
-		)
-	elif use gtk && ! use X; then
-		einfo "Configuring to build with pure GTK (without X11) support"
-		myconf+=(
-			--with-pgtk --without-x --without-ns
-			--with-toolkit-scroll-bars #836392
-			--without-gconf
-			--without-xwidgets
-			$(use_with gsettings)
-			$(use_with harfbuzz)
-			$(use_with m17n-lib libotf)
-			$(use_with m17n-lib m17n-flt)
-		)
-	else
-		# X11
-		myconf+=(
-			--with-x --without-pgtk --without-ns
-			--without-gconf
-			$(use_with gsettings)
-			$(use_with toolkit-scroll-bars)
-			$(use_with xpm)
-		)
-
-		if use xft; then
-			myconf+=(
-				--with-xft
-				$(use_with cairo)
-				$(use_with harfbuzz)
-				$(use_with m17n-lib libotf)
-				$(use_with m17n-lib m17n-flt)
-			)
-		else
-			myconf+=(
-				--without-xft
-				--without-cairo
-				--without-libotf --without-m17n-flt
-			)
-			use cairo && ewarn \
-				"USE flag \"cairo\" has no effect if \"xft\" is not set."
-			use m17n-lib && ewarn \
-				"USE flag \"m17n-lib\" has no effect if \"xft\" is not set."
-		fi
-
-		local f line
-		if use gtk; then
-			einfo "Configuring to build with GIMP Toolkit (GTK+)"
-			while read line; do ewarn "${line}"; done <<-EOF
-				Your version of GTK+ will have problems with closing open
-				displays. This is no problem if you just use one display, but
-				if you use more than one and close one of them Emacs may crash.
-				See <https://gitlab.gnome.org/GNOME/gtk/-/issues/221> and
-				<https://gitlab.gnome.org/GNOME/gtk/-/issues/2315>.
-				If you intend to use more than one display, then it is strongly
-				recommended that you compile Emacs with the Athena/Lucid or the
-				Motif toolkit instead.
-			EOF
-			myconf+=( --with-x-toolkit=gtk3 --without-xwidgets )
-			for f in motif Xaw3d athena; do
-				use ${f} && ewarn \
-					"USE flag \"${f}\" has no effect if \"gtk\" is set."
-			done
-		elif use motif; then
-			einfo "Configuring to build with Motif toolkit"
-			myconf+=( --with-x-toolkit=motif )
-			for f in Xaw3d athena; do
-				use ${f} && ewarn \
-					"USE flag \"${f}\" has no effect if \"motif\" is set."
-			done
-		elif use athena || use Xaw3d; then
-			einfo "Configuring to build with Athena/Lucid toolkit"
-			myconf+=( --with-x-toolkit=lucid $(use_with Xaw3d xaw3d) )
-		else
-			einfo "Configuring to build with no toolkit"
-			myconf+=( --with-x-toolkit=no )
-		fi
-	fi
-
-	if use gui; then
-		# Common flags recognised for all GUIs
-		myconf+=(
-			$(use_with gif)
-			$(use_with jpeg)
-			$(use_with png)
-			$(use_with svg rsvg)
-			$(use_with tiff)
-			$(use_with webp)
-			$(use_with imagemagick)
-		)
-	fi
-
-	if tc-is-cross-compiler; then
-		# Configure a CBUILD directory when cross-compiling to make tools
-		mkdir -p "${S}-build" && pushd "${S}-build" >/dev/null || die
-		ECONF_SOURCE="${S}" econf_build --without-all --without-x-toolkit
-		popd >/dev/null || die
-		# Don't try to execute the binary for dumping during the build
-		myconf+=( --with-dumping=none )
-	elif use m68k; then
-		# Workaround for https://debbugs.gnu.org/44531
-		myconf+=( --with-dumping=unexec )
-	else
-		myconf+=( --with-dumping=pdumper )
-	fi
-
-	econf "${myconf[@]}"
-}
-
-src_compile() {
-	export ac_cv_header_valgrind_valgrind_h=$(usex valgrind)
-	append-cppflags -DUSE_VALGRIND=$(usex valgrind)
-
-	if tc-is-cross-compiler; then
-		# Build native tools for compiling lisp etc.
-		emake -C "${S}-build" src
-		emake lib	   # Cross-compile dependencies first for timestamps
-		# Save native build tools in the cross-directory
-		cp "${S}-build"/lib-src/make-{docfile,fingerprint} lib-src || die
-		# Specify the native Emacs to compile lisp
-		EMACS_EMAKE_ARGS=( EMACS="${S}-build/src/emacs" )
-		emake "${EMACS_EMAKE_ARGS[@]}" actual-all
-	else
-		EMACS_EMAKE_ARGS=()
-		emake
-	fi
-}
-
-src_test() {
-	# List .el test files with a comment above listing the exact
-	# subtests which caused failure. Elements should begin with a %.
-	# e.g. %lisp/gnus/mml-sec-tests.el.
-	local exclude_tests=(
-		# Reason: permission denied on /nonexistent
-		# (vc-*-bzr only fails if breezy is installed, as they
-		# try to access cache dirs under /nonexistent)
-		#
-		# rmail-undigest-test-multipart-mixed-digest
-		# rmail-undigest-test-rfc1153-less-strict-digest
-		# rmail-undigest-test-rfc1153-sloppy-digest
-		# rmail-undigest-test-rfc934-digest
-		# vc-test-bzr02-state
-		# vc-test-bzr05-rename-file
-		# vc-test-bzr06-version-diff
-		# vc-bzr-test-bug9781
-		%lisp/mail/undigest-tests.el
-		%lisp/vc/vc-tests.el
-		%lisp/vc/vc-bzr-tests.el
-
-		# Reason: tries to access network
-		# internet-is-working
-		%src/process-tests.el
-	)
-	use elibc_musl && exclude_tests+=(
-			# Reason: newlocale(3) lenient locale validation #906012
-			# fns-tests-collate-strings
-			%src/fns-tests.el
-		)
-	use threads || exclude_tests+=(
-			%lisp/progmodes/eglot-tests.el
-			%src/emacs-module-tests.el
-			%src/keyboard-tests.el
-		)
-
-	# Redirect GnuPG's sockets, in order not to exceed the 108 char limit
-	# for socket paths on Linux.
-	mkdir -p "${T}"/gpg || die
-	local f
-	for f in browser extra ssh; do
-		printf "%%Assuan%%\nsocket=%s\n" "${T}/gpg/S.${f}" \
-			> "test/lisp/gnus/mml-sec-resources/S.gpg-agent.${f}" || die
-	done
-
-	# See test/README for possible options
-	emake \
-		EMACS_TEST_VERBOSE=1 \
-		EXCLUDE_TESTS="${exclude_tests[*]}" \
-		TERM=dumb \
-		TEST_BACKTRACE_LINE_LENGTH=nil \
-		check
-}
-
-src_install() {
-	emake \
-		"${EMACS_EMAKE_ARGS[@]}" \
-		DESTDIR="${D}" \
-		NO_BIN_LINK=t \
-		BLESSMAIL_TARGET="" \
-		install
-
-	mv "${ED}"/usr/bin/{emacs-${FULL_VERSION}-,}${EMACS_SUFFIX} || die
-	mv "${ED}"/usr/share/man/man1/{emacs-,}${EMACS_SUFFIX}.1 || die
-	mv "${ED}"/usr/share/metainfo/{emacs-,}${EMACS_SUFFIX}.metainfo.xml || die
-
-	# dissuade Portage from removing our dir file #257260
-	touch "${ED}"/usr/share/info/${EMACS_SUFFIX}/.keepinfodir
-	docompress -x /usr/share/info/${EMACS_SUFFIX}/dir
-
-	# movemail must be setgid mail
-	if ! use mailutils; then
-		fowners root:mail /usr/libexec/emacs/${FULL_VERSION}/${CHOST}/movemail
-		fperms 2751 /usr/libexec/emacs/${FULL_VERSION}/${CHOST}/movemail
-	fi
-
-	# avoid collision between slots, see bug #169033 e.g.
-	rm "${ED}"/usr/share/emacs/site-lisp/subdirs.el || die
-	rm -rf "${ED}"/usr/share/{applications,icons} || die
-	rm -rf "${ED}"/usr/share/glib-2.0 || die #911117
-	rm -rf "${ED}/usr/$(get_libdir)/systemd" || die
-	rm -rf "${ED}"/var || die
-
-	# remove unused <version>/site-lisp dir
-	rm -rf "${ED}"/usr/share/emacs/${FULL_VERSION}/site-lisp || die
-
-	# remove COPYING file (except for etc/COPYING used by describe-copying)
-	rm "${ED}"/usr/share/emacs/${FULL_VERSION}/lisp/COPYING || die
-
-	if use systemd; then
-		insinto /usr/lib/systemd/user
-		sed -e "/^##/d" \
-			-e "/^ExecStart/s,emacs,${EPREFIX}/usr/bin/${EMACS_SUFFIX}," \
-			-e "/^ExecStop/s,emacsclient,${EPREFIX}/usr/bin/&-${EMACS_SUFFIX}," \
-			etc/emacs.service | newins - ${EMACS_SUFFIX}.service
-		pipestatus || die
-	fi
-
-	if use gzip-el; then
-		# compress .el files when a corresponding .elc exists
-		find "${ED}"/usr/share/emacs/${FULL_VERSION}/lisp -type f \
-			-name "*.elc" -print | sed 's/\.elc$/.el/' | xargs gzip -9n
-		pipestatus || die "gzip .el pipeline failed"
-	fi
-
-	local cdir
-	if use source; then
-		cdir="/usr/share/emacs/${FULL_VERSION}/src"
-		insinto "${cdir}"
-		# This is not meant to install all the source -- just the
-		# C source you might find via find-function
-		doins src/*.{c,h,m}
-	elif has installsources ${FEATURES}; then
-		cdir="/usr/src/debug/${CATEGORY}/${PF}/${S#"${WORKDIR}/"}/src"
-	fi
-
-	sed -e "${cdir:+#}/^Y/d" -e "s/^[XY]//" >"${T}/${SITEFILE}" <<-EOF || die
-	X
-	;;; ${EMACS_SUFFIX} site-lisp configuration
-	X
-	(when (string-equal emacs-version "${FULL_VERSION}")
-	Y  (setq find-function-C-source-directory
-	Y	"${EPREFIX}${cdir}")
-	X  (let ((path (getenv "INFOPATH"))
-	X	(dir "${EPREFIX}/usr/share/info/${EMACS_SUFFIX}")
-	X	(re "\\\\\`${EPREFIX}/usr/share\\\\>"))
-	X    (and path
-	X	 ;; move Emacs Info dir before anything else in /usr/share
-	X	 (let* ((p (cons nil (split-string path ":" t))) (q p))
-	X	   (while (and (cdr q) (not (string-match re (cadr q))))
-	X	     (setq q (cdr q)))
-	X	   (setcdr q (cons dir (delete dir (cdr q))))
-	X	   (setenv "INFOPATH" (mapconcat #'identity (cdr p) ":"))))))
-	EOF
-	elisp-site-file-install "${T}/${SITEFILE}" || die
-
-	dodoc README BUGS CONTRIBUTE
-
-	if use gui && use aqua; then
-		dodir /Applications/Gentoo
-		rm -rf "${ED}"/Applications/Gentoo/${EMACS_SUFFIX^}.app || die
-		mv nextstep/Emacs.app \
-			"${ED}"/Applications/Gentoo/${EMACS_SUFFIX^}.app || die
-	fi
-
-	local DOC_CONTENTS="You can set the version to be started by
-		/usr/bin/emacs through the Emacs eselect module, which also
-		redirects man and info pages. Therefore, several Emacs versions can
-		be installed at the same time. \"man emacs.eselect\" for details.
-		\\n\\nIf you upgrade from a previous major version of Emacs, then
-		it is strongly recommended that you use app-admin/emacs-updater
-		to rebuild all byte-compiled elisp files of the installed Emacs
-		packages."
-	if use gui; then
-		DOC_CONTENTS+="\\n\\nYou need to install some fonts for Emacs.
-			Installing media-fonts/font-adobe-{75,100}dpi on the X server's
-			machine would satisfy basic Emacs requirements under X11.
-			See also https://wiki.gentoo.org/wiki/Xft_support_for_GNU_Emacs
-			for how to enable anti-aliased fonts."
-		use aqua && DOC_CONTENTS+="\\n\\n${EMACS_SUFFIX^}.app is in
-			\"${EPREFIX}/Applications/Gentoo\". You may want to copy or
-			symlink it into /Applications by yourself."
-	fi
-	if ! use mailutils; then
-		DOC_CONTENTS+="\\n\\nThe mailutils USE flag is disabled. If Emacs'
-		own e-mail features are going to be used as an e-mail client
-		(e.g. Rmail), you are strongly encouraged to enable it. If not,
-		Emacs will use its own implementation of movemail; which has
-		fewer features and is less secure. For more information see:
-		https://www.gnu.org/software/emacs/manual/html_node/emacs/Movemail.html"
-	fi
-	tc-is-cross-compiler && DOC_CONTENTS+="\\n\\nEmacs did not write
-		a portable dump file due to being cross-compiled.
-		To create this file at run time, execute the following command:
-		\\n${EMACS_SUFFIX} --batch -Q --eval='(dump-emacs-portable
-		\"/usr/libexec/emacs/${FULL_VERSION}/${CHOST}/emacs.pdmp\")'"
-	readme.gentoo_create_doc
-}
-
-pkg_preinst() {
-	# verify that the PM hasn't removed our Info directory index #257260
-	local infodir="${ED}/usr/share/info/${EMACS_SUFFIX}"
-	[[ -f ${infodir}/dir || ! -d ${infodir} ]] || die
-}
-
-pkg_postinst() {
-	elisp-site-regen
-	readme.gentoo_print_elog
-
-	# Force an update of the emacs symlink for the livecd/dvd,
-	# because some microemacs packages set it with USE=livecd.
-	# Otherwise, create it only when it is not yet set.
-	eselect --root="${ROOT}" emacs update $(usev !livecd ifunset)
-}
-
-pkg_postrm() {
-	elisp-site-regen
-	eselect --root="${ROOT}" emacs update ifunset
-}
diff --git a/app-editors/mousepad/Manifest b/app-editors/mousepad/Manifest
index de94f874afb3..05b2383099ce 100644
--- a/app-editors/mousepad/Manifest
+++ b/app-editors/mousepad/Manifest
@@ -1,5 +1,7 @@
 DIST mousepad-0.6.3.tar.bz2 1428583 BLAKE2B 73a0eb0cfecaa88c6d3508034561206ff1a24139bbdea4cb677ec79de30a59386cf7beb7fd540d31c0a3ec4804ba2001b13470baf0bbec19dc4cf1cc315479ee SHA512 a47e9c0d5b039444ee455e80d0ab4642d5c29d6e5632ec4fccfcef061b4bf40a1709ea73b092b02e915e1796d1593ede68e59b9fe373e127302d34f82c9beae3
 DIST mousepad-0.6.4.tar.xz 461356 BLAKE2B 1c1c8d4faebc31655186008592321a53606d880b483543ded47994b802d6e4d94e63ae12066d3f1d0649869d5fd52da2a44682d811bc9cc74c100308e38a82df SHA512 3b118a881d89502f74224ddb45121e7e0b3f771ed4f609f4567c9bbaf04757b31de8c02cbbebcb22d69c7e588f53a3c0b88c145aace3061b9a08c7ce5ae6352c
+DIST mousepad-0.6.5.tar.xz 461276 BLAKE2B 9bf9e5256a43299814d33b4ec27caf96796d2e1735b26f01851d24c2be6fcd46a5e16eba439476edd1e5e856e0b63c62d5cd47f2c30b06a01eb98ba84726792a SHA512 cd71e40c6b33707bf9955b792f5af8b72698efdf44014177380465522b0a0e3078e4a16d3b70dff22acbdacb57745469ca4302c7f2ec752f76a8ce35a0d7ee06
 EBUILD mousepad-0.6.3.ebuild 1260 BLAKE2B 63cd9db299c6a28506cf4bab78caace6efed665a7429d7a963364947dcec2c2e08d6e531360f4a859e179e137c0c29466864056cbe78204133bedc4928ae8125 SHA512 615adcfad923c131c3bec885a44d4b808b24f9dd24c99d13f5bd9110fb4ef44d7a3c258a2b2dd36d8b18fec6993ad8184a52fae82f4bb1691c9c607b29b70ca0
 EBUILD mousepad-0.6.4.ebuild 1199 BLAKE2B d3ce9c61cb897ab75097c312234773e7e9d64640d9c412d76ead99b674f6e85ee1d7734025dd83323c880f785106e46aec1e8def96f1c67c09b5c35eb525ce4d SHA512 a4a777a18792d87e2ee89a6612a1ba5ddd860fad9ca0b89c6e87bead77eb6faf771b3f3be51f8166d2836c7231104e5b115a9912c938f8ae24a57987b93ade72
+EBUILD mousepad-0.6.5.ebuild 1199 BLAKE2B d3ce9c61cb897ab75097c312234773e7e9d64640d9c412d76ead99b674f6e85ee1d7734025dd83323c880f785106e46aec1e8def96f1c67c09b5c35eb525ce4d SHA512 a4a777a18792d87e2ee89a6612a1ba5ddd860fad9ca0b89c6e87bead77eb6faf771b3f3be51f8166d2836c7231104e5b115a9912c938f8ae24a57987b93ade72
 MISC metadata.xml 318 BLAKE2B 53e8d0080a2643b6d5191012a6c86316d926678a85190371ce498705fc142f83d1a325a935a75f8f29c19c878a677ba96a35d5e8702a23c4f1e7ec210dbeef3e SHA512 89a0b309c4a205b97627be6c0d3fb1a280d9c4dfd2107c09854ef6a912e38e0dc2da39e0768d5103b81b72bf84eed7b1014084c52ff9482f4acc13e8d1a3def3
diff --git a/app-editors/mousepad/mousepad-0.6.5.ebuild b/app-editors/mousepad/mousepad-0.6.5.ebuild
new file mode 100644
index 000000000000..667064df03a7
--- /dev/null
+++ b/app-editors/mousepad/mousepad-0.6.5.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson xdg-utils
+
+DESCRIPTION="GTK+-based editor for the Xfce Desktop Environment"
+HOMEPAGE="
+	https://docs.xfce.org/apps/mousepad/start
+	https://gitlab.xfce.org/apps/mousepad/
+"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="policykit spell +shortcuts"
+
+DEPEND="
+	>=dev-libs/glib-2.56.2
+	>=x11-libs/gtk+-3.22.0:3
+	>=x11-libs/gtksourceview-4.0.0:4
+	policykit? ( >=sys-auth/polkit-0.102 )
+	spell? ( >=app-text/gspell-1.6.0 )
+	shortcuts? ( >=xfce-base/libxfce4ui-4.17.5:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dgtksourceview4=enabled
+		$(meson_feature policykit polkit)
+		$(meson_feature spell gspell-plugin)
+		$(meson_feature shortcuts shortcuts-plugin)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}