gentoo resync : 14.07.2018

1 files changed, 51 insertions, 0 deletions

diff --git a/app-i18n/scim-hangul/scim-hangul-0.4.0.ebuild b/app-i18n/scim-hangul/scim-hangul-0.4.0.ebuild
new file mode 100644
index 000000000000..aa37d7ea868e
--- /dev/null
+++ b/app-i18n/scim-hangul/scim-hangul-0.4.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="Hangul IMEngine for SCIM ported from imhangul"
+HOMEPAGE="http://www.scim-im.org/"
+SRC_URI="mirror://sourceforge/scim/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ppc x86"
+IUSE="nls"
+
+RDEPEND="
+	>=app-i18n/scim-0.99.8
+	>=app-i18n/libhangul-0.0.4
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.3.2+gcc-4.3.patch
+	"${FILESDIR}"/${PN}-0.3.2+gcc-4.7.patch
+	"${FILESDIR}"/${PN}-0.4.0+gtk.patch
+)
+
+src_configure() {
+	econf \
+		--disable-skim-support \
+		$(use_enable nls)
+}
+
+src_install() {
+	default
+	dodoc ChangeLog*
+
+	# plugin module, no point in .la files
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	elog
+	elog "To use SCIM with both GTK2 and XIM, you should use the following"
+	elog "in your user startup scripts such as .gnomerc or .xinitrc:"
+	elog
+	elog "LANG='your_language' scim -d"
+	elog "export XMODIFIERS=@im=SCIM"
+	elog
+}