gentoo auto-resync : 20:02:2025 - 00:15:26

2 files changed, 139 insertions, 0 deletions

diff --git a/dev-lang/pypy3-exe/Manifest b/dev-lang/pypy3-exe/Manifest
index c4b8e77549a4..b6c95381aece 100644
--- a/dev-lang/pypy3-exe/Manifest
+++ b/dev-lang/pypy3-exe/Manifest
@@ -1,4 +1,6 @@
 DIST pypy3.11-gentoo-patches-7.3.18_p1-r1.tar.xz 4712 BLAKE2B 474b61b2b9daa10d664545b3967cda2976d682f7f8a207a604240645afa86f4ab7c181c5f86dc82dc2b2da9520023d812ca349768bb3e124db17d5376f403ea4 SHA512 a79a98bd454b4d60e8c81d94c07a02a5212ca143d81bdafde227791afe8f502fb5c069bec809c6172aa4545c158f2f6b26cc7337246cccc8a66aea91300974a7
+DIST pypy3.11-gentoo-patches-7.3.18_p2.tar.xz 5680 BLAKE2B b96421224573009ca459693f4bd0df60e1383c412244b556332721402d91f07f1d13d94c4950e878ad2f3e739bc846d90d3f35a43bc07176fa837faeeac638e7 SHA512 c7e2dee74b692cf81ed201053941543cafcd6b8036bb507978ba53d6a4ab997bf2ee0f2bf57d110837b813d14f168054c6f22d1ff1ce27705e41762d91d842e3
 DIST pypy3.11-v7.3.18-src.tar.bz2 24908760 BLAKE2B e467d0b9ad254382bc727be0d2eea61573857a9638f0f7c896069bc2db9052876a1c9c77f12672728754287e0f69fc38a6cd8d7235e9be82de87292e409e85a4 SHA512 d4337a69c46c86594ae3eae09b8ab83db073eb4955f4e04bb8168ac412e8e55698938c2045f3e5d3c6a459a19cdf45a08af63e7587922a5d879fba373c6c9faf
 EBUILD pypy3-exe-3.11.7.3.18.ebuild 2842 BLAKE2B d0c14cce42ac67cac4b8cb3ad4fa1e3e7b79890cc72bceb1409cc3c57c4e295e8751097fd47dfa829c384c4134082fc36e3e48636dd23782941580c08fa7387a SHA512 4705831d61c9b1cb82802bdacf279d4352d2721a532e9561ac07b90f1a36a08c1fcaeb3116cb516d2c8251fd6024c5daddca15cacb1847cfde75c36f0051bcdd
+EBUILD pypy3-exe-3.11.7.3.18_p2.ebuild 2836 BLAKE2B 1deebc86c30a6737c1970f47d1ec7d3c584f07c14a14bd44662cf7d26a1d69b1da01a2e9de3d1ce37d06f5e0a4219080518fe43c71825c93a28e40e390524b3d SHA512 b3cbecfa4d2a1011c533610f9628f13e5f017c9d90f66f5c00fb30234d28f7d47a0ce69866838abbe2f638f7f36f82a52fe6b47252473765134935b5c20f90a4
 MISC metadata.xml 572 BLAKE2B cfcd1422ec312338fd876bc4747a962ac3c4bd06e28a3891489b065fba4c7be2daa6955f51e8136d9b8cf7b68bb7eb887b6f419ee9fd626ebd6db204acb7995d SHA512 c79250d47e3d5c99c2c903bfc185449cc41f88e2b923b8eae1401e83c0f23fa1a12ad85f50b6e25844e805e543ae897ccf43185a1bdf9f992dff765249e55bc1
