gentoo resync : 07.10.2018

3 files changed, 174 insertions, 3 deletions

diff --git a/app-office/gnucash/Manifest b/app-office/gnucash/Manifest
index 86d364859cd9..086b185f0b2d 100644
--- a/app-office/gnucash/Manifest
+++ b/app-office/gnucash/Manifest
@@ -3,8 +3,10 @@ AUX gnucash-2.7.4-fix-tests-for-32bit-platforms.patch 1840 BLAKE2B 4de54cb147d56
 AUX gnucash-3.2-no-gui.patch 440 BLAKE2B 223d9527e0f290e73774b39ee25dae2c1740d4ed8b340d5d8cdfde74734ae30ebc391ca4ef8df6b162dd53cfd1b5ae3c7d5cd64446978a86969bb5fcc9ea6440 SHA512 628d38969abd7475f88ed9013d99691768abd11a751205092e04b92183551e0dce2e32f1212f66fde47e83730e1d26addbc47d990478e8a8968f9c9f0bc041bd
 DIST gnucash-2.7.4.tar.bz2 13364512 BLAKE2B 0a552efe5a4f024517c054516eb25b51abb2f934e6fc904afd4b0fb48283f9ebb89583b83b0efefba66d014df16c8997c413d05278d4290c44e4fa2278564b61 SHA512 d096ec2a3907dcd09c936f0a49ef6fb5028a17d2e0ade9e68eae7303530480ce19e08c1864efd862d363fda9ef6343260396b794b3c4ac74544baa2628a310eb
 DIST gnucash-3.2.tar.bz2 13383942 BLAKE2B ce4beb9eab290bbc85c4b3bf68b205a8ebb274056bf10ef1721bce48ec18e4df4b488ce885dc767b4f1e951dabcdc2ba702cb5fe239f249ec50c8d2d1d12a434 SHA512 ef74cbf396096a71316e14500a5b4e57670f9e9c0c5d46f3afe051ccbae2e46a5f14edd8dd805dfb61276b934db286d48ae044160699df82689e2718ed2f7573
+DIST gnucash-3.3.tar.bz2 13440713 BLAKE2B a308af90d8a8e50eb732d29c7eadac1fb75b63006da5bbaa9044039c43c1c17976c6b6fdb1706a08a527b75b1300df3a8ed469151370097b0308a173a170e41b SHA512 4bf0369ca9b3c91c98a0d916f0befc7e5675a246559a6a72dba6592b64f56f3cbd1885b0711e44e8d9cca290be742812763691ae2f639ea31ec534e52e17b3f9
 DIST gtest-1.8.0.tar.gz 1281617 BLAKE2B ac052b4d0eb0d8ded03a8c7dff05177818627b8a51f2dbc2c162b2ee2a5d1323539e7d0d02236d9ebb799995e018f0171c2fdaeb4de3bb339548265e50de79e6 SHA512 1dbece324473e53a83a60601b02c92c089f5d314761351974e097b2cf4d24af4296f9eb8653b6b03b1e363d9c5f793897acae1f0c7ac40149216035c4d395d9d
 EBUILD gnucash-2.7.4-r1.ebuild 3952 BLAKE2B 011a368e9bf441c05aaaf3681ed666151ad7a68fb849c2ceca50079f47b91265f9ef10b2cf10367393f3df5243bd59e76c7a2362c3ff498c855058412112c977 SHA512 9cdf9f7b57fa0eda3d5d3d154b194bb869fc360fdac5049e327eedb9b27d91a2e4022a3388d1c372a6d84f337c7d1be96722603e05ac4028073e6a9b7baaadc2
