gentoo resync : 21.06.2020

3 files changed, 278 insertions, 2 deletions

diff --git a/app-text/calibre/Manifest b/app-text/calibre/Manifest
index c36734de2efe..8d9ab17a42fb 100644
--- a/app-text/calibre/Manifest
+++ b/app-text/calibre/Manifest
@@ -6,8 +6,10 @@ AUX calibre-server-3.init 1796 BLAKE2B f87d785d6f6fc10fa648d40944ec8538027854bb8
 DIST calibre-4.17.0-qt-5.15-fontconfig-bug-725020.patch 1222 BLAKE2B 14038b4ea5f87d9a8f645b5af8342da90337202b0247b07dccd8995f55bb965b5c2bbdddc24b55b6e92e899f91d5dec19c10ddea8fcc42c8ed3d74ee90eb09d6 SHA512 b0652c3277b8390f47039366380fceacfd3cd9014fe42306a947f6749c6192657b77e3d832044828bea06c43f1f5e745e6b4ff8dd24efc73d9ad5261c4c73a5e
 DIST calibre-4.17.0.tar.xz 37027156 BLAKE2B e1e9fbbb93cc14af0790e400d79b433c774f17bb06d99161e27769217ab7eed5c2660ab8a3e09109bade91684a8f5a8b52795667833ddf454343e530109eea63 SHA512 95719c820839a8548c0734a7be105fa4124c3c070fdd79ceeef5fef7f9c81f89d5b2077a71df3cc6cd103c14b813cd0d42add1c75ec4883686a8596de36ef5d0
 DIST calibre-4.18.0.tar.xz 37135328 BLAKE2B 247fc226fade064306309933be008e7636bacfdcfb1c96ae900fce5cc4474e26853b3a9dd932fd758543e31af95374f089d2e7a15c3d9ca7655eabd077727e2c SHA512 cc75e8b78722eb286af57f1d6b1ed783647f69471d903a3d4dd458b3f6966804e8e4fda7bd1947e9107ce9a280486ea7de101f7b843f8365bfe6e874d9ebf3d3
+DIST calibre-4.19.0.tar.xz 37172532 BLAKE2B 1cf3a4727ac7a2e7fe4d926acad7e6324b0673728db862209d98280f4fe9457eb33d734e47ac4882accebad2a6ffd12aa0add6bdcfe64cc4baa8a39dc2b4b94f SHA512 47b767b3f23f01fa1931abd470eb69f5493f5b0e6cd5c0e566b5576d1d831137c28555de3f73ad2a2dd0dd03615171a4c62356278a590ad48b77a6ca1cac890b
 DIST calibre-4.9.1.tar.xz 37529656 BLAKE2B 5d703ca0c398b43cc26a54e0628d0fe938c6a5027a4fd0c9cac83944e5143eb08439bf79b2098182be7727eaa042748f17866788b02c7744178dce131f6b1d1e SHA512 bf06aa3cbc8d255934f3f7f3ce20b4798edf107ed9f822943d2b4ae7d95473842928ed79f8ba7571f7e0ebdc267c441916d543d5b7630aae5cb151bcc3184b71
 EBUILD calibre-4.17.0-r1.ebuild 8765 BLAKE2B 5fdb90f47e390d3935639673f63c2fdd9a5e64ae5635f5a1e5732c176831f5b91decb2dead5ddc79eafd786b64ccd95aa6b0943038428f8aa6331ed45beda222 SHA512 3235f8bac83d558268c0e41b6a313204b87e545dd7606309aaed0d2b9ab8a867562f0dd5127e90bd8d8d56dc4371c46c2d0091bcefa9815cbc3b1da31f00b4ec
