gentoo auto-resync : 03:03:2025 - 19:30:11

2 files changed, 128 insertions, 0 deletions

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 44512b1f21b0..ee65c358aa98 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,9 +1,11 @@
 DIST fastfetch-2.34.1.tar.gz 1168310 BLAKE2B 2b3e617cd2c7b2168ad9844ba907aa533b500cf90b19762c180555967605ed3ba83030e07893adee9ec2f30887ace3f63840fdc62cbad00c7c9d1d9bd9021952 SHA512 026b71c8d6ad5d5683ededf173d4cb2e936b3e934c7f27227fa7c5f665b9628717e90413626a4fab25fa5f5fde50cae6cdeb75621d6a2cac1ca6368c943293de
 DIST fastfetch-2.36.1.tar.gz 1176932 BLAKE2B 0a7727e049de9a5dbb945b171e720ea888c7d7ee77ee145b6122f09cf2933eccde5437ae76f0e89501e38e17edc4349e074747abc7dd4c89b9c1e1005b96197e SHA512 2906b8e6912185a3acdd2b615ff869fa8f44ce0e547ed5529068eb2570ef5c013ed84691e62d613e52f2433595aa4e67859cf89b4116588ba4cb7c7bb7d8bb01
 DIST fastfetch-2.37.0.tar.gz 1185408 BLAKE2B d54145e9e587f5f44be2291d97037d0c17c8d86aa3d0af5423015fa17c7e4a600f708a1eb9de85540b8ba9edc413f7655ccf8c87111683eed8610e0fbb15f97e SHA512 a36540cc1a02b0549d717bd3ccd3738b66cf911c81ec3526caab2ee5ee6e9ceeda3b5da9e4e76c08c2223c9e780a5ab257d9a80eb794e6d33e95b0c68becb31d
+DIST fastfetch-2.38.0.tar.gz 1207024 BLAKE2B 7d3d34416899c19741667d0f1fdc2f5cf8596bd555a3e06910292a51b7d0cdbbe98e4203245d497c350195505fd01cc194cceba395f06edc6fa69761f621452a SHA512 6c4ffebd2999c3882cd31a6e393f78d693c688b67ab62972b70833e24c0fee2f9d79f3b1ea82c6262e71e0b45fcc40f296194ae54beca65a817ccd25cde771d0
 EBUILD fastfetch-0.1.9999.ebuild 3443 BLAKE2B 278037dd445b5d4c04ebb6c0b352f99d0d26f7211745545fb350f440a5b9e640aec786f7ecae0c416bf7d1630b971b9d73121ad0a1a69856abecc88be52a02b2 SHA512 473c0698310206dc7bec63b99828c512d25be4cbf6ebaa78bf40f112abf8f97795ab2531a2a2b331f795a70ff5ebe735b6eabd1e23971ca7eb244f93d24c5ac4
 EBUILD fastfetch-0.2.9999.ebuild 3443 BLAKE2B 278037dd445b5d4c04ebb6c0b352f99d0d26f7211745545fb350f440a5b9e640aec786f7ecae0c416bf7d1630b971b9d73121ad0a1a69856abecc88be52a02b2 SHA512 473c0698310206dc7bec63b99828c512d25be4cbf6ebaa78bf40f112abf8f97795ab2531a2a2b331f795a70ff5ebe735b6eabd1e23971ca7eb244f93d24c5ac4
 EBUILD fastfetch-2.34.1.ebuild 3440 BLAKE2B eb0fd72015c0f51661b8d9937dbd4b2cfe577ac19303f15994678ee15ff83624e77f9a8a20aceb8007bd2d89d604ee9798d07db952a5f7fc772f82014d2cba8c SHA512 676130d3d01971db4a4fa97f06ea6ce86a19476419dfd7c1738f52142c2bfaab4c51b662d4b3d6c917cb6d1a6b5e17153c48696d28426c330adf6db20bc429fb
 EBUILD fastfetch-2.36.1.ebuild 3443 BLAKE2B 3e2289a1c1e1d41f8fb97be96f4c2445880a255f53a5fa50f8ec89d5047f07229be26a851070b71b05ceb3bb77938904e08f1c5eee33bcafaa601c4dd0cebb49 SHA512 e5c9505f6007ad86f818aecf8a20f72439d10941ad14fdcad32a2277bba55aaca6965b218169508ef8d24848996c4974883c54bbb0e2fbf6c0865cbcac749880
 EBUILD fastfetch-2.37.0.ebuild 3443 BLAKE2B 3e2289a1c1e1d41f8fb97be96f4c2445880a255f53a5fa50f8ec89d5047f07229be26a851070b71b05ceb3bb77938904e08f1c5eee33bcafaa601c4dd0cebb49 SHA512 e5c9505f6007ad86f818aecf8a20f72439d10941ad14fdcad32a2277bba55aaca6965b218169508ef8d24848996c4974883c54bbb0e2fbf6c0865cbcac749880
+EBUILD fastfetch-2.38.0.ebuild 3443 BLAKE2B 3e2289a1c1e1d41f8fb97be96f4c2445880a255f53a5fa50f8ec89d5047f07229be26a851070b71b05ceb3bb77938904e08f1c5eee33bcafaa601c4dd0cebb49 SHA512 e5c9505f6007ad86f818aecf8a20f72439d10941ad14fdcad32a2277bba55aaca6965b218169508ef8d24848996c4974883c54bbb0e2fbf6c0865cbcac749880
 MISC metadata.xml 1398 BLAKE2B bba6a400cbf5e68dc779b4f15cf30b477a4837cd57e09fb17cf4c2ca06e05b19d89c9cd3c1063b078b3411a27c5b265e78e21e15e9cb32b1c681bd9a4bab3545 SHA512 018c51650911637fad242e431a2a9bdb017210b9082c0c49ed29e744fc2cba7733617d49721dd9d2519ee24ea61076608154d63e1f67c3ada4a1ef4774be2432
diff --git a/app-misc/fastfetch/fastfetch-2.38.0.ebuild b/app-misc/fastfetch/fastfetch-2.38.0.ebuild
new file mode 100644
index 000000000000..a6fd045ed767
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.38.0.ebuild
@@ -0,0 +1,126 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm elf gnome imagemagick opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.10.0
+	sys-apps/hwdata
+	sys-libs/zlib
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	elf? ( virtual/libelf:= )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? (
+		media-libs/libglvnd[X?]
+		X? ( x11-libs/libX11 )
+	)
+	osmesa? ( media-libs/mesa[osmesa] )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	opengl? ( X? ( x11-base/xorg-proto ) )
+	xcb? ( x11-base/xorg-proto )
+	xrandr? ( x11-base/xorg-proto )
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	chafa? ( imagemagick )
+"
+
+pkg_pretend() {
+	if use X && ! use opengl; then
+		einfo 'USE="X" adds GLX support for USE="opengl"'
+		einfo 'This build with USE="X -opengl" will not include any extra X support.'
+	fi
+}
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local glx=no
+	if use opengl && use X; then
+		glx=yes
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+		-DIS_MUSL=$(usex elibc_musl)
+		-DINSTALL_LICENSE=no
+		-DBUILD_FLASHFETCH=no
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_ELF=$(usex elf)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=${glx}
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}