gentoo auto-resync : 02:08:2023 - 22:51:19

3 files changed, 366 insertions, 0 deletions

diff --git a/app-emulation/Manifest.gz b/app-emulation/Manifest.gz
index f5bf5c34d18d..3248dad3eb2e 100644
--- a/app-emulation/Manifest.gz
+++ b/app-emulation/Manifest.gz
diff --git a/app-emulation/libvirt/Manifest b/app-emulation/libvirt/Manifest
index ab1230d24585..55acb295ddff 100644
--- a/app-emulation/libvirt/Manifest
+++ b/app-emulation/libvirt/Manifest
@@ -19,8 +19,11 @@ DIST libvirt-9.4.0.tar.xz 9250724 BLAKE2B 837a6eef509a43a0cd25a2ecaac9de95f21e90
 DIST libvirt-9.4.0.tar.xz.asc 833 BLAKE2B 3a31f4097d8684a3a5e4b696c9bb49316a07c611a0cf1703e18653536af93d018ec44cbe5d0ce031e6f2c23a7c72691ded4c219faafa4bc770ad0dd7b616d0ce SHA512 710861b6b1c866be452e2da18a631076ad3ca3fbeb1728e561de08b34d16d2b49a0c390e7fa36eb35d0dc58fa35d5866ea6c573c84e9312b02880cdb969f7342
 DIST libvirt-9.5.0.tar.xz 9261176 BLAKE2B 9c270f782bb74194f209251d6397537182949e97877238bd96b36256b14000998d7b8ad2d4bccad5b44c54a69a21b0be6f60665b3f3bab5cd129e4cfce39a264 SHA512 d8c40281856a60ba2a22a7a64721c4baee1803235227a973a22465aacfb26f674dc65045b87d0dcd183be324cb65408f253b4d72c2ed494fb809e98772eea2e3
 DIST libvirt-9.5.0.tar.xz.asc 833 BLAKE2B 48e935f3509b05403a742119657983f4708a26637af1ec6b622ff82ae5d2507ff935cdf113ade37b643b2bca49ad56bfd1eba7809349a17634e4779d25edbd96 SHA512 794e7be683e61da963b96ac6185e4abb65a44578e00fa14073a0d6c7d98973c4fa5038a0a905f822a6d2f8fd1b201145714b0137adf936c6d56df79523a08b9e
+DIST libvirt-9.6.0.tar.xz 9282400 BLAKE2B a58f2dea7a3051bb7a69678bd1e1dac9123892b2ca7ee6b204bda1a0a3c8fd2d210b2295b300bb88fab86dfddb3d7472d495ff4c10af84bb53b7662190cf17c4 SHA512 654d22cc71926715e103313f01a4f117a19dfcf3087ffe714cf2114dbc88e42ac33cc6c100c61e60f76f13468ff5f369b157748ca6cd69c4d504d4de6b6e44b4
+DIST libvirt-9.6.0.tar.xz.asc 833 BLAKE2B c8eb984dfb797dad5c09a1aea28b835f43f14ee560548df5d3514efab14b0c4df37c964caa6ec092751a804f998d48b89cdddb03172a6d19de82b649774212b5 SHA512 8f1cb80ecddeaed137c2a381be9c324a08aa661d629c56667ef0080b140000f288ce33491c3ebdd286f490b6935ce460cb4dd7b5ec694f4636d6fff2d621ca88
 EBUILD libvirt-9.3.0.ebuild 9338 BLAKE2B 199fe95d127cff893f2134bcf6cb5bc6226b505e576959f7495ffa6781cc4732128448f77d90356ad6de2527a2d94e2a0d32ae9ca6ecf394604980c7d982bf34 SHA512 0557c857c21bdd7237ce6dc6b13f229aa3528061bde1756ac401e3f2fb296c79d7570aaec8572b1b6e61e2aaa0134a0f823437dd05d5de0cb9f34649865f0e09
 EBUILD libvirt-9.4.0-r3.ebuild 9398 BLAKE2B df2befc323dac346e566e01173956e4a314c2881896c1c4de558d998797b36ffeee908c81e1031dc6023481f65bbe22b63a9d8b2d84c9692e1a3a936a52b84e1 SHA512 1aaa65e207ff046e7b978604cda547c5d8fb5abb7b03c5777bcd74d3cc48328930c6ddad51d6d78d05d39ccbe2de19db32671ceb1c62ed671bd74eb3ebbc1c47
 EBUILD libvirt-9.5.0.ebuild 9400 BLAKE2B 27447d18b321a9d69a4a8d4d9baf827ac5544866a10420720d26da870c3751e522fecc0e065280b41b8633db0fc9797e9a137fe5dab90cc5af5f2ff130a3ef71 SHA512 51f89121a3757f3c38ab8538c19186de9e204a37e2554d196d0bb32f8d03b7e4d987a52e2bedb78d80b5f132022e81d6e7572e173da1946bd79435de18ef3007
