gentoo resync : 24.07.2021

1 files changed, 58 insertions, 0 deletions

diff --git a/app-emacs/wanderlust/wanderlust-2.15.9_p20210629.ebuild b/app-emacs/wanderlust/wanderlust-2.15.9_p20210629.ebuild
new file mode 100644
index 000000000000..036441e2b356
--- /dev/null
+++ b/app-emacs/wanderlust/wanderlust-2.15.9_p20210629.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+NEED_EMACS=24.5
+
+inherit elisp
+
+DESCRIPTION="Yet Another Message Interface on Emacsen"
+HOMEPAGE="https://github.com/wanderlust/wanderlust"
+GITHUB_SHA1="769699d60aa033049804083b459ee562b82db77e"
+SRC_URI="https://github.com/wanderlust/${PN}/archive/${GITHUB_SHA1}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${GITHUB_SHA1}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="bbdb ssl l10n_ja"
+
+RDEPEND=">=app-emacs/apel-10.8
+	>=app-emacs/flim-1.14.9
+	>=app-emacs/semi-1.14.7
+	bbdb? ( app-emacs/bbdb )"
+DEPEND="${RDEPEND}"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_configure() {
+	local lang="\"en\""
+	use l10n_ja && lang="${lang} \"ja\""
+	echo "(setq wl-info-lang '(${lang}) wl-news-lang '(${lang}))" >>WL-CFG
+	use ssl && echo "(setq wl-install-utils t)" >>WL-CFG
+}
+
+src_compile() {
+	emake
+	emake info
+}
+
+src_install() {
+	emake \
+		LISPDIR="${ED}${SITELISP}" \
+		PIXMAPDIR="${ED}${SITEETC}/wl/icons" \
+		install
+
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}" wl
+
+	insinto "${SITEETC}/wl/samples/en"
+	doins samples/en/*
+	doinfo doc/wl*.info
+	dodoc BUGS ChangeLog* INSTALL NEWS README.md
+
+	if use l10n_ja; then
+		insinto "${SITEETC}/wl/samples/ja"
+		doins samples/ja/*
+		dodoc BUGS.ja INSTALL.ja NEWS.ja README.ja.md
+	fi
+}