gentoo resync : 05.02.2020

4 files changed, 128 insertions, 4 deletions

diff --git a/dev-libs/nspr/Manifest b/dev-libs/nspr/Manifest
index 85b4b3be6d38..f1ce8923688b 100644
--- a/dev-libs/nspr/Manifest
+++ b/dev-libs/nspr/Manifest
@@ -9,7 +9,9 @@ AUX nspr-4.9.5_nspr_config.patch 251 BLAKE2B 65ae8b981e758e2955b7a3358f24b7b17dc
 DIST nspr-4.20.tar.gz 1140892 BLAKE2B 2cb96b7a40c307f904dac038f016b5c0e527aaf673463cbcb59d8bb6c9d0239219402587d624f48804e33f43abd4427c87f267bf1a88a0dacffcc408ac15dc49 SHA512 22fdf7627f450b0594ebccaee170098e1a8cd0f429fd44816f1322756002ced3d69cf686c3f69f7cb30b8132d3605a9fce5457ab99d0002e6af11a3408a5c949
 DIST nspr-4.22.tar.gz 1078701 BLAKE2B 8b37031ffebf79320c91ce674d7c3a0cfbef25bfb006cb9aaff44f090110b35ea2768f83dae4a793723f8e2f3aecabc1a4b8042cd1b0ab0aade30781e43f9d62 SHA512 d34271f0692905162f71b02cf6f62a8ebf779159335e4ed286ee8d51faaad633a61c9392bada86d976bca2b5aa47c8760085de30dbd13c9cfa423582c31db37b
 DIST nspr-4.24.tar.gz 1078825 BLAKE2B 3a773768c31334fa4f3f406d838d430dccfbcf5f7bd34dca422b199265f17fc08ef3d5d1e6df5468efeeeace8b5f8a38ece518e6bdbcdf811c2642d43be80c6c SHA512 b020031ed7a8997099c11e0772779c7b10d15b4f6b14e2b1832732943e8b8224afa952ce04a1914c1553af9d3973a6d9cacf08058ee6fff35102e3b2ec0943c1
-EBUILD nspr-4.20.ebuild 3770 BLAKE2B d27554e938728d5dda0bbd6da5223b994bb106b2bf9af1631c4f0f66cfee3eea384f4f665356bffd5b1cb87c82f475c9099e767235cce02c06408e5987b9cd09 SHA512 cc0067760312e923bad46dd322ea193decb62f8deb6d50519f3373e837d1c0aaf8cc75f28b8b0439f9f89566ebcba1c15837713535446abef7b583b7b2680af1
-EBUILD nspr-4.22.ebuild 3865 BLAKE2B 69207a7090aac468f09ac874cf1070e33fef8338ad3c7900373ca39f29845cb3f0fef1c197c3fb90ab78c7d1efcdd25edc5185a9ef84df82cf2414c96c9fd69c SHA512 9877374a313c217c8c17c17434ae243446be9ef1beb20c58683207135f2a18c1085f4bff0d8b8ce20bc57cd730825fcd97f59813b91dcc081c15277dcd839826
+DIST nspr-4.25.tar.gz 1079633 BLAKE2B 377e5ec0e60cca13f1ee988adb10870bbb6cb9e4eb61e4434152418d4f8d446741a192d7019298ec2669b8e190cacb6a1ca9c4b2838e9b14dd3590ed40facdd2 SHA512 b9aa576e0da37e8729088fe559d94030cf18f277c1f7a30104d3088a804913343ed884645c0adb62144da475e20934b359f897bf3ae9a6ebb5f9daf283d5a562
+EBUILD nspr-4.20.ebuild 3771 BLAKE2B bb3acc31dce12797676844a0d4becab46e4096ffb869baf9856dd3bf5453b40a03a79b8fce932aeb1f0da654eea1654a6aee06dc81a95add08076a3c47ded5c5 SHA512 49cdd10845eedb22d151ca16319a99781d71c02d4a4b1ae0f86424695d181449ba375c2136b6778f7e1ef08e80c8d813784c53d10b5d125b1bfd68381b6fe9ad
+EBUILD nspr-4.22.ebuild 3866 BLAKE2B d06d5802bb4cf147eef99551cb6dbb9727efdd8cf3ec202b17cae8204831868433b632d0270b1e83a82656bb7c6af12281db86ade223198a5042ec8615474dc0 SHA512 4d2fa3d9b533fc990d824a24d2c71345611409a5c205de5bf0f5dc3ed3d413b1b5fbe94ce115e75a3891e6960ce53b1eaa85eb8ae56e8996b6da38239767fd23
 EBUILD nspr-4.24.ebuild 3943 BLAKE2B 425caf054f7b308e6c9a6a9b911bd7f594959f566fc691dd821e8d6fbdf3e98a5a0689dd3fcf0772da6989e1ed69b615fd86ec394ac963ab7cd58002371ffa13 SHA512 c01b2d44c50bdf750daaaf53647b0423865c8e72f80ca6e5feba4cf77f81b288421d1fe54f34ead168ccbf3aa87da82d64d02a4e2db3a1ded31b10bf9bc56ce0
