gentoo resync : 30.09.2020

2 files changed, 130 insertions, 0 deletions

diff --git a/dev-db/pgadmin4/Manifest b/dev-db/pgadmin4/Manifest
index a12af4090379..e007c6d4df8f 100644
--- a/dev-db/pgadmin4/Manifest
+++ b/dev-db/pgadmin4/Manifest
@@ -2,6 +2,8 @@ AUX pgadmin4-4.17-python-3.8.patch 595 BLAKE2B 695b133a61d2a54939a3bd8fa3c8fe3ea
 AUX pgadmin4.desktop 298 BLAKE2B 9048ee03c9f8e05807f2907fd7dcfda9d76bb3cd3b2567676cf6bc9acebdf8d2b4de1626f9fe57c4940422766fa7e6fa9111a5bc9c252e34f72af2850813b158 SHA512 a083c525cf49543751dcf4f98a9e2607ce06c35a573c5a97d4088b21b41dc260ea0fcbb139ce153f0e1deb6bd8e6e75e69a6fe08ff2f4aa563d7398bd52553b2
 DIST pgadmin4-4.17.tar.gz 28007097 BLAKE2B d296f2b9372c23067db899fa82e1b8e732837b01a6172dd2d70520f815aafde161715eea9d9d53e7507a6a715dbfdaabf001a10d143c1aa0505237b2b138e334 SHA512 f9e292ba7ff1e5edaa8738188eb01744d69d0eb134700feb0623806425c998e7f298f74cd498a09f2d9a073a9a349c82f7a3f617e1da3c8dd757cc982d941c9f
 DIST pgadmin4-4.25.tar.gz 33167393 BLAKE2B 5a40e45c53f79ea66c6f685d1605ddce7b1758540bf3a6863d4b092cc4dab5b00daff15832cd6feee28aa348c7a5376e25a93508fd348d8ffd4d29031e2b6c68 SHA512 a1944f9c65b8aa7ec5bd83ef75702293d869ae341ea73f81fb4358bfbc7f91a6981237eb9f1b20055c5f3fa182428afe19dc170963265789c34d73f2e240c268
+DIST pgadmin4-4.26.tar.gz 33525278 BLAKE2B 2a4061f59299bc48b029a4a93f410538170b6c3d97597074d2b3b6eed1de0f9a1ac88bc187614d9e46d8fe872941f173ba0f0a02def590451dad09e6a3b78e5a SHA512 952a4771f80541c54234fcaa9c870283fdf4887246d0d9751a77c28340b7e39ba871141f230086efda9a274d5e6bd567305047cdc7edf766ccd41112281fdf94
 EBUILD pgadmin4-4.17-r1.ebuild 3307 BLAKE2B 2f4dab13a9365051abc89e66101bf6b8c93400b3eefb34f53033feb9d6d49321f9e2fcb7c3f58340ab21b1d358006d0a1846a08ce6a26048bde0a4a779cdf131 SHA512 4c80f4f5f243a25aee956ee3230ff6ee9a55e1dce19fcd1c1da91b00b4f16942fdc64815559bfbc873a67f99b6676f463cf923987d7fe039ed8d027b7a64b51a
 EBUILD pgadmin4-4.25.ebuild 3545 BLAKE2B 3e716cd6cb3f4fe19d2ffe6f6f8581f6ce9b558df9291c21eec36de684e766373fac11e610585d416911eb097d13310804320fe82985428a14f5fcbfb3c6acaf SHA512 46b1e593c9d10d4d69df656656bd1a5d020698a6e799e06b63f8f27358dfbcac2501ce2d34c55d2448d274aacf6a1a85eb89dea43f6e6113b74f02c6ee77bd8e
+EBUILD pgadmin4-4.26.ebuild 3797 BLAKE2B 37f2b12586c1c12d0485673af2f63b5434e79271630c32e7da611d2edcfa044262424387be8449af46548750c084087968bf724991238704f48d25958f0cedf4 SHA512 9b175c0ec000a9d3801093294378004deb289d7c08fae35944d2128fd3b2aa3a2d2979200b684d7f2275fc5383163cdf32676a8f2f04d8801e190797d5d87c6e
 MISC metadata.xml 266 BLAKE2B 9d5988ab45f9939f9be5ee7f4b7a9950a3d62252aa0d3e6c953265467428c59fb8c05b2bb72085431b7aa9fc18d31f2b3273e8fdb33443d786b2237db697b7e2 SHA512 9f85990c7ce6a1de5c1067e4781af18bede2d3bd02963a7b2927766b70dbe98d3fb63bb01e19b1cf6e2b77038d9788bf38155b3cc33f9e5ff8430b10a4006325
