gentoo resync : 09.07.2022

3 files changed, 142 insertions, 5 deletions

diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index a5ea3b940d44..ec267df369c2 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -5,7 +5,10 @@ AUX poppler-22.05.0-missing-include.patch 518 BLAKE2B 7ade72f27a3d0b9fd32fb83113
 DIST poppler-22.05.0.tar.xz 1828628 BLAKE2B d1757893c841d35cbdeda493afea92046c447dfa0d519ab9a872a75fdb7edbb06bbde78b2e7d41757f5bbff8d1f46c81f7314dff8386d4d686ded4d2cc85d65e SHA512 629098793050f7a901c2a2cf1efcad83c58d26164cf94f4aa3985465f016a8875c62be4fb8ab8005ca00ef061402962e6d6c14eb611ce29f2d71d3ae83f24737
 DIST poppler-22.06.0.tar.xz 1834980 BLAKE2B 6988480dc30f5fe67be0170f8f006bdb4d3e6b0e0ad8643aa6cbf4fe017d52d8747f108267a30aee5ec4567aa5d2fcc9ce9824fc4dac45a1d37291fa668c2dfe SHA512 79e1a1440a0903ea6238dcc7afc4ecdf1f8cc53af94ec5649f631fca568711d48a7ec4046fccb8520818420dc21e4ad1aaf602c22b13f9ce22f4d06edc83c8a3
 DIST poppler-22.06.0.tar.xz.sig 833 BLAKE2B e2a842fac83b5c42713aa45072d8ea1de5219cbbc35d04142a902f569fc7c558cbda9a2379fde6f9f933b701fabe98f93de71a0676837b2a21104f919a097bc8 SHA512 b61f706e52c57209bb180fbe5a65e366e2a841743ac2c24fc0828dc4bab8ae52da12330e4694e8dade1e1963112fc7b01c0c1b30141be2b7c8c0cf2aaab059c5
+DIST poppler-22.07.0.tar.xz 1838796 BLAKE2B 401573c3bd1e4801ee331e97a3787c88c0c3f0a10ca59f234622cee22760cd18a566c952f94a1e7263294d6f43c34c861cf53bde59b4bd92f806efe136f92197 SHA512 d3d8a0f50ddcf2020bbbc3c21c6fcdd6f31b431d984622c2a4ae4986b82a14d79969d7113588ba5d9a672babe4dc01fe2f5e8d9ce73a9fbce14685220d914f02
+DIST poppler-22.07.0.tar.xz.sig 833 BLAKE2B a73cc36e0c1c20c4f55e4896ae8d880d62d458a0d256022cdac50e48c7993fbf617e9c4de704958d103fae1ccb619d6122a06d2b51e0389f15338d67e34cefdb SHA512 252c34d4f8b7b43255ea5371c35348ac2d3044860d850fd510213a4785c633e230f61aab06b706b173e8e3482c7028a433fccae982adc18681f0da2b6e2bed3d
 EBUILD poppler-22.05.0.ebuild 3397 BLAKE2B 69946eb58b8b7844de29734e327cdc8c912fa535c3281f908739e68901fc99ac6ca92c437f771bc3e328fcd48fb76b522146941f76df9fe414fc8305d8b23c86 SHA512 e1130a9e67d32e1fe3052c8fa9dd0f43c96024c69cb6ec44c8a103c8fcd8b98d7e29e7f2ecf05384f6bf582f0efd8757d04801024ec8d284f752c5f1b0d873b8
 EBUILD poppler-22.06.0.ebuild 3627 BLAKE2B bb1ec0745496495ef86d376d2d1ca6982a5a5f94a7976fbf7c62305e0e02dfcaa2ca56c6f615e10607379ca28b2779ec0405202232257cf637519707691159dc SHA512 39d1d7e26eac8e3bd11e089d5ff44ad7ac0d39ec2f0245e831b59cb8a34c9d533ff25ea343aaf3ddb83ed867b6f5218897540ddc943d3df7341ca539940c6da6
-EBUILD poppler-9999.ebuild 3628 BLAKE2B be29c55201cdf0c4e31a77538984b0057722b464f548903dd07ff898b9276c4338f0a27d98c8f9ff825f6c07f1fc4a62b761f38ace0a5a3eb6ce5db477744d88 SHA512 f8b03fd6a733bfde1faf5bb8327d952ef8134bf773c1b9d7034b06d88b8f02da247510c84e087fb776701c4e6729b7767b30264b0e5227a785a7563db94f3148
+EBUILD poppler-22.07.0.ebuild 3656 BLAKE2B c4afa4a9b28fa4ca0e4b08f52d5ae33b2d0c6fdbb22228b42c8cf36522a76ddaeb6520e79c0e920ec7c201a87ddda06ad15ec8e34391a51162235d9cfc8b27b2 SHA512 8343422ad9b5978b3646a9e3ae7eb0c5a3689a330112a4ba1183ff09fb1bcc7b731cbea87dcf6abcf2a8687e29c25bc4e8cac673d74716e81aa52c223d85b27d
+EBUILD poppler-9999.ebuild 3656 BLAKE2B c4afa4a9b28fa4ca0e4b08f52d5ae33b2d0c6fdbb22228b42c8cf36522a76ddaeb6520e79c0e920ec7c201a87ddda06ad15ec8e34391a51162235d9cfc8b27b2 SHA512 8343422ad9b5978b3646a9e3ae7eb0c5a3689a330112a4ba1183ff09fb1bcc7b731cbea87dcf6abcf2a8687e29c25bc4e8cac673d74716e81aa52c223d85b27d
 MISC metadata.xml 1078 BLAKE2B c5ce2245efedc75eb39a6c649d27698da0ac07b87da3240aeb9fea1435d48c3282a8a3bb9f002c78b79de2a518cb73f3eef563c05f41528bb55ffeca84409e13 SHA512 22c83f7f6a7632fc4fe94223be9e5edac085099bf5c0f6621b0179b16e35b98b0027e467e76c0ca365008d765258e05faf48dbc4b1e8d5eb507f348a533f88f6
