gentoo auto-resync : 02:09:2022 - 10:16:01

3 files changed, 345 insertions, 2 deletions

diff --git a/app-emulation/libvirt/Manifest b/app-emulation/libvirt/Manifest
index e1587ba6f564..a0cb96ab2fd3 100644
--- a/app-emulation/libvirt/Manifest
+++ b/app-emulation/libvirt/Manifest
@@ -33,6 +33,8 @@ DIST libvirt-8.4.0.tar.xz 8846528 BLAKE2B 479d7d47a9d711e0240da09eb295f1a644bc4c
 DIST libvirt-8.4.0.tar.xz.asc 833 BLAKE2B 7bfbfc05ce7d95018c07e92d475bc0fddbb0b396132c12defd0205638d22534ba83fea8180345635b9f59b8a10fd3177b1a84ad748f1ddb9e533e11700bd4cbd SHA512 5d85ce4764dc36d940033c5feda59b9cff64844a52e3a25b1b8d0278adbc2378978a7dbe6f577f82bc760d617edc75c4a6ab8e1325a38847e1d40e3bf7c9684b
 DIST libvirt-8.5.0.tar.xz 8886088 BLAKE2B a789b5d4d4f3d359403b53b1b6bdc31ddd8938d12fce3c77e953a30be359a3f75071c385bc8ce3df11ccc7ad682e433c067781948cf107abef84e54d5aadd0d9 SHA512 62b05c5cd58eab0ab2d945b832fd85807aea9b5f12a7ef5d1205fe0edac8d361ba3a9245f60f200a8548c96f718943d4502d87fff87c4495bd1e2637f14aaccf
 DIST libvirt-8.5.0.tar.xz.asc 833 BLAKE2B 2e4ee3309e409fa700b0e09c067d2d7978f5033bc947108012582a9ba4b6a5438a2f419375e10b342dd0082560768eab1913aea86558293abc9a51bdb87111eb SHA512 d05482a7d0ef5649428368553e7a9c49a116435b273179c13248081711ecc2d8fa1f6ad82a3d5ce43efc2afee51718bc3362e483463c61ebd10dbcc41875749e
+DIST libvirt-8.7.0.tar.xz 8937316 BLAKE2B 131d46206662627e952b6daa3ceeab187321ff5fb1984980bc2816dfedf730c6ccd4b5a1cbfb46f33cc9e84508621e2625fa661f06b9e35561e8de52906824e5 SHA512 35d33d0e0dab525e8f0a8a592d286e9d17fc5c5d1ff2fab5af5c40b85248481dd17b5c3daf64e8c6e1b8a93328eebee6ece3e95edacff208a81d8b78dc102d7a
+DIST libvirt-8.7.0.tar.xz.asc 833 BLAKE2B ebea1430670bcb44e9ffb4460388b2ab41e8b409d1513d09ac56b12f379621f5ad39af0dba9691b36220bbed5634ad24b2efda8315b41bb2e7f3f6a65e9b028c SHA512 5ac09b10de74283c474fb80cfe600a171d6b49039df73113702cda565889f6c6919e99aff6ce60538ee7fda52287ef035ee15e8f47e5f724384c6ec474e6bed8
 EBUILD libvirt-7.10.0-r3.ebuild 8817 BLAKE2B 4d17950d3395ded22cd9046f41748ef2bf5cb392b63051a1558ed205b9e24b1107d888dc0393c4f53a9620b9e625bdfeb263d0c79ddd317943d14f2b324d677b SHA512 5f8d9301c0311e8f2702a5171c7c1b72c91cd821b7c51396481f0db0bee77d38b8941016c4813cba231c1c0d75d40a5a2f2001a15bbe9b7ffc1af43fe4f8e1d8
 EBUILD libvirt-7.7.0-r2.ebuild 8730 BLAKE2B 177f5c41fac1d9fc6a7e7c6d992975593aca9aef3d4b327b98278801e30a506c28747dbb96795bf3045a7c195f8d8ec0c7a5f6223be8f3e59ba6d44d69a65d40 SHA512 e7f8060e14246c469723fb4cb78d77de257b5b39af21190855e1efcfaae3654503b28b2b4d965b8fdb04f33f0877436b5ff1845060f0f18ca6a407ecd6780a5d
 EBUILD libvirt-8.0.0-r2.ebuild 8802 BLAKE2B 473763cf6d30b1d9f7132e0430c9af615dd2b8356cc329c5d79ca3afd370f708ec4c1b69f45503d30ccf3582610c2a8ae602128e48082e109cc63bb123bb546f SHA512 e37ec22bf9e856161f51e7492f47c20409c3eb7a184a066fca83c92ee2d17016c1d4d56f2f88feebbcd3228f5ffd14a556728ad9b5ad77adb212c14607da2f86