+EBUILD libvirt-9.6.0.ebuild 9400 BLAKE2B 9b0ed520dd0ece1a4643c7bd21299544efb7e36e20939150abc674e45968e0402f270bcf5cbd001ae4cd77523fda000939bc536ab5b68768452b22bfa05e4039 SHA512 2aa1a8383d8a88bfc6496478c585069994cf82635f6d164bc8ce72012db26f91b4f9bb855212ab3a03ddde92419fbbb7e9b7814179876d544351dcb0bb6d07ae
 EBUILD libvirt-9999.ebuild 9400 BLAKE2B 9b0ed520dd0ece1a4643c7bd21299544efb7e36e20939150abc674e45968e0402f270bcf5cbd001ae4cd77523fda000939bc536ab5b68768452b22bfa05e4039 SHA512 2aa1a8383d8a88bfc6496478c585069994cf82635f6d164bc8ce72012db26f91b4f9bb855212ab3a03ddde92419fbbb7e9b7814179876d544351dcb0bb6d07ae
 MISC metadata.xml 3729 BLAKE2B 2e68676afb3820c7b8cd3d76b0a5c42886e246fc6b440ce49c71cbe60c124cdccd4ed8fb97f7153529b758d56dfba98b6a98a31b2fbff7e738f52bce796a3476 SHA512 0dfe519af8b740de9d41b1e2c40133026718a782b654a261c54cbe22b5f694cda8b73036c59411317757b73c40acaea77f70d7ab86ae8325e78d61151e6c64f1