diff --git a/app-text/poppler/poppler-22.07.0.ebuild b/app-text/poppler/poppler-22.07.0.ebuild
new file mode 100644
index 000000000000..cffe79567ee4
--- /dev/null
+++ b/app-text/poppler/poppler-22.07.0.ebuild
@@ -0,0 +1,134 @@
+# Copyright 2005-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake toolchain-funcs xdg-utils
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
+	SLOT="0/9999"
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/aacid.asc
+	inherit verify-sig
+
+	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
+	SRC_URI+=" verify-sig? ( https://poppler.freedesktop.org/${P}.tar.xz.sig )"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	SLOT="0/122"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="https://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="boost cairo cjk curl +cxx debug doc +introspection +jpeg +jpeg2k +lcms nss png qt5 tiff +utils"
+
+# No test data provided
+RESTRICT="test"
+
+COMMON_DEPEND="
+	media-libs/fontconfig
+	>=media-libs/freetype-2.8
+	sys-libs/zlib
+	cairo? (
+		dev-libs/glib:2
+		x11-libs/cairo
+		introspection? ( dev-libs/gobject-introspection:= )
+	)
+	curl? ( net-misc/curl )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
+	lcms? ( media-libs/lcms:2 )
+	nss? ( >=dev-libs/nss-3.19:0 )
+	png? ( media-libs/libpng:0= )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtxml:5
+	)
+	tiff? ( media-libs/tiff:0 )
+"
+RDEPEND="${COMMON_DEPEND}
+	cjk? ( app-text/poppler-data )
+"
+DEPEND="${COMMON_DEPEND}
+	boost? ( dev-libs/boost )
+"
+BDEPEND="
+	dev-util/glib-utils
+	virtual/pkgconfig
+"
+
+if [[ ${PV} != *9999* ]] ; then
+	BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-aacid )"
+fi
+
+DOCS=( AUTHORS NEWS README.md README-XPDF )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-20.12.1-qt5-deps.patch"
+	"${FILESDIR}/${PN}-21.09.0-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Clang doesn't grok this flag, the configure nicely tests that, but
+	# cmake just uses it, so remove it if we use clang
+	if tc-is-clang ; then
+		sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
+	fi
+
+	if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
+		sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
+			-i CMakeLists.txt || die
+	else
+		einfo "policy(SET CMP0002 OLD) - workaround can be removed"
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+	local mycmakeargs=(
+		-DBUILD_GTK_TESTS=OFF
+		-DBUILD_QT5_TESTS=OFF
+		-DBUILD_CPP_TESTS=OFF
+		-DBUILD_MANUAL_TESTS=OFF
+		-DRUN_GPERF_IF_PRESENT=OFF
+		-DENABLE_BOOST="$(usex boost)"
+		-DENABLE_ZLIB=ON
+		-DENABLE_ZLIB_UNCOMPRESS=OFF
+		-DENABLE_UNSTABLE_API_ABI_HEADERS=ON
+		-DUSE_FLOAT=OFF
+		-DWITH_Cairo=$(usex cairo)
+		-DENABLE_LIBCURL=$(usex curl)
+		-DENABLE_CPP=$(usex cxx)
+		-DWITH_JPEG=$(usex jpeg)
+		-DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
+		-DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
+		-DENABLE_CMS=$(usex lcms lcms2 none)
+		-DWITH_NSS3=$(usex nss)
+		-DWITH_PNG=$(usex png)
+		$(cmake_use_find_package qt5 Qt5Core)
+		-DWITH_TIFF=$(usex tiff)
+		-DENABLE_UTILS=$(usex utils)
+		-DENABLE_QT6=OFF
+	)
+	use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# live version doesn't provide html documentation
+	if use cairo && use doc && [[ ${PV} != *9999* ]]; then
+		# For now install gtk-doc there
+		insinto /usr/share/gtk-doc/html/poppler
+		doins -r "${S}"/glib/reference/html/*
+	fi
+}
diff --git a/app-text/poppler/poppler-9999.ebuild b/app-text/poppler/poppler-9999.ebuild
index 1e336c95ce57..cffe79567ee4 100644
--- a/app-text/poppler/poppler-9999.ebuild
+++ b/app-text/poppler/poppler-9999.ebuild
@@ -15,7 +15,7 @@ else
 
 	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
 	SRC_URI+=" verify-sig? ( https://poppler.freedesktop.org/${P}.tar.xz.sig )"
-	#KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 	SLOT="0/122"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
 fi
 
@@ -28,7 +28,7 @@ IUSE="boost cairo cjk curl +cxx debug doc +introspection +jpeg +jpeg2k +lcms nss
 # No test data provided
 RESTRICT="test"
 
-DEPEND="
+COMMON_DEPEND="
 	media-libs/fontconfig
 	>=media-libs/freetype-2.8
 	sys-libs/zlib
@@ -50,10 +50,10 @@ DEPEND="
 	)
 	tiff? ( media-libs/tiff:0 )
 "
-RDEPEND="${DEPEND}
+RDEPEND="${COMMON_DEPEND}
 	cjk? ( app-text/poppler-data )
 "
-DEPEND+="
+DEPEND="${COMMON_DEPEND}
 	boost? ( dev-libs/boost )
 "
 BDEPEND="