-EBUILD gnucash-3.2-r2.ebuild 3964 BLAKE2B 8143c1d294c5b5df4cf83f0901919edbd44d2a22909cb09d9bccea15247c3e15ce050a8003f6845e00cf3cb74291f32e8c26700f851407ccbd5a83a5435d862e SHA512 3779398d4db88d1a8263fa4ffa44ca399b79e43fa0d956bedac9945d33bb90f2dc1fecca88c4321bfe1b5f43702cb8e2b49cdb007aea4756a3883099416c785b
+EBUILD gnucash-3.2-r2.ebuild 3959 BLAKE2B 37cdc89d7db8903b4b89332d7f9b47cef47fb29588a443b979a49d43bad5e883158a939898368afc02cae89402b25a7498a5a373c51cb8fb9c5265c7d05c15ae SHA512 97da97ae88ed1aa564ec605d5e8d24852869745521457d98e76adbb4b72a2a28025bcddad413e2f85a2d3f6c4116c40a889438428c9c5197a873e1834077235b
 EBUILD gnucash-3.2.ebuild 3888 BLAKE2B 7c7f0231e94ea7c430c2007968e70cd69c74dbb804f4b8e9858eafffc29e05ad8e2a1528b902294c75115161466ae2558e1149fc8c98a2376bf3f609e742e794 SHA512 b767881302588a21edc469ca1ed91a47a4560a756e099914c23a5907c78b1b9cd615831c3024c1c6f00a4c444b7c1c03d7417e1b9d90aa967c2196ab09d22b06
+EBUILD gnucash-3.3.ebuild 3964 BLAKE2B 8143c1d294c5b5df4cf83f0901919edbd44d2a22909cb09d9bccea15247c3e15ce050a8003f6845e00cf3cb74291f32e8c26700f851407ccbd5a83a5435d862e SHA512 3779398d4db88d1a8263fa4ffa44ca399b79e43fa0d956bedac9945d33bb90f2dc1fecca88c4321bfe1b5f43702cb8e2b49cdb007aea4756a3883099416c785b
 MISC metadata.xml 877 BLAKE2B 0fcba4a83ba82aa6634bc2e3d71da766f2890340e827ba478157fae994456daaecd12722991626069e04086d670a77f156e378a5b0d7b8ee35717561ca944a03 SHA512 1654790fbffc4ec76fc9520221877ad7eaa8fc774f4a05e9e250e44c0fb989081bafcacb018c8d2f6a4787d1794672a87e09c1687919b544a8f1fb36bb449bdc
diff --git a/app-office/gnucash/gnucash-3.2-r2.ebuild b/app-office/gnucash/gnucash-3.2-r2.ebuild
index 52fda92ce402..d582a50930ee 100644
--- a/app-office/gnucash/gnucash-3.2-r2.ebuild
+++ b/app-office/gnucash/gnucash-3.2-r2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -16,7 +16,7 @@ SRC_URI="https://github.com/Gnucash/${PN}/releases/download/${PV}/${P}.tar.bz2
 
 SLOT="0"
 LICENSE="GPL-2"
-KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+KEYWORDS="amd64 ~ppc ~ppc64 x86"
 
 IUSE="aqbanking chipcard debug doc examples gnome-keyring mysql nls ofx postgres
 	  python quotes -register2 sqlite +gui"