@@ -41,5 +43,6 @@ EBUILD libvirt-8.2.0.ebuild 8817 BLAKE2B 1f849e58e6fb66c5b732b16b4df83fb73ec36c7
 EBUILD libvirt-8.3.0.ebuild 8948 BLAKE2B 4dffb4d34aafa8a4998ddc3ef9e26b18e5188f1c836ca75d68b75909bae70a9c52a9e03311b08e8e39ee498e243d2557e37f4024e376fc40565f55f778f3c3e7 SHA512 39568ef7a362fa13e7e9958246d02a919174f07381b44fe44134ecc6ef00a1ee81e836e3e12be391bba7e0510aa4651a6816aaaf2f5340f398dea54656e5b248
 EBUILD libvirt-8.4.0.ebuild 8953 BLAKE2B afa854c0c31cf705e401fb5733d52c3ac720c52c62dd7517ef79d791c8e93a71b5f2c1628a49ab9d6e314bdf343304aaf9cb79ec56a5b2cb99309055e7a785f8 SHA512 77c6cac11ece2fd8a01193ab1da4cfaa7ac6f7addc4500054f93a649faac4f119400056c79a835f56e29417fbaa683e7f4dc8b73d03585dadcf8926b6be22ade
 EBUILD libvirt-8.5.0.ebuild 8997 BLAKE2B be5e5afc4b65e4a41a9b2e45766924506c441a2b9fb09e6030a7ae7b53a002d0a7a2211817b8d4231aa47de6a5a6aa5ce045e78a62c21de7c0f7878eaa303288 SHA512 79f6459febb08d1a7c4783c8b59ed384c4bfe64bcad9e00b9577e74c1bbc124aa89661a8ef255227e9af51b0dc71b599bec236ce19b28a6f9fe538792d31e651
-EBUILD libvirt-9999.ebuild 8948 BLAKE2B 4dffb4d34aafa8a4998ddc3ef9e26b18e5188f1c836ca75d68b75909bae70a9c52a9e03311b08e8e39ee498e243d2557e37f4024e376fc40565f55f778f3c3e7 SHA512 39568ef7a362fa13e7e9958246d02a919174f07381b44fe44134ecc6ef00a1ee81e836e3e12be391bba7e0510aa4651a6816aaaf2f5340f398dea54656e5b248
+EBUILD libvirt-8.7.0.ebuild 8952 BLAKE2B 0dac207e98eb645dababc294f06e115d0a57bc8f4581a64fe8ccfa5167a0af955187e8423f21ed1f6a713667f283f9c89222b8be3d71b0d9aade69942a5f5efb SHA512 42a7d1535272d93bd6cccb8d7529933762c2b0aec70e4f299db87bd61fbdd2c11329d2b81d85c27dcabf5ee3c02a14ee3eaf67fed8f60cfc68c97b161399a144
+EBUILD libvirt-9999.ebuild 8947 BLAKE2B 144c415c7ff7366583ebc88ba3f9cf30080b3c6fa74192ad0b254dc75ffe6edf0b19b17dbdb67f57588ce0ce044f48b6e22fe41b24cb1088d52ba26f92895ee1 SHA512 fa69bb9c7c76f2317313a4b42ccf4d454cf404c7ec358308b8abffff81a41a029e6d0ad790830ed2d78f56835f2691397b52e700760b190805b52bf5d751be16
 MISC metadata.xml 3784 BLAKE2B 79ac58c142350e62e237e7245c40f4fd25d8e3c19d308440de66df8e6af46bd8847370fb1bf17dfd36e331fe50bd2114a6ebec7e40544fbd3bc049602e9a8657 SHA512 6a27d14d0b4345ccc2060c39af245673df10460d4844cb2732e82005804706e1c61192a0c26dfc04c3c4dc1225173fb8fb966e4197454433f6d7ed8d5601c84d
