gentoo resync : 12.05.2022

2 files changed, 118 insertions, 0 deletions

diff --git a/dev-libs/libical/Manifest b/dev-libs/libical/Manifest
index b6c04b273979..4d1b34a2ed67 100644
--- a/dev-libs/libical/Manifest
+++ b/dev-libs/libical/Manifest
@@ -3,5 +3,6 @@ AUX libical-3.0.4-tests.patch 747 BLAKE2B 41c72700e8a87c3665144bf12e7ea2c7f74c17
 DIST libical-3.0.12.tar.gz 883537 BLAKE2B a67cbf767f5dba7717c80b2ed90f257025544b6fbbd85e4d10712fb63ec5d750c00e9a1d664b0c75f7e833847aeee2fc1412866bf4b599ead663132b3665835f SHA512 e97aec11895d4c51fcb1fe32598f5fc23bbffc26274d1f46e74d1b9a365bea65446563224b852d13a763334eab0375e77cabb5ba535d3b2f89b652bbe24b4517
 DIST libical-3.0.14.tar.gz 887795 BLAKE2B 8c073b77b5e4e6b24e3dfae7ac7a5f88da874bdfa53489cd04afd4d458d2fc963d39c2816691e777003ca9af510ceaf7bab9d7e1021942aa9c3adaad32ca8341 SHA512 36da5516672976c71b049a12af36164d91f9b655f81f1884766558149f25e80c30e64d15da848842f8a629295d708f39ce6fa63a3b0da39b5cbeb91911a4e6d8
 EBUILD libical-3.0.12.ebuild 2470 BLAKE2B b88d73cf9650df8db27900f7d6cf7dec9147fbec3baa47739a2952d04b7296896db5a045822462b5083791ab744da8572f875c9c3cfeb0b56638c6bfd91e1ac5 SHA512 1ad241526b56cf35498e582887e66813486b7922eef140b92b0a12861f6ef2d373b798961eab25870e031f352909ed9e20443e0991bf725f25e68f7e2f5c1163
+EBUILD libical-3.0.14-r1.ebuild 2440 BLAKE2B 4c80199afe8ad9cb6326d45099b35da71d6ccaca648fc32dbe56230aadcc515d4143bb0d276806504ba921bb72395ebffa6be2bd47e69848884c0107aa41e5ce SHA512 1d1e5f6dc065b5450149c4516a6e23e1b3a741ce6c98bdd13c4c3c288e8e9f77f78dc1b009dbdbb94ccec09bcde1c6230852e45ba9a50e7a864ab7a4ab29955d
 EBUILD libical-3.0.14.ebuild 2483 BLAKE2B 2c8f9a13664b4bbf048ddb2ff2d527fe19afa756ebeb6095ec499476e3e5905c5096ba29065b4debbff0e8e748a0c648a982fbf7629a348904e958a34c159c69 SHA512 d756f5e5513b0b313222ca381fb2c3c48522e7928c6b1454db2336cbb09de4819d90da890f962186638dcf8acfe219c00e5faa89a7afd41aaf1b217e27aa7124
 MISC metadata.xml 415 BLAKE2B a03d59a58e875698695319e5f427ef82ef11dd8aaa457cc6647039ec57583d730d53c5040b5b76007bf9662a78684968791f0a15ae7172007d4c49ffe8fd2318 SHA512 0663988285e1881903c0e8f62bd5ef99c26089b54f4abfeaa0a97f5ecc9820586b1a20077ddea24bf4e513b8049110f08c33acde433777adc1dd6d03f7ea7966
diff --git a/dev-libs/libical/libical-3.0.14-r1.ebuild b/dev-libs/libical/libical-3.0.14-r1.ebuild
new file mode 100644
index 000000000000..727ee343e87a
--- /dev/null
+++ b/dev-libs/libical/libical-3.0.14-r1.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+VALA_USE_DEPEND="vapigen"
+inherit cmake python-any-r1 vala
+
+DESCRIPTION="Implementation of basic iCAL protocols"
+HOMEPAGE="https://github.com/libical/libical"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( MPL-2.0 LGPL-2.1 )"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+IUSE="doc examples +glib +introspection static-libs test vala"
+
+REQUIRED_USE="introspection? ( glib ) vala? ( introspection )"
+
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	dev-libs/icu:=
+	glib? ( dev-libs/glib:2 )
+"
+DEPEND="${COMMON_DEPEND}
+	glib? ( dev-libs/libxml2:2 )
+"
+RDEPEND="${COMMON_DEPEND}
+	sys-libs/timezone-data
+"
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen[dot]
+		glib? ( dev-util/gtk-doc )
+	)
+	introspection? ( dev-libs/gobject-introspection )
+	test? (
+		${PYTHON_DEPS}
+		glib? ( $(python_gen_any_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]') )
+	)
+	vala? ( $(vala_depend) )
+"
+
+DOCS=(
+	AUTHORS README.md ReleaseNotes.txt TEST THANKS TODO
+	doc/{AddingOrModifyingComponents.txt,UsingLibical.md}
+)
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.0.4-tests.patch"
+	"${FILESDIR}/${PN}-3.0.11-pkgconfig-libdir.patch"
+)
+
+python_check_deps() {
+	has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	use examples || cmake_comment_add_subdirectory examples
+	use vala && vala_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_BerkeleyDB=ON
+		-DICAL_BUILD_DOCS=$(usex doc)
+		-DICAL_GLIB=$(usex glib)
+		-DGOBJECT_INTROSPECTION=$(usex introspection)
+		-DSHARED_ONLY=$(usex !static-libs)
+		-DLIBICAL_BUILD_TESTING=$(usex test)
+		-DICAL_GLIB_VAPI=$(usex vala)
+	)
+	if use vala; then
+		mycmakeargs+=(
+			-DVALAC="${VALAC}"
+			-DVAPIGEN="${VAPIGEN}"
+		)
+	fi
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use doc; then
+		cmake_src_compile docs
+
+		HTML_DOCS=( "${BUILD_DIR}"/apidocs/html/. )
+	fi
+}
+
+src_test() {
+	local myctestargs=(
+		-E "(icalrecurtest|icalrecurtest-r)" # bug 660282
+	)
+
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	if use examples; then
+		rm examples/CMakeLists.txt || die
+		dodoc -r examples
+	fi
+}