+EBUILD nspr-4.25.ebuild 3943 BLAKE2B 6c7c97ffa992259f8af3fccc2fc4442725aaa072fed0132360eb20f7aa7302f84de303bad4c73a7db0b510c7dbd3bc8a3e569f35d338f9e9817c10fd3c9ad8e8 SHA512 da462495bd77b6745170a3da6dc891ee6ae4c59847f9bef3812d576628cdf848bcede1e18b70f577d7f369d71c7039429c9fb2fcf01fb2e7c26b43735683017f
 MISC metadata.xml 349 BLAKE2B 06dabb7ec8263989dcff436449a820af581cc04ce9de05d7c4553751c8d9c6dc43a2af221c69107fca9ae046a1b3ec807cd3f3122195cffd23de9c6ce8b1c258 SHA512 5185204ed18d7e0e4a48f918dfd871a18c62572968767566b6e0c028075e1054ec8028aac412de0c598936a79e3f70486ef889f96b720e2b15d862cf91b12b23
diff --git a/dev-libs/nspr/nspr-4.20.ebuild b/dev-libs/nspr/nspr-4.20.ebuild
index 19ed970007c3..44bbbffaf876 100644
--- a/dev-libs/nspr/nspr-4.20.ebuild
+++ b/dev-libs/nspr/nspr-4.20.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://archive.mozilla.org/pub/nspr/releases/v${PV}/src/${P}.tar.gz"
 
 LICENSE="|| ( MPL-2.0 GPL-2 LGPL-2.1 )"
 SLOT="0"
-KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 s390 ~sh sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 s390 ~sh sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
 IUSE="debug"
 
 MULTILIB_CHOST_TOOLS=(
diff --git a/dev-libs/nspr/nspr-4.22.ebuild b/dev-libs/nspr/nspr-4.22.ebuild
index 8a508486ba00..a4d3ed14045c 100644
--- a/dev-libs/nspr/nspr-4.22.ebuild
+++ b/dev-libs/nspr/nspr-4.22.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://archive.mozilla.org/pub/nspr/releases/v${PV}/src/${P}.tar.gz"
 
 LICENSE="|| ( MPL-2.0 GPL-2 LGPL-2.1 )"
 SLOT="0"
-KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sh sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sh sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
 IUSE="debug elibc_musl"
 
 MULTILIB_CHOST_TOOLS=(
diff --git a/dev-libs/nspr/nspr-4.25.ebuild b/dev-libs/nspr/nspr-4.25.ebuild
new file mode 100644
index 000000000000..c238ea281780
--- /dev/null
+++ b/dev-libs/nspr/nspr-4.25.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools toolchain-funcs multilib-minimal
+
+MIN_PV="$(ver_cut 2)"
+
+DESCRIPTION="Netscape Portable Runtime"
+HOMEPAGE="http://www.mozilla.org/projects/nspr/"
+SRC_URI="https://archive.mozilla.org/pub/nspr/releases/v${PV}/src/${P}.tar.gz"
+
+LICENSE="|| ( MPL-2.0 GPL-2 LGPL-2.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug elibc_musl"
+
+MULTILIB_CHOST_TOOLS=(
+	/usr/bin/nspr-config
+)
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.23-prtime.patch
+	"${FILESDIR}"/${PN}-4.7.1-solaris.patch
+	"${FILESDIR}"/${PN}-4.10.6-solaris.patch
+	"${FILESDIR}"/${PN}-4.8.4-darwin-install_name.patch
+	"${FILESDIR}"/${PN}-4.8.9-link-flags.patch
+	# We do not need to pass -L$libdir via nspr-config --libs
+	"${FILESDIR}"/${PN}-4.9.5_nspr_config.patch
+)
+
+src_prepare() {
+	cd "${S}"/nspr || die
+
+	default
+
+	use elibc_musl && eapply "${FILESDIR}"/${PN}-4.21-ipv6-musl-support.patch
+
+	# rename configure.in to configure.ac for new autotools compatibility
+	if [[ -e "${S}"/nspr/configure.in ]] ; then
+		einfo "Renaming configure.in to configure.ac"
+		mv "${S}"/nspr/configure.{in,ac} || die
+	else
+		elog "configure.in rename logic can be removed from ebuild."
+	fi
+
+	# We must run eautoconf to regenerate configure
+	eautoconf
+
+	# make sure it won't find Perl out of Prefix
+	sed -i -e "s/perl5//g" "${S}"/nspr/configure || die
+
+	# Respect LDFLAGS
+	sed -i -e 's/\$(MKSHLIB) \$(OBJS)/\$(MKSHLIB) \$(LDFLAGS) \$(OBJS)/g' \
+		"${S}"/nspr/config/rules.mk || die
+}
+
+multilib_src_configure() {
+	# We use the standard BUILD_xxx but nspr uses HOST_xxx
+	tc-export_build_env BUILD_CC
+	export HOST_CC=${BUILD_CC} HOST_CFLAGS=${BUILD_CFLAGS} HOST_LDFLAGS=${BUILD_LDFLAGS}
+	tc-export AR CC CXX RANLIB
+	[[ ${CBUILD} != ${CHOST} ]] \
+		&& export CROSS_COMPILE=1 \
+		|| unset CROSS_COMPILE
+
+	local myconf=(
+		--libdir="${EPREFIX}/usr/$(get_libdir)"
+		$(use_enable debug)
+		$(use_enable !debug optimize)
+	)
+
+	# The configure has some fancy --enable-{{n,x}32,64bit} switches
+	# that trigger some code conditional to platform & arch. This really
+	# matters for the few common arches (x86, ppc) but we pass a little
+	# more of them to be future-proof.
+
+	# use ABI first, this will work for most cases
+	case "${ABI}" in
+		alpha|arm|hppa|m68k|o32|ppc|s390|sh|sparc|x86) ;;
+		n32) myconf+=( --enable-n32 );;
+		x32) myconf+=( --enable-x32 );;
+		s390x|*64) myconf+=( --enable-64bit );;
+		default) # no abi actually set, fall back to old check
+			einfo "Running a short build test to determine 64bit'ness"
+			echo > "${T}"/test.c || die
+			${CC} ${CFLAGS} ${CPPFLAGS} -c "${T}"/test.c -o "${T}"/test.o || die
+			case $(file "${T}"/test.o) in
+				*32-bit*x86-64*) myconf+=( --enable-x32 );;
+				*64-bit*|*ppc64*|*x86_64*) myconf+=( --enable-64bit );;
+				*32-bit*|*ppc*|*i386*) ;;
+				*) die "Failed to detect whether your arch is 64bits or 32bits, disable distcc if you're using it, please";;
+			esac ;;
+		*) ;;
+	esac
+
+	# Ancient autoconf needs help finding the right tools.
+	LC_ALL="C" ECONF_SOURCE="${S}/nspr" \
+	ac_cv_path_AR="${AR}" \
+	econf "${myconf[@]}"
+}
+
+multilib_src_install() {
+	# Their build system is royally confusing, as usual
+	MINOR_VERSION=${MIN_PV} # Used for .so version
+	emake DESTDIR="${D}" install
+
+	einfo "removing static libraries as upstream has requested!"
+	rm "${ED}"/usr/$(get_libdir)/*.a || die "failed to remove static libraries."
+
+	# install nspr-config
+	dobin config/nspr-config
+
+	# Remove stupid files in /usr/bin
+	rm "${ED}"/usr/bin/prerr.properties || die
+
+	# This is used only to generate prerr.c and prerr.h at build time.
+	# No other projects use it, and we don't want to depend on perl.
+	# Talked to upstream and they agreed w/punting.
+	rm "${ED}"/usr/bin/compile-et.pl || die
+}