gentoo resync : 05.12.2021

1 files changed, 79 insertions, 0 deletions

diff --git a/dev-lang/clipsjni/clipsjni-6.40.ebuild b/dev-lang/clipsjni/clipsjni-6.40.ebuild
new file mode 100644
index 000000000000..a6d8f93e099d
--- /dev/null
+++ b/dev-lang/clipsjni/clipsjni-6.40.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+JAVA_PKG_IUSE="source"
+
+inherit desktop toolchain-funcs xdg java-pkg-2
+
+DESCRIPTION="Tool for building Expert Systems (Java version)"
+HOMEPAGE="http://www.clipsrules.net/"
+
+CLPN="clips_jni_$(ver_cut 1)$(ver_cut 2)"
+SRC_URI="https://sourceforge.net/projects/clipsrules/files/CLIPS/${PV}/${CLPN}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN^^}"
+
+LICENSE="public-domain"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="examples"
+
+RDEPEND=">=virtual/jre-1.8:*"
+DEPEND=">=virtual/jdk-1.8:*"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-library-src_makefile.lnx-remove_hardcoded.patch"
+	"${FILESDIR}/${PN}-makefile.lnx-java.patch"
+)
+
+src_prepare() {
+	xdg_environment_reset
+	tc-export AR CC
+
+	rm ./*.dll ./*.jar ./*jnilib || die
+	java-pkg-2_src_prepare
+
+	default
+}
+
+src_compile() {
+	pushd library-src || die
+	emake -f makefile.lnx
+	popd || die
+
+	if use examples ; then
+		emake -f makefile.lnx
+	else
+		emake -f makefile.lnx clipsjni ide
+	fi
+}
+
+src_install() {
+	java-pkg_doso ./library-src/libCLIPSJNI.so
+	java-pkg_dojar CLIPSIDE.jar CLIPSJNI.jar
+
+	local e
+	for e in clipside clipsjni ; do
+		java-pkg_dolauncher ${e} --jar ${e^^}.jar
+	done
+
+	doicon ./java-src/net/sf/clipsrules/jni/examples/ide/resources/CLIPS.png
+
+	make_desktop_entry  \
+		clipside CLIPSIDE CLIPS "Development;IDE"
+	make_desktop_entry  \
+		clipsjni CLIPSJNI CLIPS "Development;ConsoleOnly;" "Terminal=true"
+
+	if use examples ; then
+		insinto /usr/share/clipsjni/examples
+		doins ./*Demo.jar
+	fi
+
+	use source && java-pkg_dosrc ./java-src
+}
+
+pkg_preinst() {
+	java-pkg-2_pkg_preinst
+	xdg_pkg_preinst
+}