diff --git a/app-office/gnucash/gnucash-3.3.ebuild b/app-office/gnucash/gnucash-3.3.ebuild
new file mode 100644
index 000000000000..52fda92ce402
--- /dev/null
+++ b/app-office/gnucash/gnucash-3.3.ebuild
@@ -0,0 +1,169 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# google{test,mock} version
+GV="1.8.0"
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit cmake-utils gnome2-utils python-single-r1 xdg-utils
+
+DESCRIPTION="A personal finance manager"
+HOMEPAGE="http://www.gnucash.org/"
+SRC_URI="https://github.com/Gnucash/${PN}/releases/download/${PV}/${P}.tar.bz2
+		 https://github.com/google/googletest/archive/release-${GV}.tar.gz -> gtest-${GV}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+IUSE="aqbanking chipcard debug doc examples gnome-keyring mysql nls ofx postgres
+	  python quotes -register2 sqlite +gui"
+REQUIRED_USE="
+	chipcard? ( aqbanking )
+	python? ( ${PYTHON_REQUIRED_USE} )"
+
+# libdbi version requirement for sqlite taken from bug #455134
+#
+# dev-libs/boost must always be built with nls enabled.
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	>=dev-libs/libxml2-2.7.0:2
+	>=sys-libs/zlib-1.1.4
+	>=dev-scheme/guile-2.0.0:12=[regex]
+	dev-libs/boost:=[icu,nls]
+	dev-libs/icu:=
+	dev-libs/libxslt
+	aqbanking? (
+		>=net-libs/aqbanking-5[gtk,ofx?]
+		sys-libs/gwenhywfar[gtk]
+		chipcard? ( sys-libs/libchipcard )
+	)
+	gnome-keyring? ( >=app-crypt/libsecret-0.18 )
+	gui? (
+	  gnome-base/dconf
+	  net-libs/webkit-gtk:4=
+	  >=x11-libs/gtk+-3.14.0:3
+	)
+	mysql? (
+		dev-db/libdbi
+		dev-db/libdbi-drivers[mysql]
+	)
+	ofx? ( >=dev-libs/libofx-0.9.1 )
+	postgres? (
+		dev-db/libdbi
+		dev-db/libdbi-drivers[postgres]
+	)
+	python? ( ${PYTHON_DEPS} )
+	quotes? (
+		>=dev-perl/Finance-Quote-1.11
+		dev-perl/Date-Manip
+		dev-perl/HTML-TableExtract
+	)
+	sqlite? (
+		>=dev-db/libdbi-0.9.0
+		>=dev-db/libdbi-drivers-0.9.0[sqlite]
+	)
+"
+
+DEPEND="${RDEPEND}
+	~dev-cpp/gtest-${GV}
+	>=sys-devel/gettext-0.19.6
+	dev-lang/perl
+	dev-perl/XML-Parser
+	sys-devel/libtool
+	virtual/pkgconfig
+"
+
+PDEPEND="doc? (
+	~app-doc/gnucash-docs-${PV}
+	gnome-extra/yelp
+)"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.2-no-gui.patch )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local sql_on_off="OFF"
+	if use mysql || use postgres || use sqlite ; then
+		sql_on_off="ON"
+	fi
+
+	local mycmakeargs=(
+		-DGMOCK_ROOT="${WORKDIR}"/googletest-release-${GV}/googlemock
+		-DGTEST_ROOT="${WORKDIR}"/googletest-release-${GV}/googletest
+
+		-DDISABLE_NLS=$(usex !nls)
+		-DENABLE_REGISTER2=$(usex register2)
+		-DWITH_AQBANKING=$(usex aqbanking)
+		-DWITH_OFX=$(usex ofx)
+		-DWITH_PYTHON=$(usex python)
+		-DWITH_SQL=${sql_on_off}
+		-DWITH_GNUCASH=$(usex gui)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	if use python ; then
+		cp common/test-core/unittest_support.py \
+		   "${BUILD_DIR}"/common/test-core/ || die
+	fi
+
+	cd "${BUILD_DIR}" || die
+	XDG_DATA_HOME="${T}/$(whoami)" emake check
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	rm "${ED%/}"/usr/share/doc/${PF}/README.dependencies || die
+
+	if use gui ; then
+	  rm "${ED%/}"/usr/share/glib-2.0/schemas/gschemas.compiled || die
+	fi
+
+	if use examples ; then
+		mv "${ED%/}"/usr/share/doc/gnucash \
+		   "${ED%/}"/usr/share/doc/${PF}/examples || die
+		pushd "${ED%/}"/usr/share/doc/${PF}/examples/ > /dev/null || die
+		rm AUTHORS DOCUMENTERS LICENSE NEWS projects.html ChangeLog* \
+		   *win32-bin.txt || die
+		popd > /dev/null || die
+		docompress -x /usr/share/doc/${PF}/examples/
+	else
+		rm -r "${ED%/}"/usr/share/doc/gnucash || die
+	fi
+
+	use aqbanking && dodoc doc/README.HBCI
+	use ofx && dodoc doc/README.OFX
+}
+
+pkg_postinst() {
+	if use gui ; then
+		gnome2_icon_cache_update
+		gnome2_schemas_update
+	fi
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+
+	ewarn "Backup all financial files or databases before using GnuCash >=2.7.0!"
+	ewarn
+	ewarn "GnuCash 2.7.0 introduced large changes in its file format and database"
+	ewarn "schema that WILL prevent you from reverting back to GnuCash 2.6."
+}
+
+pkg_postrm() {
+	if use gui ; then
+		gnome2_icon_cache_update
+		gnome2_schemas_update
+	fi
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}