diff --git a/dev-lang/pypy3-exe/pypy3-exe-3.11.7.3.18_p2.ebuild b/dev-lang/pypy3-exe/pypy3-exe-3.11.7.3.18_p2.ebuild
new file mode 100644
index 000000000000..76bfdf01614c
--- /dev/null
+++ b/dev-lang/pypy3-exe/pypy3-exe-3.11.7.3.18_p2.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit check-reqs pax-utils toolchain-funcs
+
+PYVER=$(ver_cut 1-2)
+PATCHSET_PV=$(ver_cut 3-)
+PYPY_PV=${PATCHSET_PV%_p*}
+
+MY_P="pypy${PYVER}-v${PYPY_PV/_}"
+PATCHSET="pypy${PYVER}-gentoo-patches-${PATCHSET_PV/_rc/rc}"
+
+DESCRIPTION="PyPy3.11 executable (build from source)"
+HOMEPAGE="
+	https://pypy.org/
+	https://github.com/pypy/pypy/
+"
+SRC_URI="
+	https://downloads.python.org/pypy/${MY_P}-src.tar.bz2
+	https://buildbot.pypy.org/pypy/${MY_P}-src.tar.bz2
+	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
+"
+S="${WORKDIR}/${MY_P}-src"
+
+LICENSE="MIT"
+SLOT="${PV%_p*}"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+jit low-memory ncurses cpu_flags_x86_sse2"
+
+RDEPEND="
+	app-arch/bzip2:0=
+	dev-libs/expat:0=
+	dev-libs/libffi:0=
+	>=sys-libs/zlib-1.1.3:0=
+	virtual/libintl:0=
+	ncurses? ( sys-libs/ncurses:0= )
+	!dev-lang/pypy3-exe-bin:${SLOT}
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	|| (
+		dev-lang/pypy:2.7
+		dev-python/pypy
+	)
+	virtual/pkgconfig
+"
+
+check_env() {
+	if use low-memory; then
+		CHECKREQS_MEMORY="1750M"
+		use amd64 && CHECKREQS_MEMORY="3500M"
+	else
+		CHECKREQS_MEMORY="3G"
+		use amd64 && CHECKREQS_MEMORY="6G"
+	fi
+
+	check-reqs_pkg_pretend
+}
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && check_env
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && check_env
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+	default
+}
+
+src_configure() {
+	tc-export CC
+
+	local jit_backend
+	if use jit; then
+		jit_backend='--jit-backend='
+
+		# We only need the explicit sse2 switch for x86.
+		# On other arches we can rely on autodetection which uses
+		# compiler macros. Plus, --jit-backend= doesn't accept all
+		# the modern values...
+
+		if use x86; then
+			if use cpu_flags_x86_sse2; then
+				jit_backend+=x86
+			else
+				jit_backend+=x86-without-sse2
+			fi
+		else
+			jit_backend+=auto
+		fi
+	fi
+
+	local args=(
+		--no-shared
+		$(usex jit -Ojit -O2)
+
+		${jit_backend}
+
+		pypy/goal/targetpypystandalone
+		--withmod-bz2
+		$(usex ncurses --with{,out}mod-_minimal_curses)
+	)
+
+	local interp=( pypy )
+	if use low-memory; then
+		local -x PYPY_GC_MAX_DELTA=200MB
+		interp+=( --jit loop_longevity=300 )
+	fi
+
+	# translate into the C sources
+	# we're going to build them ourselves since otherwise pypy does not
+	# free up the unneeded memory before spawning the compiler
+	set -- "${interp[@]}" rpython/bin/rpython --batch --source "${args[@]}"
+	echo -e "\033[1m${@}\033[0m"
+	"${@}" || die "translation failed"
+}
+
+src_compile() {
+	emake -C "${T}"/usession*-0/testing_1
+}
+
+src_install() {
+	cd "${T}"/usession*-0 || die
+	newbin "testing_1/pypy${PYVER}-c" "pypy${PYVER}-c-${PYPY_PV}"
+	insinto "/usr/include/pypy${PYVER}/${PYPY_PV}"
+	doins *.h
+	pax-mark m "${ED}/usr/bin/pypy${PYVER}-c-${PYPY_PV}"
+}