summaryrefslogtreecommitdiff
path: root/app-emulation/libspectrum/libspectrum-1.5.0.ebuild
diff options
context:
space:
mode:
authorV3n3RiX <venerix@redcorelinux.org>2021-03-20 14:27:17 +0000
committerV3n3RiX <venerix@redcorelinux.org>2021-03-20 14:27:17 +0000
commit5bb9ff1ee56d2b5e75e01a7f066d8b0cec84ec02 (patch)
tree66e860a5099bcad013f1cf667255dc372a7c11b3 /app-emulation/libspectrum/libspectrum-1.5.0.ebuild
parent7218e1b46bceac05841e90472501742d905fb3fc (diff)
gentoo resync : 20.03.2021
Diffstat (limited to 'app-emulation/libspectrum/libspectrum-1.5.0.ebuild')
-rw-r--r--app-emulation/libspectrum/libspectrum-1.5.0.ebuild55
1 files changed, 55 insertions, 0 deletions
diff --git a/app-emulation/libspectrum/libspectrum-1.5.0.ebuild b/app-emulation/libspectrum/libspectrum-1.5.0.ebuild
new file mode 100644
index 000000000000..aec492d2edec
--- /dev/null
+++ b/app-emulation/libspectrum/libspectrum-1.5.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Spectrum emulation library"
+HOMEPAGE="http://fuse-emulator.sourceforge.net/libspectrum.php"
+SRC_URI="mirror://sourceforge/fuse-emulator/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="audiofile bzip2 gcrypt zlib"
+
+RDEPEND="dev-libs/glib:2
+ audiofile? ( >=media-libs/audiofile-0.3.6 )
+ bzip2? ( >=app-arch/bzip2-1.0 )
+ gcrypt? ( dev-libs/libgcrypt:0 )
+ zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl
+ virtual/pkgconfig"
+
+PATCHES=(
+ "${FILESDIR}"/remove-local-prefix.patch
+)
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ local myconf=(
+ --disable-static
+ $(use_with audiofile libaudiofile)
+ $(use_with bzip2)
+ $(use_with gcrypt libgcrypt)
+ $(use_with zlib)
+ )
+ econf "${myconf[@]}"
+}
+
+src_test() {
+ # check only builds test executable but doesn't run it
+ emake check
+ ./test/test || die
+}
+
+src_install() {
+ default
+ dodoc doc/*.txt *.txt
+}