gentoo resync : 03.11.2019

2 files changed, 104 insertions, 0 deletions

diff --git a/app-emulation/containers-storage/Manifest b/app-emulation/containers-storage/Manifest
index 475c2f7f51e5..4298fe5a2958 100644
--- a/app-emulation/containers-storage/Manifest
+++ b/app-emulation/containers-storage/Manifest
@@ -1,6 +1,8 @@
 DIST containers-storage-1.13.1.tar.gz 5983556 BLAKE2B 1d0b6aba0464603fb26c45beecdb9b4afe6566dff4698da980ad6f9736a6d810ec41334f181d5709f78bab986e704c965b1967ed591348cd687d9cb92875321d SHA512 9fa686f44dda3d363f7c623abc9baa0911e26eb5e7dbb7bc60da259fe8d52411cb25fb98e2c8db10a5a80ebf04d07af8390acd48d26706f913900b19e58eac9f
 DIST containers-storage-1.13.3.tar.gz 5983607 BLAKE2B 9e591873da4824a133e3818ba9a97074bca234c3154bef9c4febcfd559d0b2ab7462c7da24ce7d391bbdbe2d9a62cb9fd711624623ba28cd8e79d0ca7fcabb47 SHA512 83fd16cbe5821c68092845defc2c5b8407b03c3972b146f409be3444a114d357709fefc25206a1ca26e6ef4a5fc219f360bb0195ffdc1c6e9f79e90f07740820
+DIST containers-storage-1.13.5.tar.gz 5968281 BLAKE2B 9690ebc87ce32a82b7560d594e192e0ad4dc9e8885797593d8c9699c13b9ddf0814773bce081edafe3050aba5d2bc470855c0717874c091b1468d52f7ad08658 SHA512 7f9f65e3141b7843a42389c78b3fbcc55a205eb661968f85942ccc2751fa6eb3fdf1199e8d244264d1b8f392e290a1770f93d5a8fd58de98f9d9a277aa39155f
 DIST github.com-pquerna-ffjson-e517b90714f7c0eabe6d2e570a5886ae077d6db6.tar.gz 103470 BLAKE2B 81f0f6ea6648997cb61723d09d456802e60a3d1eb35134c4bbc8af5943b955b1402fe2b3f8d0d4d2d0293ab256a9be66d53262d5f79ca00bf8c18ded39dc44f4 SHA512 fadca5a7bd0c0578b23281720a08c505054f3497daeee8efa36b5acafa4118feb4b8a96c4acb4c279d72ebcd50846307cfbb846a355b62f350c961f9102c93a6
 EBUILD containers-storage-1.13.1.ebuild 3686 BLAKE2B e61c082b0de35a9cddd00e37459579ea0e98112a43a62187e1e45a19a62121df830af9f7d0a67460fa8bc71eb4295b6f8405ee21796168d18ee46033d5f11b34 SHA512 29f51afd336f77f80c75c5a99813e64d98e857b0eba4b932329eb94004657bb815e4c1a875bf9fa99da044265cd6443282eaeca79c04f59b58374c287c22a94c
 EBUILD containers-storage-1.13.3.ebuild 3699 BLAKE2B 045609a6d1b3ca7a0f17b860e5d4ff581cfb7d558406ab957e9684f05850e7fb654b5ec1e40fdc3d2dc5d51fae68aa2487c57500c5d71379f3ea62c97f8c8dd1 SHA512 65a39e7b91924a764eba4ef51eecdef7477bf45aae0e08e407f3a5f67b80426b9fdbeb585c3db5e9b6cf3a92ec0b41877da77ce45e66545da209ffb490f3c69b
+EBUILD containers-storage-1.13.5.ebuild 3485 BLAKE2B 539646c67e3f3559b47d10f14924a708c6762ba2dedbb243e26507b1223cbb103d9e123d9c937dfe75af86885a2af5ce025ea5d5dc90c77bbbdc7e559baf8039 SHA512 4d23fee826634ab51e11f2208bb024ffab896143ce8027345e699e669ffb93ecbeffd1aa3c87c1a1f96741f963eecee0b997ad84cee0a37fda14adcaec6fdcb9
 MISC metadata.xml 691 BLAKE2B 512255d8e2d91d64a04fcd5da04fa6db20fbaf66c580491f001716a06c0ff81ff572491cb9b4274229f2312c7235abcbe8e32b6de9e2344b418015c253866f26 SHA512 eeb059ee40101e47a81d4ff871a55295c68891c9bb6a5a2f87d7855e3aea36648f2db77317f3660602d338d6f3f8cf1018cc61f2722fcd6cb78f7f32ac62989b