diff --git a/dev-db/pgadmin4/pgadmin4-4.26.ebuild b/dev-db/pgadmin4/pgadmin4-4.26.ebuild
new file mode 100644
index 000000000000..239acf0a8228
--- /dev/null
+++ b/dev-db/pgadmin4/pgadmin4-4.26.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="sqlite"
+inherit desktop python-single-r1 qmake-utils xdg
+
+DESCRIPTION="GUI administration and development platform for PostgreSQL"
+HOMEPAGE="https://www.pgadmin.org/"
+SRC_URI="https://ftp.postgresql.org/pub/pgadmin/${PN}/v${PV}/source/${P}.tar.gz"
+
+LICENSE="POSTGRESQL"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="test"
+
+# libsodium dep added because of 689678
+COMMON_DEPEND="${PYTHON_DEPS}
+	dev-libs/libsodium[-minimal]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtwidgets:5
+"
+DEPEND="${COMMON_DEPEND}
+	doc? (
+		$(python_gen_cond_dep '
+			dev-python/sphinx[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+	virtual/imagemagick-tools[png]
+"
+
+# In 4.25's requirement.txt, bcrypt is listed as <=3.17, but upstream's
+# git history shows this is just for compatibility with <python-3.6.
+# In 4.26's requirement.txt, cryptography is listed as <=3.0, but upstream's
+# git history shows this is just for compatibility with Windows.
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		>=dev-python/blinker-1.4[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/flask-1.0.2[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/flask-compress-1.4.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/flask-gravatar-0.5.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/flask-login-0.4.1[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/flask-mail-0.9.1[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/flask-migrate-2.4.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/flask-paranoid-0.2.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/flask-principal-0.4.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/flask-security-3.0.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/flask-sqlalchemy-2.3.2[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/flask-wtf-0.14.2[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/ldap3-2.5.1[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/passlib-1.7.2[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/psutil-5.7.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/psycopg-2.8[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/python-dateutil-2.8.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pytz-2018.9[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/simplejson-3.16.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/six-1.12.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/speaklater-1.3[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/sqlalchemy-1.3.13[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/sqlparse-0.2.4[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/sshtunnel-0.1.5[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/werkzeug-0.15.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/wtforms-2.2.1[${PYTHON_MULTI_USEDEP}]
+		dev-python/bcrypt[${PYTHON_MULTI_USEDEP}]
+		dev-python/cryptography[${PYTHON_MULTI_USEDEP}]
+		dev-python/python-email-validator[${PYTHON_MULTI_USEDEP}]
+	')
+"
+
+S="${WORKDIR}"/${P}/runtime
+
+src_prepare() {
+	cd "${WORKDIR}"/${P} || die
+	default
+}
+
+src_configure() {
+	export PGADMIN_PYTHON_DIR="${EPREFIX}/usr"
+	eqmake5
+}
+
+src_compile() {
+	default
+	use doc && emake -C "${WORKDIR}"/${P} docs
+}
+
+src_install() {
+	dobin pgAdmin4
+
+	cd "${WORKDIR}"/${P} || die
+
+	local APP_DIR=/usr/share/${PN}/web
+	insinto "${APP_DIR}"
+	doins -r web/.
+	newins - config_local.py <<-EOF
+		SERVER_MODE = False
+		UPGRADE_CHECK_ENABLED = False
+	EOF
+	python_optimize "${D}${APP_DIR}"
+
+	insinto /etc/xdg/pgadmin
+	newins - pgadmin4.conf <<-EOF
+		[General]
+		ApplicationPath=${APP_DIR}
+		PythonPath=$(python_get_sitedir)
+	EOF
+
+	if use doc; then
+		rm -r docs/en_US/_build/html/_sources || die
+		insinto /usr/share/${PN}/docs/en_US/_build
+		doins -r docs/en_US/_build/html
+	fi
+
+	local s
+	for s in 16 32 48 64 72 96 128 192 256; do
+		convert runtime/pgAdmin4.png -resize ${s}x${s} ${PN}_${s}.png || die
+		newicon -s ${s} ${PN}_${s}.png ${PN}.png
+	done
+	domenu "${FILESDIR}"/${PN}.desktop
+}