gentoo auto-resync : 08:10:2023 - 18:03:40

2 files changed, 116 insertions, 0 deletions

diff --git a/app-pda/libimobiledevice/Manifest b/app-pda/libimobiledevice/Manifest
index a76b8c1d5831..f9f536b875ef 100644
--- a/app-pda/libimobiledevice/Manifest
+++ b/app-pda/libimobiledevice/Manifest
@@ -4,4 +4,5 @@ AUX libimobiledevice-1.3.0-slibtool.patch 5477 BLAKE2B 963072a0e577c52a2434d011b
 DIST libimobiledevice-1.3.0.tar.bz2 733949 BLAKE2B 40717280bb3424c7431aa93d06d10de817e6761acf2b19948d80b691cfb4dd4ef0e31b81c8458eed29a43c8c8aa256da7baa3648fb785cfbdb7316daaba119a3 SHA512 7b22040552a6561729c79c0846f571b0e608abb7c297567d2ecfdd1718ce86df08a5e34ba51f209bdee96a1917da15e7ba3aaef1d289a951d1d3470b1f89e6a8
 EBUILD libimobiledevice-1.3.0-r1.ebuild 2580 BLAKE2B 483dfa764ca3b9ad7f2d57d3c1b37cbcc343f66fbc2c6d2e203c00d0bb9bdd17e0f886218280efe99fbf91e3034ea6a004feff38193fa5cae2cd60c940ae2aad SHA512 9daf6f8d12da723b82cf823e4696ff21cb158af7f749737c21abb3d953415eda79d7f36f08b5d598b145a72eac9b5f706dd698a868e7ff9a95a67a4f8c2ea898
 EBUILD libimobiledevice-1.3.0-r2.ebuild 2614 BLAKE2B da5b7dd32f7b3a1c1d3e1e2f0c0c9e6a2a8441240a42cdf6b44b7745d1388ff55c3b2b39a51d4ad2496afe107cc5cdfc8717f87e942a6e859f96cc77ce07bd3e SHA512 72b7bae22b3e481f723c72333b21bd31c0f61f16042b37ff5bfb443fde7ad2b0aca8948cf32e2a97bba2f8bddd43f83600e084368c747902cd7128793259d336
+EBUILD libimobiledevice-1.3.0-r3.ebuild 2639 BLAKE2B 5aaee8aa5a2635ea6bfaa8da54dce9fa9dee51a5f744e70e66c44d001516a16889fee353af3038f8c7b559334e2a18df73f8f87529b343812f74b51923e39b46 SHA512 3f1dbc9f9ca369af079a5d486307527584d17739103cef05eb084be78ecfbd4004d767b36c2786642c7fd0ace8cf0c3c198f3a849020ffecabf1b9e6bb472880
 MISC metadata.xml 346 BLAKE2B 5979763c0edb5ba8ea839769460571c50fff06027fa402e66b8f6927179e8898bde50732d847e775683b065eae274afa900b7a9ca6643ad98b4362fb9ec1385f SHA512 6252917ccb0280baea04596905530e2a37e364dfab87281987d9e8369e3fadc7eedded779d50bce6c0f2a39a9d224641c69bbc668f41765ff6f453bee4ea050b
diff --git a/app-pda/libimobiledevice/libimobiledevice-1.3.0-r3.ebuild b/app-pda/libimobiledevice/libimobiledevice-1.3.0-r3.ebuild
new file mode 100644
index 000000000000..47b0b4f1185d
--- /dev/null
+++ b/app-pda/libimobiledevice/libimobiledevice-1.3.0-r3.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit autotools python-r1
+
+DESCRIPTION="Support library to communicate with Apple iPhone/iPod Touch devices"
+HOMEPAGE="https://www.libimobiledevice.org/"
+SRC_URI="https://github.com/libimobiledevice/libimobiledevice/releases/download/${PV}/${P}.tar.bz2"
+
+# While COPYING* doesn't mention 'or any later version', all the headers do, hence use +
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0/1.0-6" # based on SONAME of libimobiledevice-1.0.so
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc gnutls python static-libs"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=app-pda/libplist-2.2.0:= <app-pda/libplist-2.3
+	>=app-pda/libusbmuxd-2.0.2:=
+	gnutls? (
+		dev-libs/libgcrypt:0
+		>=dev-libs/libtasn1-1.1
+		>=net-libs/gnutls-2.2.0
+	)
+	!gnutls? (
+		dev-libs/openssl:0=
+	)
+	python? (
+		${PYTHON_DEPS}
+		app-pda/libplist[python(-),${PYTHON_USEDEP}]
+	)
+"
+DEPEND="
+	${RDEPEND}
+"
+# <cython-3 for bug #898666
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	python? ( <dev-python/cython-3[${PYTHON_USEDEP}] )
+"
+
+BUILD_DIR="${S}_build"
+
+PATCHES=(
+	"${FILESDIR}/${P}-slibtool.patch"
+	"${FILESDIR}/${P}-missing_libflags.patch" #787962
+	"${FILESDIR}/${P}-python.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local ECONF_SOURCE=${S}
+
+	local myeconfargs=( $(use_enable static-libs static) )
+	use gnutls && myeconfargs+=( --disable-openssl )
+
+	do_configure() {
+		mkdir -p "${BUILD_DIR}" || die
+		pushd "${BUILD_DIR}" >/dev/null || die
+		econf "${myeconfargs[@]}" "${@}"
+		popd >/dev/null || die
+	}
+
+	do_configure_python() {
+		# Bug 567916
+		local -x PYTHON_LDFLAGS="$(python_get_LIBS)"
+		do_configure "$@"
+	}
+
+	do_configure --without-cython
+	use python && python_foreach_impl do_configure_python
+}
+
+src_compile() {
+	python_compile() {
+		emake -C "${BUILD_DIR}"/cython \
+			VPATH="${S}/cython:$1/cython" \
+			imobiledevice_la_LIBADD="$1/src/libimobiledevice-1.0.la"
+	}
+
+	emake -C "${BUILD_DIR}"
+	use python && python_foreach_impl python_compile "${BUILD_DIR}"
+
+	if use doc; then
+		doxygen "${BUILD_DIR}"/doxygen.cfg || die
+	fi
+}
+
+src_install() {
+	python_install() {
+		emake -C "${BUILD_DIR}/cython" install \
+			DESTDIR="${D}" \
+			VPATH="${S}/cython:$1/cython"
+	}
+
+	emake -C "${BUILD_DIR}" install DESTDIR="${D}"
+	use python && python_foreach_impl python_install "${BUILD_DIR}"
+	use doc && dodoc docs/html/*
+
+	if use python; then
+		insinto /usr/include/${PN}/cython
+		doins cython/imobiledevice.pxd
+	fi
+
+	find "${D}" -name '*.la' -delete || die
+}