diff --git a/app-emulation/containers-storage/containers-storage-1.13.5.ebuild b/app-emulation/containers-storage/containers-storage-1.13.5.ebuild
new file mode 100644
index 000000000000..abe57aef3e08
--- /dev/null
+++ b/app-emulation/containers-storage/containers-storage-1.13.5.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGO_VENDOR=(
+	"github.com/pquerna/ffjson e517b90714f7c0eabe6d2e570a5886ae077d6db6"
+)
+
+inherit golang-vcs-snapshot
+
+KEYWORDS="~amd64"
+DESCRIPTION="containers/storage library"
+HOMEPAGE="https://github.com/containers/storage"
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+IUSE="btrfs +device-mapper test"
+EGO_PN="${HOMEPAGE#*//}"
+EGIT_COMMIT="v${PV}"
+SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz
+	${EGO_VENDOR_URI}"
+RDEPEND="
+	btrfs? ( sys-fs/btrfs-progs )
+	device-mapper? ( sys-fs/lvm2:= )"
+DEPEND="${RDEPEND}
+	dev-go/go-md2man
+	test? (
+		sys-fs/btrfs-progs
+		sys-fs/lvm2
+		sys-apps/util-linux
+	)"
+RESTRICT="test? ( userpriv ) !test? ( test )"
+
+src_unpack() {
+	golang-vcs-snapshot_src_unpack
+}
+
+src_prepare() {
+	default
+
+	[[ -f ${S}/src/${EGO_PN}/hack/btrfs_tag.sh ]] || die
+	use btrfs || { echo -e "#!/bin/sh\necho exclude_graphdriver_btrfs" > \
+		"${S}/src/${EGO_PN}/hack/btrfs_tag.sh" || die; }
+
+	[[ -f ${S}/src/${EGO_PN}/hack/libdm_tag.sh ]] || die
+	use device-mapper || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_devicemapper" > \
+		"${S}/src/${EGO_PN}/hack/libdm_tag.sh" || die; }
+
+	sed -e 's:TestChrootUntarPath(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/chrootarchive/archive_test.go" || die
+	sed -e 's:TestTarUntar(:_\0:' \
+		-e 's:TestTarWithOptionsChownOptsAlwaysOverridesIdPair(:_\0:' \
+		-e 's:TestTarWithOptions(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/archive_test.go" || die
+	sed -e 's:TestTarUntarWithXattr(:_\0:' \
+		-e 's:TestTarWithBlockCharFifo(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/archive_unix_test.go" || die
+	sed -e 's:TestTarUntarWithXattr(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/archive_test.go" || die
+	sed -e 's:TestApplyLayer(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/changes_test.go" || die
+	sed -e 's:TestApplyLayerInvalidFilenames(:_\0:' \
+		-e 's:TestApplyLayerInvalidHardlink(:_\0:' \
+		-e 's:TestApplyLayerInvalidSymlink(:_\0:' \
+		-e 's:TestApplyLayerWhiteouts(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/diff_test.go" || die
+	sed -e 's:TestCopyCaseE(:_\0:' \
+		-e 's:TestCopyCaseEFSym(:_\0:' \
+		-e 's:TestCopyCaseG(:_\0:' \
+		-e 's:TestCopyCaseGFSym(:_\0:' \
+		-e 's:TestCopyCaseH(:_\0:' \
+		-e 's:TestCopyCaseHFSym(:_\0:' \
+		-e 's:TestCopyCaseJ(:_\0:' \
+		-e 's:TestCopyCaseJFSym(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/copy_unix_test.go" || die
+	sed -e 's:TestMount(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/mount/mounter_linux_test.go" || die
+}
+
+src_compile() {
+	export -n GOCACHE XDG_CACHE_HOME #678856
+	mkdir -p "${S}/src/github.com/pquerna" || die
+	ln -s "${S}/src/${EGO_PN}/vendor/github.com/pquerna/ffjson" "${WORKDIR}/${P}/src/github.com/pquerna/ffjson" || die
+	mkdir -p "${S}/bin" || die
+	cd "${S}/bin" || die
+	GOPATH="${S}" GOBIN="${S}/bin" \
+		go build -v -work -x ${EGO_BUILD_FLAGS} "${S}/src/github.com/pquerna/ffjson/ffjson.go" || die
+	GOPATH="${S}" GOBIN="${S}/bin" PATH="${S}/bin:${PATH}" \
+		emake -C "${S}/src/${EGO_PN}" containers-storage docs
+}
+
+src_install() {
+	dobin "${S}/src/${EGO_PN}/${PN}"
+	while read -r -d ''; do
+		mv "${REPLY}" "${REPLY%.1}" || die
+	done < <(find "${S}/src/${EGO_PN}/docs" -name '*.[[:digit:]].1' -print0)
+	find "${S}/src/${EGO_PN}/docs" -name '*.[[:digit:]]' -exec doman '{}' + || die
+}
+
+src_test() {
+	GOPATH="${S}" unshare -m emake -C "${S}/src/${EGO_PN}" FLAGS="-v -work -x" local-test-unit || die
+}