-EBUILD calibre-4.18.0.ebuild 8697 BLAKE2B 0cf516ba2e15a614c2eff207fe03bfedc6e6d20f3bfa0948ff3d077dbd111580bdd807a360df27f5813282acaef9dff0dda504c69cd502d84b294cff5fa45da6 SHA512 884a603d9e249bec56e2631ce378d79d3c86e0a0c7740a0d81c1aeb60af0332a7353c8629756f25793669c231bd4fd950d35437fbc6a81f228dd09b2a86d0ecd
+EBUILD calibre-4.18.0.ebuild 8697 BLAKE2B 2375f915eb98ca26ac5ad31db9a0ffee9ec8cc6694b0a7daca9eda35604c1ca606f71b3e3b7277033ba9c35e35abbc9ffdf02fceb2f1d72cc286a6d6daf357aa SHA512 48ccd11e78545cd8f489ad0a7fa1e660ed52e68dadf54d1439baa1a378afa67d766e6f7b0c0c5bd53538695e274e2fa4c2a6bb0555d5898d854cac56660a9cda
+EBUILD calibre-4.19.0.ebuild 8550 BLAKE2B fcaf2c66cd59bbe0017ab5ead307bb532ac1ae8f5fcc9c0b4e015ec652646f8faed0d108ccbf29675384265f07fb6720634abe757faa6653a73146c685caa7f4 SHA512 01f6b7944e0ae5ffdf420b8046a104200217f958fcdeef057ba5e81a06bc04ffb9b1b2a8bcddcc3b50bd2d3dfd27b738df9084454d2bd7ae51ed28ab7b78d714
 EBUILD calibre-4.9.1-r2.ebuild 8799 BLAKE2B abbcecaeec5f818cf7ed218edef294ee45d53861b3a8a573ac8c119deeb3d6f25ee16c42433daefb41a1b05eb7ffef007759632d6823b731931c57b60272cd30 SHA512 8989bcbb4e122b2e7ad8fde2b671ed71173658a6b05932b2b56e270e600d84ac916d61af1e2eb63dd146b9ff8801670cd42a2ba8db5a6aca3f21e944f1ecbd43
 MISC metadata.xml 382 BLAKE2B 87fa7e63a6ed7a4ea55247b362288b43f7edd312cc3085bb8c1b947402ae4aa0df01fac4f6646d260653ff8af7fe28d3dabb8a213dbf3e206181b69835b33d5f SHA512 8503e0a4a48d93682c386eb1d6507b4b26585afc9d62b7cd52bc00b457a887bd17422a03669ff404570ff7f5ff6f0bba14ee935979f8b54722870d6620097de5
diff --git a/app-text/calibre/calibre-4.18.0.ebuild b/app-text/calibre/calibre-4.18.0.ebuild
index f37e5cccd2f6..a4f5f90a8186 100644
--- a/app-text/calibre/calibre-4.18.0.ebuild
+++ b/app-text/calibre/calibre-4.18.0.ebuild
@@ -63,7 +63,7 @@ COMMON_DEPEND="${PYTHON_DEPS}
 		>=dev-python/lxml-3.8.0[${PYTHON_MULTI_USEDEP}]
 		>=dev-python/markdown-3.0.1[${PYTHON_MULTI_USEDEP}]
 		>=dev-python/mechanize-0.3.5[${PYTHON_MULTI_USEDEP}]