diff --git a/app-emulation/libvirt/libvirt-8.7.0.ebuild b/app-emulation/libvirt/libvirt-8.7.0.ebuild
new file mode 100644
index 000000000000..a10d45ea6c5b
--- /dev/null
+++ b/app-emulation/libvirt/libvirt-8.7.0.ebuild
@@ -0,0 +1,340 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Packages which get releases together:
+# app-emacs/nxml-libvirt-schemas
+# dev-python/libvirt-python
+# dev-perl/Sys-Virt
+# app-emulation/libvirt
+# Please bump them together!
+
+PYTHON_COMPAT=( python3_{8..11} )
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/libvirt.org.asc
+inherit meson bash-completion-r1 linux-info python-any-r1 readme.gentoo-r1 tmpfiles verify-sig
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/libvirt/libvirt.git"
+	EGIT_BRANCH="master"
+else
+	SRC_URI="https://libvirt.org/sources/${P}.tar.xz
+		verify-sig? ( https://libvirt.org/sources/${P}.tar.xz.asc )"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="C toolkit to manipulate virtual machines"
+HOMEPAGE="https://www.libvirt.org/ https://gitlab.com/libvirt/libvirt/"
+LICENSE="LGPL-2.1"
+SLOT="0/${PV}"
+IUSE="
+	apparmor audit bash-completion +caps dtrace firewalld fuse glusterfs
+	iscsi iscsi-direct +libvirtd lvm libssh libssh2 lxc nfs nls numa openvz
+	parted pcap policykit +qemu rbd sasl selinux +udev
+	virtualbox +virt-network wireshark-plugins xen zfs
+"
+
+REQUIRED_USE="
+	firewalld? ( virt-network )
+	libvirtd? ( || ( lxc openvz qemu virtualbox xen ) )
+	lxc? ( caps libvirtd )
+	openvz? ( libvirtd )
+	qemu? ( libvirtd )
+	virt-network? ( libvirtd )
+	virtualbox? ( libvirtd )
+	xen? ( libvirtd )"
+
+BDEPEND="
+	app-text/xhtml1
+	dev-lang/perl
+	dev-libs/libxslt
+	dev-perl/XML-XPath
+	dev-python/docutils
+	virtual/pkgconfig
+	net-libs/rpcsvc-proto
+	bash-completion? ( >=app-shells/bash-completion-2.0 )
+	verify-sig? ( sec-keys/openpgp-keys-libvirt )"
+
+# gettext.sh command is used by the libvirt command wrappers, and it's
+# non-optional, so put it into RDEPEND.
+# We can use both libnl:1.1 and libnl:3, but if you have both installed, the
+# package will use 3 by default. Since we don't have slot pinning in an API,
+# we must go with the most recent
+RDEPEND="
+	acct-user/qemu
+	app-misc/scrub
+	>=dev-libs/glib-2.56.0
+	dev-libs/libgcrypt
+	dev-libs/libnl:3
+	>=dev-libs/libxml2-2.9.1
+	>=net-analyzer/openbsd-netcat-1.105-r1
+	>=net-libs/gnutls-3.2.0:=
+	net-libs/libtirpc:=
+	>=net-misc/curl-7.18.0
+	sys-apps/dbus
+	sys-apps/dmidecode
+	sys-devel/gettext
+	>=sys-libs/readline-7.0:=
+	virtual/acl
+	apparmor? ( sys-libs/libapparmor )
+	audit? ( sys-process/audit )
+	caps? ( sys-libs/libcap-ng )
+	dtrace? ( dev-util/systemtap )
+	firewalld? ( >=net-firewall/firewalld-0.6.3 )
+	fuse? ( sys-fs/fuse:= )
+	glusterfs? ( >=sys-cluster/glusterfs-3.4.1 )
+	iscsi? ( >=sys-block/open-iscsi-1.18.0 )
+	iscsi-direct? ( >=net-libs/libiscsi-1.18.0 )
+	libssh? ( >=net-libs/libssh-0.7:= )
+	libssh2? ( >=net-libs/libssh2-1.3 )
+	lvm? ( >=sys-fs/lvm2-2.02.48-r2[-device-mapper-only(-)] )
+	lxc? ( !sys-apps/systemd[cgroup-hybrid(-)] )
+	nfs? ( net-fs/nfs-utils )
+	numa? (
+		>sys-process/numactl-2.0.2
+		sys-process/numad
+	)
+	parted? (
+		>=sys-block/parted-1.8[device-mapper]
+		sys-fs/lvm2[-device-mapper-only(-)]
+	)
+	pcap? ( >=net-libs/libpcap-1.8.0 )
+	policykit? (
+		acct-group/libvirt
+		>=sys-auth/polkit-0.9
+	)
+	qemu? (
+		>=app-emulation/qemu-4.2
+		>=dev-libs/yajl-2.0.3:=
+	)
+	rbd? ( sys-cluster/ceph )
+	sasl? ( >=dev-libs/cyrus-sasl-2.1.26 )
+	selinux? ( >=sys-libs/libselinux-2.0.85 )
+	virt-network? (
+		net-dns/dnsmasq[dhcp,ipv6(+),script]
+		net-firewall/ebtables
+		>=net-firewall/iptables-1.4.10[ipv6(+)]
+		net-misc/radvd
+		sys-apps/iproute2[-minimal]
+	)
+	wireshark-plugins? ( >=net-analyzer/wireshark-2.6.0:= )
+	xen? (
+		>=app-emulation/xen-4.9.0
+		app-emulation/xen-tools:=
+	)
+	udev? (
+		virtual/libudev:=
+		>=x11-libs/libpciaccess-0.10.9
+	)
+	zfs? ( sys-fs/zfs )
+	kernel_linux? ( sys-apps/util-linux )"
+DEPEND="${BDEPEND}
+	${RDEPEND}
+	${PYTHON_DEPS}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-6.0.0-fix_paths_in_libvirt-guests_sh.patch
+	"${FILESDIR}"/${PN}-8.2.0-do-not-use-sysconfig.patch
+	"${FILESDIR}"/${PN}-8.2.0-fix-paths-for-apparmor.patch
+)
+
+pkg_setup() {
+	# Check kernel configuration:
+	CONFIG_CHECK=""
+	use fuse && CONFIG_CHECK+="
+		~FUSE_FS"
+
+	use lvm && CONFIG_CHECK+="
+		~BLK_DEV_DM
+		~DM_MULTIPATH
+		~DM_SNAPSHOT"
+
+	use lxc && CONFIG_CHECK+="
+		~BLK_CGROUP
+		~CGROUP_CPUACCT
+		~CGROUP_DEVICE
+		~CGROUP_FREEZER
+		~CGROUP_NET_PRIO
+		~CGROUP_PERF
+		~CGROUPS
+		~CGROUP_SCHED
+		~CPUSETS
+		~IPC_NS
+		~MACVLAN
+		~NAMESPACES
+		~NET_CLS_CGROUP
+		~NET_NS
+		~PID_NS
+		~POSIX_MQUEUE
+		~SECURITYFS
+		~USER_NS
+		~UTS_NS
+		~VETH
+		~!GRKERNSEC_CHROOT_MOUNT
+		~!GRKERNSEC_CHROOT_DOUBLE
+		~!GRKERNSEC_CHROOT_PIVOT
+		~!GRKERNSEC_CHROOT_CHMOD
+		~!GRKERNSEC_CHROOT_CAPS"
+
+	kernel_is lt 4 7 && use lxc && CONFIG_CHECK+="
+		~DEVPTS_MULTIPLE_INSTANCES"
+
+	use virt-network && CONFIG_CHECK+="
+		~BRIDGE_EBT_MARK_T
+		~BRIDGE_NF_EBTABLES
+		~NETFILTER_ADVANCED
+		~NETFILTER_XT_CONNMARK
+		~NETFILTER_XT_MARK
+		~NETFILTER_XT_TARGET_CHECKSUM
+		~IP_NF_FILTER
+		~IP_NF_MANGLE
+		~IP_NF_NAT
+		~IP_NF_TARGET_MASQUERADE
+		~IP6_NF_FILTER
+		~IP6_NF_MANGLE
+		~IP6_NF_NAT"
+	# Bandwidth Limiting Support
+	use virt-network && CONFIG_CHECK+="
+		~BRIDGE_EBT_T_NAT
+		~IP_NF_TARGET_REJECT
+		~NET_ACT_POLICE
+		~NET_CLS_FW
+		~NET_CLS_U32
+		~NET_SCH_HTB
+		~NET_SCH_INGRESS
+		~NET_SCH_SFQ"
+
+	ERROR_USER_NS="Optional depending on LXC configuration."
+
+	if [[ -n ${CONFIG_CHECK} ]]; then
+		linux-info_pkg_setup
+	fi
+
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	touch "${S}/.mailmap" || die
+
+	default
+	python_fix_shebang .
+
+	# Skip fragile tests which relies on pristine environment
+	# (Breaks because of sandbox environment variables)
+	# bug #802876
+	sed -i -e "/commandtest/d" tests/meson.build || die
+
+	# Tweak the init script:
+	cp "${FILESDIR}/libvirtd.init-r19" "${S}/libvirtd.init" || die
+	sed -e "s/USE_FLAG_FIREWALLD/$(usex firewalld 'need firewalld' '')/" \
+		-i "${S}/libvirtd.init" || die "sed failed"
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature apparmor)
+		$(meson_feature apparmor apparmor_profiles)
+		$(meson_feature audit)
+		$(meson_feature caps capng)
+		$(meson_feature dtrace)
+		$(meson_feature firewalld)
+		$(meson_feature fuse)
+		$(meson_feature glusterfs)
+		$(meson_feature glusterfs storage_gluster)
+		$(meson_feature iscsi storage_iscsi)
+		$(meson_feature iscsi-direct storage_iscsi_direct)
+		$(meson_feature libvirtd driver_libvirtd)
+		$(meson_feature libssh)
+		$(meson_feature libssh2)
+		$(meson_feature lvm storage_lvm)
+		$(meson_feature lvm storage_mpath)
+		$(meson_feature lxc driver_lxc)
+		$(meson_feature nls)
+		$(meson_feature numa numactl)
+		$(meson_feature numa numad)
+		$(meson_feature openvz driver_openvz)
+		$(meson_feature parted storage_disk)
+		$(meson_feature pcap libpcap)
+		$(meson_feature policykit polkit)
+		$(meson_feature qemu driver_qemu)
+		$(meson_feature qemu yajl)
+		$(meson_feature rbd storage_rbd)
+		$(meson_feature sasl)
+		$(meson_feature selinux)
+		$(meson_feature udev)
+		$(meson_feature virt-network driver_network)
+		$(meson_feature virtualbox driver_vbox)
+		$(meson_feature wireshark-plugins wireshark_dissector)
+		$(meson_feature xen driver_libxl)
+		$(meson_feature zfs storage_zfs)
+
+		-Dnetcf=disabled
+		-Dsanlock=disabled
+
+		-Ddriver_esx=enabled
+		-Dinit_script=systemd
+		-Dqemu_user=$(usex caps qemu root)
+		-Dqemu_group=$(usex caps qemu root)
+		-Ddriver_remote=enabled
+		-Dstorage_fs=enabled
+		-Ddriver_vmware=enabled
+
+		--localstatedir="${EPREFIX}/var"
+		-Drunstatedir="${EPREFIX}/run"
+		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	export VIR_TEST_DEBUG=1
+	# Don't run the syntax check tests, they're fragile and not relevant
+	# to us downstream anyway.
+	# We also crank up the timeout (as Fedora does) just to preempt failures
+	# on slower arches.
+	meson_src_test --no-suite syntax-check --timeout-multiplier 10
+}
+
+src_install() {
+	meson_src_install
+
+	# Depending on configuration option, libvirt will create some bogus
+	# directoreis. They are either not used, or libvirtd is able to create
+	# them on demand, so let's remove them.
+	#
+	# Note, we are using -f here so that rm does not fail or warn if the
+	# directory is nonexistent.
+	rm -rf "${D}"/etc/sysconfig
+	rm -rf "${D}"/var
+	rm -rf "${D}"/run
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+
+	newtmpfiles "${FILESDIR}"/libvirtd.tmpfiles.conf libvirtd.conf
+
+	newinitd "${S}/libvirtd.init" libvirtd
+	newinitd "${FILESDIR}/libvirt-guests.init-r4" libvirt-guests
+	newinitd "${FILESDIR}/virtlockd.init-r2" virtlockd
+	newinitd "${FILESDIR}/virtlogd.init-r2" virtlogd
+
+	newconfd "${FILESDIR}/libvirtd.confd-r5" libvirtd
+	newconfd "${FILESDIR}/libvirt-guests.confd" libvirt-guests
+
+	DOC_CONTENTS=$(<"${FILESDIR}/README.gentoo-r3")
+	DISABLE_AUTOFORMATTING=true
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
+		touch "${ROOT}"/etc/libvirt/qemu/networks/default.xml || die
+	fi
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+	tmpfiles_process libvirtd.conf
+	readme.gentoo_print_elog
+}
diff --git a/app-emulation/libvirt/libvirt-9999.ebuild b/app-emulation/libvirt/libvirt-9999.ebuild
index 6128a61b974d..2fa520a81044 100644
--- a/app-emulation/libvirt/libvirt-9999.ebuild
+++ b/app-emulation/libvirt/libvirt-9999.ebuild
@@ -105,7 +105,7 @@ RDEPEND="
 		>=sys-auth/polkit-0.9
 	)
 	qemu? (
-		>=app-emulation/qemu-2.11
+		>=app-emulation/qemu-4.2
 		>=dev-libs/yajl-2.0.3:=
 	)
 	rbd? ( sys-cluster/ceph )