gentoo resync : 06.08.2019

3 files changed, 111 insertions, 6 deletions

diff --git a/app-emacs/emacs-common-gentoo/Manifest b/app-emacs/emacs-common-gentoo/Manifest
index af04281d42ed..84acac06b8bd 100644
--- a/app-emacs/emacs-common-gentoo/Manifest
+++ b/app-emacs/emacs-common-gentoo/Manifest
@@ -1,3 +1,4 @@
 DIST emacs-common-gentoo-1.6.tar.xz 61224 BLAKE2B 70e4f30c26c9098fdb02a53cab5d60cb611143d8bac6947707f3c7596b5a81ceb513b5a0809ee90f351472824f1d4216720c02cadb51d25b3dfce5e436e02bdf SHA512 a7daed2241d778ab283482ecc016801e25084eed10fcbbc50e187d5f842df5a0d278a77f94ae950b086c8651e8ca1a18f89c11dffdde9cf9168755288aae926a
-EBUILD emacs-common-gentoo-1.6-r2.ebuild 2888 BLAKE2B 7f7037a5712a7b3b1943e457b86c01a53db206f17e918b15d1c8d7dff361b9fac86d3c7eade82eeccc3ae582a73a6a941d7691f999a734938c95b44644e500bc SHA512 7e6de29ed815b67ce99bd3c8f30fbc57ee75bbd38b5c3698e8396a593fbb1d6c07cc4decad4fd71f5c4da1921759d79432c1b80e459337549a2bdd358e0b9bcb
+EBUILD emacs-common-gentoo-1.6-r1.ebuild 2878 BLAKE2B aafb8c7842b9075d08dd037ed2e3fd59699bf0110d380f10a2c8adf4dba2aea3008b5670b3bd9ee8f33dca4ca1f88a4e081df292e4eb9c0578b9a51cb9b0c84b SHA512 d9b0cb62a397af1ee382aff2c9344891f9632b9eafd54f56c7f34c29b4712b0ae4006420798e6022e4ffa9658aa2874c1f43a824a3eba5ddc0e1f056af730fce
+EBUILD emacs-common-gentoo-1.6-r3.ebuild 2849 BLAKE2B 0f526443ee423c4e77c5b07da987c84da4303a449a3e955b680fb9faeb61b3c8dd158ccb1cf9c32d97d5e430f70a5141288a73d11a0e103e2c0733b9b8c1a9b9 SHA512 641b456b2f238d69dc6542b400488201c10d08a2b6fdd2e28408c93a325bff325bca1099c74b79ece849640e3f6681010b66c986cc74e0649526b50a882eb150
 MISC metadata.xml 360 BLAKE2B e7e420afb7a8377bffcf2a23f3954bbf4cc80fcd19a8514733e2e0164f4235271e21dc860bf77cb9cfcd1a4026ef3dafe97a10dc397e2d8e6f001f02bf6e9bc7 SHA512 d57f8f097617229f774b06437aaa83595aab2a6d9321d51b97dac8bd56fa94db396c7bdca538570f0912390e25ae8643c5adc374908757f67f1422fa1f872605
diff --git a/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r2.ebuild b/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r1.ebuild
index 5e48e30334cd..84eab96b484e 100644
--- a/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r2.ebuild
+++ b/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r1.ebuild
@@ -1,9 +1,9 @@
 # Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=6
 
-inherit elisp-common desktop xdg-utils gnome2-utils readme.gentoo-r1
+inherit elisp-common desktop xdg-utils gnome2-utils readme.gentoo-r1 user
 
 DESCRIPTION="Common files needed by all GNU Emacs versions"
 HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
@@ -11,13 +11,15 @@ SRC_URI="https://dev.gentoo.org/~ulm/emacs/${P}.tar.xz"
 
 LICENSE="GPL-3+"
 SLOT="0"
-KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~riscv ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
 IUSE="games X"
 
-RDEPEND="games? ( acct-group/gamestat )"
-DEPEND="${RDEPEND}"
 PDEPEND="virtual/emacs"
 
+pkg_setup() {
+	use games && enewgroup gamestat 36
+}
+
 src_install() {
 	insinto "${SITELISP}"
 	doins subdirs.el
diff --git a/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r3.ebuild b/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r3.ebuild
new file mode 100644
index 000000000000..b6a09310a9f4
--- /dev/null
+++ b/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.6-r3.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit elisp-common desktop xdg-utils readme.gentoo-r1
+
+DESCRIPTION="Common files needed by all GNU Emacs versions"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
+SRC_URI="https://dev.gentoo.org/~ulm/emacs/${P}.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ia64 ~mips ppc ppc64 ~riscv ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="games X"
+
+RDEPEND="games? ( acct-group/gamestat )"
+DEPEND="${RDEPEND}"
+PDEPEND="virtual/emacs"
+
+src_install() {
+	insinto "${SITELISP}"
+	doins subdirs.el
+	newins site-gentoo.el{,.orig}
+
+	keepdir /etc/emacs
+	insinto /etc/emacs
+	doins site-start.el
+
+	if use games; then
+		keepdir /var/games/emacs
+		fowners 0:gamestat /var/games/emacs
+		fperms g+w /var/games/emacs
+	fi
+
+	if use X; then
+		local i
+		domenu emacs.desktop emacsclient.desktop || die
+
+		pushd icons || die
+		newicon sink.png emacs-sink.png
+		newicon emacs25_48.png emacs.png
+		for i in 16 24 32 48 128; do
+			[[ ${i} -le 48 ]] && newicon -s ${i} emacs22_${i}.png emacs22.png
+			newicon -s ${i} emacs23_${i}.png emacs23.png
+			newicon -s ${i} emacs25_${i}.png emacs.png
+		done
+		doicon -s scalable emacs23.svg
+		newicon -s scalable emacs25.svg emacs.svg
+		popd
+	fi
+
+	DOC_CONTENTS="All site initialisation for Gentoo-installed packages is
+		added to ${SITELISP}/site-gentoo.el. In order for this site
+		initialisation to be loaded for all users automatically, a default
+		site startup file /etc/emacs/site-start.el is installed. You are
+		responsible for maintenance of this file.
+		\n\nAlternatively, individual users can add the following command:
+		\n\n(require 'site-gentoo)
+		\n\nto their ~/.emacs initialisation files, or, for greater
+		flexibility, users may load single package-specific initialisation
+		files from the ${SITELISP}/site-gentoo.d/ directory."
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	# make sure that site-gentoo.el exists since site-start.el requires it
+	if [[ ! -f ${ED}${SITELISP}/site-gentoo.el ]]; then		#554518
+		mv "${ED}${SITELISP}"/site-gentoo.el{.orig,} || die
+	fi
+	if [[ -d ${EROOT}${SITELISP} ]]; then
+		elisp-site-regen
+		cp "${EROOT}${SITELISP}/site-gentoo.el" "${ED}${SITELISP}/" || die
+	fi
+
+	if use games; then
+		local f
+		for f in /var/games/emacs/{snake,tetris}-scores; do
+			if [[ -e ${EROOT}${f} ]]; then
+				cp "${EROOT}${f}" "${ED}${f}" || die
+			fi
+			touch "${ED}${f}" || die
+			chgrp gamestat "${ED}${f}" || die
+			chmod g+w "${ED}${f}" || die
+		done
+	fi
+}
+
+pkg_postinst() {
+	if use X; then
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	if use X; then
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+}