-		>=dev-python/msgpack-0.5.6[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/msgpack-0.6.2[${PYTHON_MULTI_USEDEP}]
 		>=dev-python/netifaces-0.10.5[${PYTHON_MULTI_USEDEP}]
 		>=dev-python/pillow-3.2.0[${PYTHON_MULTI_USEDEP}]
 		>=dev-python/psutil-4.3.0[${PYTHON_MULTI_USEDEP}]
diff --git a/app-text/calibre/calibre-4.19.0.ebuild b/app-text/calibre/calibre-4.19.0.ebuild
new file mode 100644
index 000000000000..ae82240de8bf
--- /dev/null
+++ b/app-text/calibre/calibre-4.19.0.ebuild
@@ -0,0 +1,274 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+PYTHON_REQ_USE="sqlite,ssl"
+
+inherit bash-completion-r1 desktop toolchain-funcs python-single-r1 xdg-utils
+
+DESCRIPTION="Ebook management application"
+HOMEPAGE="https://calibre-ebook.com/"
+SRC_URI="https://download.calibre-ebook.com/${PV}/${P}.tar.xz"
+
+LICENSE="
+	GPL-3+
+	GPL-3
+	GPL-2+
+	GPL-2
+	GPL-1+
+	LGPL-3+
+	LGPL-2.1+
+	LGPL-2.1
+	BSD
+	MIT
+	Old-MIT
+	Apache-2.0
+	public-domain
+	|| ( Artistic GPL-1+ )
+	CC-BY-3.0
+	OFL-1.1
+	PSF-2
+"
+KEYWORDS="~amd64 ~arm ~x86"
+SLOT="0"
+IUSE="ios +udisks"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-text/hunspell-1.7:=
+	>=app-text/podofo-0.9.6_pre20171027:=
+	>=app-text/poppler-0.26.5[qt5]
+	>=dev-libs/chmlib-0.40:=
+	dev-libs/glib:2=
+	dev-libs/hyphen:=
+	>=dev-libs/icu-57.1:=
+	dev-libs/libinput:=
+	>=dev-libs/dbus-glib-0.106
+	>=sys-apps/dbus-1.10.8
+	$(python_gen_cond_dep '
+		>=dev-python/apsw-3.25.2_p1[${PYTHON_MULTI_USEDEP}]
+		dev-python/beautifulsoup:4[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/chardet-3.0.3[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/cssselect-0.7.1[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/css-parser-1.0.4[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/dbus-python-1.2.4[${PYTHON_MULTI_USEDEP}]
+		dev-python/dnspython[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/feedparser-5.2.1[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/html2text-2019.8.11[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/html5-parser-0.4.9[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/lxml-3.8.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/markdown-3.0.1[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/mechanize-0.3.5[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/msgpack-0.6.2[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/netifaces-0.10.5[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pillow-3.2.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/psutil-4.3.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pygments-2.3.1[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/python-dateutil-2.5.3[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/PyQt5-5.12[gui,svg,widgets,network,printsupport,${PYTHON_MULTI_USEDEP}]
+		>=dev-python/PyQtWebEngine-5.12[${PYTHON_MULTI_USEDEP}]
+		dev-python/regex[${PYTHON_MULTI_USEDEP}]
+		dev-python/zeroconf[${PYTHON_MULTI_USEDEP}]
+	')
+	dev-qt/qtcore:5=
+	dev-qt/qtdbus:5=
+	dev-qt/qtgui:5=
+	>=dev-qt/qtwebengine-5.12
+	dev-qt/qtwidgets:5=
+	dev-util/desktop-file-utils
+	dev-util/gtk-update-icon-cache
+	media-fonts/liberation-fonts
+	media-libs/fontconfig:=
+	>=media-libs/freetype-2:=
+	>=media-libs/libmtp-1.1.11:=
+	>=media-libs/libwmf-0.2.8
+	>=media-gfx/optipng-0.7.6
+	>=sys-libs/zlib-1.2.11:=
+	virtual/libusb:1=
+	x11-libs/libxkbcommon:=
+	x11-libs/libX11:=
+	x11-libs/libXext:=
+	x11-libs/libXrender:=
+	x11-misc/shared-mime-info
+	>=x11-misc/xdg-utils-1.0.2-r2
+	ios? (
+		>=app-pda/usbmuxd-1.0.8
+		>=app-pda/libimobiledevice-1.2.0
+	)
+	udisks? ( virtual/libudev )"
+RDEPEND="${COMMON_DEPEND}
+	udisks? ( sys-fs/udisks:2 )"
+DEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		>=dev-python/setuptools-23.1.0[${PYTHON_MULTI_USEDEP}]
+		dev-python/sip[${PYTHON_MULTI_USEDEP}]
+	')
+	>=virtual/podofo-build-0.9.6_pre20171027
+	virtual/pkgconfig"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]] && tc-is-gcc && [[ $(gcc-major-version) -lt 6 ]]; then
+		eerror "Calibre cannot be built with this version of gcc."
+		eerror "You need at least gcc-6.0"
+		die "Your C compiler is too old for this package."
+	fi
+}
+
+src_prepare() {
+	# no_updates: do not annoy user with "new version is availible all the time
+	# disable_plugins: walking sec-hole, wait for upstream to use GHNS interface
+	eapply \
+		"${FILESDIR}/${PN}-2.9.0-no_updates_dialog.patch" \
+		"${FILESDIR}/${PN}-disable_plugins.patch"
+
+	eapply_user
+
+	# Fix outdated version constant.
+	#sed -e "s#\\(^numeric_version =\\).*#\\1 (${PV//./, })#" \
+	#	-i src/calibre/constants.py || \
+	#	die "sed failed to patch constants.py"
+
+	# Avoid sandbox violation in /usr/share/gnome/apps when linux.py
+	# calls xdg-* (bug #258938).
+	sed -e "s|'xdg-desktop-menu', 'install'|\\0, '--mode', 'user'|" \
+		-e "s|check_call(\\['xdg-desktop-menu', 'forceupdate'\\])|#\\0|" \
+		-e "s|\\(CurrentDir(tdir)\\), \\\\\$|\\1:|" \
+		-e "s|, PreserveMIMEDefaults():|:|" \
+		-e "s|'xdg-icon-resource', 'install'|\\0, '--mode', 'user'|" \
+		-e "s|cmd\[2\]|cmd[4]|" \
+		-e "s|cc(\\['xdg-desktop-menu', 'forceupdate'\\])|#\\0|" \
+		-e "s|'xdg-mime', 'install'|\\0, '--mode', 'user'|" \
+		-i src/calibre/linux.py || die "sed failed to patch linux.py"
+
+	# Disable unnecessary privilege dropping for bug #287067.
+	sed -e "s:if os.geteuid() == 0:if False and os.geteuid() == 0:" \
+		-i setup/install.py || die "sed failed to patch install.py"
+
+	sed -e "/^                self.check_call(\\[QMAKE\\] + qmc + \\[proname\\])$/a\
+\\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ \\ self.check_call(['sed', \
+'-e', 's|^CFLAGS .*|\\\\\\\\0 ${CFLAGS}|', \
+'-e', 's|^CXXFLAGS .*|\\\\\\\\0 ${CXXFLAGS}|', \
+'-e', 's|^LFLAGS .*|\\\\\\\\0 ${LDFLAGS}|', \
+'-i', 'Makefile'])" \
+		-i setup/build.py || die "sed failed to patch build.py"
+}
+
+src_install() {
+	# calibre works with python 3, so remove the python 2 constraint
+	export CALIBRE_PY3_PORT=1
+
+	# Bypass kbuildsycoca and update-mime-database in order to
+	# avoid sandbox violations if xdg-mime tries to call them.
+	cat - > "${T}/kbuildsycoca" <<-EOF
+	#!${BASH}
+	echo $0 : $@
+	exit 0
+	EOF
+
+	cp "${T}"/{kbuildsycoca,update-mime-database} || die
+	chmod +x "${T}"/{kbuildsycoca,update-mime-database} || die
+
+	export QMAKE="${EPREFIX}/usr/$(get_libdir)/qt5/bin/qmake"
+
+	# Unset DISPLAY in order to prevent xdg-mime from triggering a sandbox
+	# violation with kbuildsycoca as in bug #287067, comment #13.
+	export -n DISPLAY
+
+	# Bug #352625 - Some LANGUAGE values can trigger the following ValueError:
+	#   File "/usr/lib/python2.6/locale.py", line 486, in getdefaultlocale
+	#    return _parse_localename(localename)
+	#  File "/usr/lib/python2.6/locale.py", line 418, in _parse_localename
+	#    raise ValueError, 'unknown locale: %s' % localename
+	#ValueError: unknown locale: 46
+	export -n LANG LANGUAGE ${!LC_*}
+	export LC_ALL=C.utf8 #709682
+
+	# Bug #295672 - Avoid sandbox violation in ~/.config by forcing
+	# variables to point to our fake temporary $HOME.
+	export HOME="${T}/fake_homedir"
+	export XDG_CONFIG_HOME="${HOME}/.config"
+	export XDG_DATA_HOME="${HOME}/.local/share"
+	export CALIBRE_CONFIG_DIRECTORY="${XDG_CONFIG_HOME}/calibre"
+	mkdir -p "${XDG_DATA_HOME}" "${CALIBRE_CONFIG_DIRECTORY}" || die
+
+	tc-export CC CXX
+	# Bug #334243 - respect LDFLAGS when building extensions
+	export OVERRIDE_CFLAGS="$CFLAGS" OVERRIDE_LDFLAGS="$LDFLAGS"
+	local libdir=$(get_libdir)
+	[[ -n $libdir ]] || die "get_libdir returned an empty string"
+
+	addpredict /dev/dri #665310
+
+	PATH=${T}:${PATH} PYTHONPATH=${S}/src${PYTHONPATH:+:}${PYTHONPATH} \
+	"${PYTHON}" setup.py install \
+		--root="${D}" \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/${libdir}" \
+		--staging-root="${ED}/usr" \
+		--staging-libdir="${ED}/usr/${libdir}" || die
+
+	rm "${ED}/usr/share/applications/defaults.list" || die
+	find "${ED}"/usr/share -type d -empty -delete
+
+	cd "${ED}"/usr/share/calibre/fonts/liberation || die
+	local x
+	for x in * ; do
+		[[ -f ${EPREFIX}/usr/share/fonts/liberation-fonts/${x} ]] || continue
+		ln -sf "../../../fonts/liberation-fonts/${x}" "${x}" || die
+	done
+
+	einfo "Converting python shebangs"
+	python_fix_shebang --force "${ED}"
+
+	einfo "Compiling python modules"
+	python_optimize "${ED}"/usr/lib/calibre
+
+	newinitd "${FILESDIR}"/calibre-server-3.init calibre-server
+	newconfd "${FILESDIR}"/calibre-server-3.conf calibre-server
+
+	bashcomp_alias calibre \
+		lrfviewer \
+		calibre-debug \
+		ebook-meta \
+		calibre-server \
+		ebook-viewer \
+		ebook-polish \
+		fetch-ebook-metadata \
+		lrf2lrs \
+		ebook-convert \
+		ebook-edit \
+		calibre-smtp \
+		ebook-device
+
+}
+
+pkg_preinst() {
+	# Indentify stray directories from upstream's "Binary install"
+	# method (see bug 622728).
+	CALIBRE_LIB_DIR=/usr/$(get_libdir)/calibre
+	CALIBRE_LIB_CONTENT=$(for x in "${ED}${CALIBRE_LIB_DIR}"/*; do
+		printf -- "${x##*/} "; done) || die "Failed to list ${ED}${CALIBRE_LIB_DIR}"
+}
+
+pkg_postinst() {
+	[[ -n ${CALIBRE_LIB_DIR} ]] || die "CALIBRE_LIB_DIR is unset"
+	local x
+	for x in "${EROOT}${CALIBRE_LIB_DIR}"/*; do
+		if [[ " ${CALIBRE_LIB_CONTENT} " != *" ${x##*/} "* ]]; then
+			elog "Purging '${x}'"
+			rm -rf "${x}"
+		fi
+	done
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	xdg_icon_cache_update
+}