diff --git a/app-emulation/libvirt/libvirt-9.6.0.ebuild b/app-emulation/libvirt/libvirt-9.6.0.ebuild
new file mode 100644
index 000000000000..4adcd0b92658
--- /dev/null
+++ b/app-emulation/libvirt/libvirt-9.6.0.ebuild
@@ -0,0 +1,363 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Packages which get releases together:
+# app-emacs/nxml-libvirt-schemas
+# dev-python/libvirt-python
+# dev-perl/Sys-Virt
+# app-emulation/libvirt
+# Please bump them together!
+
+PYTHON_COMPAT=( python3_{9..11} )
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/libvirt.org.asc
+inherit meson linux-info python-any-r1 readme.gentoo-r1 tmpfiles verify-sig
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/libvirt/libvirt.git"
+	EGIT_BRANCH="master"
+else
+	SRC_URI="https://libvirt.org/sources/${P}.tar.xz
+		verify-sig? ( https://libvirt.org/sources/${P}.tar.xz.asc )"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="C toolkit to manipulate virtual machines"
+HOMEPAGE="https://www.libvirt.org/ https://gitlab.com/libvirt/libvirt/"
+LICENSE="LGPL-2.1"
+SLOT="0/${PV}"
+IUSE="
+	apparmor audit bash-completion +caps dtrace firewalld fuse glusterfs
+	iscsi iscsi-direct +libvirtd lvm libssh libssh2 lxc nfs nls numa openvz
+	parted pcap policykit +qemu rbd sasl selinux test +udev
+	virtualbox +virt-network wireshark-plugins xen zfs
+"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+	firewalld? ( virt-network )
+	libvirtd? ( || ( lxc openvz qemu virtualbox xen ) )
+	lxc? ( caps libvirtd )
+	openvz? ( libvirtd )
+	qemu? ( libvirtd )
+	virt-network? ( libvirtd )
+	virtualbox? ( libvirtd )
+	xen? ( libvirtd )"
+
+BDEPEND="
+	app-text/xhtml1
+	dev-lang/perl
+	dev-libs/libxslt
+	dev-perl/XML-XPath
+	dev-python/docutils
+	virtual/pkgconfig
+	net-libs/rpcsvc-proto
+	bash-completion? ( >=app-shells/bash-completion-2.0 )
+	verify-sig? ( sec-keys/openpgp-keys-libvirt )"
+
+# gettext.sh command is used by the libvirt command wrappers, and it's
+# non-optional, so put it into RDEPEND.
+# We can use both libnl:1.1 and libnl:3, but if you have both installed, the
+# package will use 3 by default. Since we don't have slot pinning in an API,
+# we must go with the most recent.
+RDEPEND="
+	acct-user/qemu
+	app-misc/scrub
+	>=dev-libs/glib-2.56.0
+	dev-libs/libgcrypt
+	dev-libs/libnl:3
+	>=dev-libs/libxml2-2.9.1
+	>=net-analyzer/openbsd-netcat-1.105-r1
+	>=net-libs/gnutls-3.2.0:=
+	net-libs/libtirpc:=
+	>=net-misc/curl-7.18.0
+	sys-apps/dbus
+	sys-apps/dmidecode
+	sys-devel/gettext
+	>=sys-libs/readline-7.0:=
+	virtual/acl
+	apparmor? ( sys-libs/libapparmor )
+	audit? ( sys-process/audit )
+	caps? ( sys-libs/libcap-ng )
+	dtrace? ( dev-util/systemtap )
+	firewalld? ( >=net-firewall/firewalld-0.6.3 )
+	fuse? ( sys-fs/fuse:= )
+	glusterfs? ( >=sys-cluster/glusterfs-3.4.1 )
+	iscsi? ( >=sys-block/open-iscsi-1.18.0 )
+	iscsi-direct? ( >=net-libs/libiscsi-1.18.0 )
+	libssh? ( >=net-libs/libssh-0.8.1:= )
+	libssh2? ( >=net-libs/libssh2-1.3 )
+	lvm? ( >=sys-fs/lvm2-2.02.48-r2[lvm] )
+	lxc? ( !sys-apps/systemd[cgroup-hybrid(-)] )
+	nfs? ( net-fs/nfs-utils )
+	numa? (
+		>sys-process/numactl-2.0.2
+		sys-process/numad
+	)
+	parted? (
+		>=sys-block/parted-1.8[device-mapper]
+		sys-fs/lvm2[lvm]
+	)
+	pcap? ( >=net-libs/libpcap-1.8.0 )
+	policykit? (
+		acct-group/libvirt
+		>=sys-auth/polkit-0.9
+	)
+	qemu? (
+		>=app-emulation/qemu-4.2
+		app-crypt/swtpm
+		>=dev-libs/yajl-2.0.3:=
+	)
+	rbd? ( sys-cluster/ceph )
+	sasl? ( >=dev-libs/cyrus-sasl-2.1.26 )
+	selinux? ( >=sys-libs/libselinux-2.0.85 )
+	virt-network? (
+		net-dns/dnsmasq[dhcp,ipv6(+),script]
+		net-firewall/ebtables
+		>=net-firewall/iptables-1.4.10[ipv6(+)]
+		net-misc/radvd
+		sys-apps/iproute2[-minimal]
+	)
+	wireshark-plugins? ( >=net-analyzer/wireshark-2.6.0:= )
+	xen? (
+		>=app-emulation/xen-4.9.0
+		app-emulation/xen-tools:=
+	)
+	udev? (
+		virtual/libudev:=
+		>=x11-libs/libpciaccess-0.10.9
+	)
+	zfs? ( sys-fs/zfs )
+	kernel_linux? ( sys-apps/util-linux )"
+DEPEND="
+	${BDEPEND}
+	${RDEPEND}
+	${PYTHON_DEPS}
+"
+# The 'circular' dependency on dev-python/libvirt-python is because of
+# virt-qemu-qmp-proxy.
+PDEPEND="
+	qemu? ( dev-python/libvirt-python )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-9.4.0-fix_paths_in_libvirt-guests_sh.patch
+	"${FILESDIR}"/${PN}-9.4.0-do-not-use-sysconfig.patch
+	"${FILESDIR}"/${PN}-9.6.0-fix-paths-for-apparmor.patch
+)
+
+pkg_setup() {
+	# Check kernel configuration:
+	CONFIG_CHECK=""
+	use fuse && CONFIG_CHECK+="
+		~FUSE_FS"
+
+	use lvm && CONFIG_CHECK+="
+		~BLK_DEV_DM
+		~DM_MULTIPATH
+		~DM_SNAPSHOT"
+
+	use lxc && CONFIG_CHECK+="
+		~BLK_CGROUP
+		~CGROUP_CPUACCT
+		~CGROUP_DEVICE
+		~CGROUP_FREEZER
+		~CGROUP_NET_PRIO
+		~CGROUP_PERF
+		~CGROUPS
+		~CGROUP_SCHED
+		~CPUSETS
+		~IPC_NS
+		~MACVLAN
+		~NAMESPACES
+		~NET_CLS_CGROUP
+		~NET_NS
+		~PID_NS
+		~POSIX_MQUEUE
+		~SECURITYFS
+		~USER_NS
+		~UTS_NS
+		~VETH
+		~!GRKERNSEC_CHROOT_MOUNT
+		~!GRKERNSEC_CHROOT_DOUBLE
+		~!GRKERNSEC_CHROOT_PIVOT
+		~!GRKERNSEC_CHROOT_CHMOD
+		~!GRKERNSEC_CHROOT_CAPS"
+
+	kernel_is lt 4 7 && use lxc && CONFIG_CHECK+="
+		~DEVPTS_MULTIPLE_INSTANCES"
+
+	use virt-network && CONFIG_CHECK+="
+		~BRIDGE_EBT_MARK_T
+		~BRIDGE_NF_EBTABLES
+		~NETFILTER_ADVANCED
+		~NETFILTER_XT_CONNMARK
+		~NETFILTER_XT_MARK
+		~NETFILTER_XT_TARGET_CHECKSUM
+		~IP_NF_FILTER
+		~IP_NF_MANGLE
+		~IP_NF_NAT
+		~IP6_NF_FILTER
+		~IP6_NF_MANGLE
+		~IP6_NF_NAT"
+
+	# This was renamed in kernel commit v5.2-rc1~133^2~174^2~6
+	if use virt-network ; then
+		if kernel_is -lt 5 2 ; then
+			CONFIG_CHECK+="
+			~IP_NF_TARGET_MASQUERADE"
+		else
+			CONFIG_CHECK+="
+			~NETFILTER_XT_TARGET_MASQUERADE"
+		fi
+	fi
+
+	# Bandwidth Limiting Support
+	use virt-network && CONFIG_CHECK+="
+		~BRIDGE_EBT_T_NAT
+		~IP_NF_TARGET_REJECT
+		~NET_ACT_POLICE
+		~NET_CLS_FW
+		~NET_CLS_U32
+		~NET_SCH_HTB
+		~NET_SCH_INGRESS
+		~NET_SCH_SFQ"
+
+	ERROR_USER_NS="Optional depending on LXC configuration."
+
+	if [[ -n ${CONFIG_CHECK} ]]; then
+		linux-info_pkg_setup
+	fi
+
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	touch "${S}/.mailmap" || die
+
+	default
+	python_fix_shebang .
+
+	# Skip fragile tests which relies on pristine environment
+	# (Breaks because of sandbox environment variables)
+	# bug #802876
+	sed -i -e "/commandtest/d" tests/meson.build || die
+
+	# Tweak the init script:
+	cp "${FILESDIR}/libvirtd.init-r19" "${S}/libvirtd.init" || die
+	sed -e "s/USE_FLAG_FIREWALLD/$(usex firewalld 'need firewalld' '')/" \
+		-i "${S}/libvirtd.init" || die "sed failed"
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature apparmor)
+		$(meson_feature apparmor apparmor_profiles)
+		$(meson_feature audit)
+		$(meson_feature caps capng)
+		$(meson_feature dtrace)
+		$(meson_feature firewalld)
+		$(meson_feature fuse)
+		$(meson_feature glusterfs)
+		$(meson_feature glusterfs storage_gluster)
+		$(meson_feature iscsi storage_iscsi)
+		$(meson_feature iscsi-direct storage_iscsi_direct)
+		$(meson_feature libvirtd driver_libvirtd)
+		$(meson_feature libssh)
+		$(meson_feature libssh2)
+		$(meson_feature lvm storage_lvm)
+		$(meson_feature lvm storage_mpath)
+		$(meson_feature lxc driver_lxc)
+		$(meson_feature nls)
+		$(meson_feature numa numactl)
+		$(meson_feature numa numad)
+		$(meson_feature openvz driver_openvz)
+		$(meson_feature parted storage_disk)
+		$(meson_feature pcap libpcap)
+		$(meson_feature policykit polkit)
+		$(meson_feature qemu driver_qemu)
+		$(meson_feature qemu yajl)
+		$(meson_feature rbd storage_rbd)
+		$(meson_feature sasl)
+		$(meson_feature selinux)
+		$(meson_feature test tests)
+		$(meson_feature udev)
+		$(meson_feature virt-network driver_network)
+		$(meson_feature virtualbox driver_vbox)
+		$(meson_feature wireshark-plugins wireshark_dissector)
+		$(meson_feature xen driver_libxl)
+		$(meson_feature zfs storage_zfs)
+
+		-Dnetcf=disabled
+		-Dsanlock=disabled
+		-Dopenwsman=disabled
+
+		-Ddriver_esx=enabled
+		-Dinit_script=systemd
+		-Dqemu_user=$(usex caps qemu root)
+		-Dqemu_group=$(usex caps qemu root)
+		-Ddriver_remote=enabled
+		-Dstorage_fs=enabled
+		-Ddriver_vmware=enabled
+
+		--localstatedir="${EPREFIX}/var"
+		-Dinitconfdir="${EPREFIX}/etc/systemd"
+		-Drunstatedir="${EPREFIX}/run"
+		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	export VIR_TEST_DEBUG=1
+	# Don't run the syntax check tests, they're fragile and not relevant
+	# to us downstream anyway.
+	# We also crank up the timeout (as Fedora does) just to preempt failures
+	# on slower arches.
+	meson_src_test --no-suite syntax-check --timeout-multiplier 10
+}
+
+src_install() {
+	meson_src_install
+
+	# Depending on configuration option, libvirt will create some bogus
+	# directoreis. They are either not used, or libvirtd is able to create
+	# them on demand, so let's remove them.
+	#
+	# Note, we are using -f here so that rm does not fail or warn if the
+	# directory is nonexistent.
+	rm -rf "${D}"/etc/sysconfig
+	rm -rf "${D}"/var
+	rm -rf "${D}"/run
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+
+	newtmpfiles "${FILESDIR}"/libvirtd.tmpfiles.conf libvirtd.conf
+
+	newinitd "${S}/libvirtd.init" libvirtd
+	newinitd "${FILESDIR}/libvirt-guests.init-r4" libvirt-guests
+	newinitd "${FILESDIR}/virtlockd.init-r2" virtlockd
+	newinitd "${FILESDIR}/virtlogd.init-r2" virtlogd
+
+	newconfd "${FILESDIR}/libvirtd.confd-r5" libvirtd
+	newconfd "${FILESDIR}/libvirt-guests.confd" libvirt-guests
+
+	DOC_CONTENTS=$(<"${FILESDIR}/README.gentoo-r3")
+	DISABLE_AUTOFORMATTING=true
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
+		touch "${ROOT}"/etc/libvirt/qemu/networks/default.xml || die
+	fi
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+	tmpfiles_process libvirtd.conf
+	readme.gentoo_print_elog
+}