gentoo auto-resync : 11:12:2023 - 17:14:47

3 files changed, 89 insertions, 0 deletions

diff --git a/app-i18n/fcitx-gtk/Manifest b/app-i18n/fcitx-gtk/Manifest
new file mode 100644
index 000000000000..5a5f11172316
--- /dev/null
+++ b/app-i18n/fcitx-gtk/Manifest
@@ -0,0 +1,3 @@
+DIST fcitx-gtk-5.1.0.tar.xz 54128 BLAKE2B d6c4f6607067955b260a3a53b29bad210b6358151ae0542ff5d414e8fd75aebc51c9d616f845e4c47e28bd7f18874e0bfb62a8a288a7ae66d0bab9d2c54ba9d6 SHA512 6b042714a4facb253d0e5cce119239e923511b809681909b63a2c1d47ecfc403672522c24f9ac91c12ed3e0b61c5023ec9e340d51f6aefc3f61fa1a1fbe39dfc
+EBUILD fcitx-gtk-5.1.0.ebuild 1443 BLAKE2B 617b6e79885a6bbd50f1ff79e0f0bb4fec18030e028b463c8b59865c0f2fdece8bfa14d09d00ad8c8529a3145eb3bdb1baf026792da670a5fea521c1065a35ef SHA512 e5ebe0273c753dbdc3c69a3aab28294c8dfd130c947ed4e812833c14133460d2d6fb5b445681c250ffcd6f7d174664f486d6b5723a89454cd692169498f6545b
+MISC metadata.xml 872 BLAKE2B 88c8dd56d42438578ce739932b66b9b04e7ee647ea859187387b6d58825973e1b147d60429632caf1af61afdcaba793071d7d0c8222128c5b54647b1b754b593 SHA512 0048fa62e7228efd07624db98aea00d5e809f3b553c7f1fdded8a7ed906afc6feb60004842da882f45dda844c00c58b85cec9f31fac646085e9469010bb352c2
diff --git a/app-i18n/fcitx-gtk/fcitx-gtk-5.1.0.ebuild b/app-i18n/fcitx-gtk/fcitx-gtk-5.1.0.ebuild
new file mode 100644
index 000000000000..1ff0c65b1539
--- /dev/null
+++ b/app-i18n/fcitx-gtk/fcitx-gtk-5.1.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="fcitx5-gtk"
+
+inherit cmake gnome2-utils xdg
+
+DESCRIPTION="Gtk im module for fcitx5 and glib based dbus client library"
+HOMEPAGE="https://github.com/fcitx/fcitx5-gtk"
+SRC_URI="https://download.fcitx-im.org/fcitx5/${MY_PN}/${MY_PN}-${PV}.tar.xz -> ${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE="gtk2 +gtk3 +gtk4 +introspection +snooper onlyplugin wayland +X"
+REQUIRED_USE="|| ( gtk2 gtk3 gtk4 )"
+
+RDEPEND="
+	app-i18n/fcitx:5
+	>=dev-libs/glib-2.56
+	x11-libs/libxkbcommon
+	gtk2? ( x11-libs/gtk+:2 )
+	gtk3? ( x11-libs/gtk+:3[wayland?,X?] )
+	gtk4? ( gui-libs/gtk:4[wayland?,X?] )
+	introspection? ( dev-libs/gobject-introspection )
+	X? ( x11-libs/libX11 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	kde-frameworks/extra-cmake-modules:0
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_GTK2_IM_MODULE=$(usex gtk2)
+		-DENABLE_GTK3_IM_MODULE=$(usex gtk3)
+		-DENABLE_GTK4_IM_MODULE=$(usex gtk4)
+		-DENABLE_SNOOPER=$(usex snooper)
+		-DENABLE_GIR=$(usex introspection)
+		-DBUILD_ONLY_PLUGIN=$(usex onlyplugin)
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	use gtk2 && gnome2_query_immodules_gtk2
+	use gtk3 && gnome2_query_immodules_gtk3
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	use gtk2 && gnome2_query_immodules_gtk2
+	use gtk3 && gnome2_query_immodules_gtk3
+}
diff --git a/app-i18n/fcitx-gtk/metadata.xml b/app-i18n/fcitx-gtk/metadata.xml
new file mode 100644
index 000000000000..f92aad4b3725
--- /dev/null
+++ b/app-i18n/fcitx-gtk/metadata.xml
@@ -0,0 +1,26 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person" proxied="yes">
+		<email>tanekliang@gmail.com</email>
+		<name>Yongxiang Liang</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>cjk@gentoo.org</email>
+		<name>Cjk</name>
+	</maintainer>
+	<use>
+		<flag name="gtk2">Install input method module for GTK+ 2</flag>
+		<flag name="gtk3">Enable support for GTK+3</flag>
+		<flag name="gtk4">Enable support for GTK 4</flag>
+		<flag name="onlyplugin">Build only plugin</flag>
+		<flag name="snooper">Enable key snooper for gtk app</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">fcitx/fcitx5-gtk</remote-id>
+	</upstream>
+</pkgmetadata>