gentoo resync : 14.07.2018

1 files changed, 46 insertions, 0 deletions

diff --git a/app-text/gspell/gspell-1.4.2.ebuild b/app-text/gspell/gspell-1.4.2.ebuild
new file mode 100644
index 000000000000..25328fe7e66c
--- /dev/null
+++ b/app-text/gspell/gspell-1.4.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala virtualx
+
+DESCRIPTION="Spell check library for GTK+ applications"
+HOMEPAGE="https://wiki.gnome.org/Projects/gspell"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/1" # subslot = libgspell-1 soname version
+KEYWORDS="~alpha amd64 ~arm ~ppc ~sparc x86 ~amd64-fbsd"
+
+IUSE="+introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	app-text/iso-codes
+	>=app-text/enchant-1.6.0
+	>=dev-libs/glib-2.44:2
+	>=x11-libs/gtk+-3.20:3[introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-1.42.0:= )
+	vala? ( $(vala_depend) )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.25
+	>=sys-devel/gettext-0.19.4
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}
+
+src_test() {
+	virtx emake check
+}