gentoo auto-resync : 17:08:2023 - 15:32:39

1 files changed, 57 insertions, 0 deletions

diff --git a/dev-libs/libstrophe/libstrophe-0.12.3.ebuild b/dev-libs/libstrophe/libstrophe-0.12.3.ebuild
new file mode 100644
index 000000000000..bfa7f2b9db7f
--- /dev/null
+++ b/dev-libs/libstrophe/libstrophe-0.12.3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="A simple, lightweight C library for writing XMPP clients"
+HOMEPAGE="https://strophe.im/libstrophe/"
+SRC_URI="
+	https://github.com/strophe/${PN}/releases/download/${PV}/${P}.tar.xz
+"
+LICENSE="|| ( MIT GPL-3 )"
+# Subslot: ${SONAME}.1 to differentiate from previous versions without SONAME
+SLOT="0/0.1"
+KEYWORDS="~amd64 ~arm64"
+IUSE="doc expat gnutls"
+
+RDEPEND="
+	expat? ( dev-libs/expat )
+	!expat? ( dev-libs/libxml2:2 )
+	gnutls? ( net-libs/gnutls:0= )
+	!gnutls? ( dev-libs/openssl:0= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+DOCS=( ChangeLog )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.12.3-allow-tests-when-static.patch"
+)
+
+src_configure() {
+	# shellcheck disable=SC2207
+	local myeconf=(
+		--enable-tls
+		$(use_with !expat libxml2)
+		$(use_with gnutls)
+	)
+	econf "${myeconf[@]}"
+}
+
+src_compile() {
+	default
+	if use doc; then
+		doxygen || die
+		HTML_DOCS=( docs/html/* )
+	fi
+}
+
+src_install() {
+	default
+	use doc && dodoc -r examples
+	find "${D}" -type f \( -name '*.la' -o -name '*.a' \) -delete || die
+}