gentoo resync : 29.12.2022

2 files changed, 81 insertions, 0 deletions

diff --git a/dev-libs/ntl/Manifest b/dev-libs/ntl/Manifest
index 6da4f045f748..640e834312c3 100644
--- a/dev-libs/ntl/Manifest
+++ b/dev-libs/ntl/Manifest
@@ -1,3 +1,4 @@
 DIST ntl-11.5.1.tar.gz 2304103 BLAKE2B 92284383451c7a810f7ee8d9a82836695d19d2a2e46b71c8c60b00acb77f4b4d3bad5497a309616a3e3188567d20203f5ad31295130ab0f3ace08417188c9fda SHA512 cf1f642b8a0f9cdc6dda888e07183817dc67ff494e56a852053aeb15b3d2a0e61fbc05824779c5d1f20b8115fba6f97266acf7e0b0b527c25df5989c86d5928f
 EBUILD ntl-11.5.1-r1.ebuild 2071 BLAKE2B 63b41f8d75761d7d002238955c7c3a8f81af90cd3db436eec1e5a30017995f2ffa2456d912e3b103bdb25d3916e5d6f94b17f70ae5960b91fa83bb870f3201a3 SHA512 71a9d39b67f2144522090613a9143585ae17727d200958a89ae7317d6dacaadcdf09d5d10fcca2c00c77f507243fd7e56bfef9cbdc989c42a27f828a8be18dc6
+EBUILD ntl-11.5.1-r2.ebuild 2109 BLAKE2B acdc6f33fba7f2dfc82abec4a303eea07e4f364127376fb84305382041b2ebee4ba10874ada71cd3fee70c73ed7005b9ebcfe3e4883301ac32f643897862afc9 SHA512 a07995d7da5fa543982344701b9d57ab9110db4ee8643926312777fd5fcfaf38d712fdf3442c34f8dfabd1f110c67c13a302016639ff053654600771c3cb6c0a
 MISC metadata.xml 553 BLAKE2B cdfae3ba1eecfe54b279aec52c8a122226eb0247dfad805feb9f0854705e99247f15e42dedd6d08164a8d9c9cc9db871a481f6bcebad3062ac32ad05c3c32b7b SHA512 ca5e891461461757b75aea48a2cf631cc871daf33159c1f2c2a9a9e6acad43db97733de1c24754709e9b4eb1173a50af3ce63690443ce5ddd6794de9580b0d19
diff --git a/dev-libs/ntl/ntl-11.5.1-r2.ebuild b/dev-libs/ntl/ntl-11.5.1-r2.ebuild
new file mode 100644
index 000000000000..fd3a3c4dcc5d
--- /dev/null
+++ b/dev-libs/ntl/ntl-11.5.1-r2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs gnuconfig
+
+DESCRIPTION="High-performance and portable C++ number theory library"
+HOMEPAGE="https://www.shoup.net/ntl/ https://github.com/libntl/ntl"
+SRC_URI="https://www.shoup.net/ntl/${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/44"
+KEYWORDS="~amd64 ~arm64 ~ppc ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="doc static-libs threads cpu_flags_x86_avx2"
+
+BDEPEND="dev-lang/perl"
+DEPEND="dev-libs/gmp:0=
+	dev-libs/gf2x
+	threads? ( >=dev-libs/gf2x-1.2 )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${P}/src"
+
+DOCS=( "${WORKDIR}/${P}"/README )
+
+src_unpack() {
+	default
+	gnuconfig_update "${S}/libtool-origin/"
+}
+
+src_configure() {
+	# The DoConfig script builds its own libtool, but doesn't
+	# really try to set up the build environment (bug 718892).
+	export CC="$(tc-getCC)"
+	export CXX="$(tc-getCXX)"
+
+	# Currently the build system can build a static library or both
+	# static and shared libraries, but not only shared libraries. The
+	# name NTL_GMP_LIP is *not* a typo.
+	perl DoConfig \
+		PREFIX="${EPREFIX}"/usr \
+		LIBDIR="${EPREFIX}"/usr/$(get_libdir) \
+		CXXFLAGS="${CXXFLAGS}" \
+		CPPFLAGS="${CPPFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		CXX="$(tc-getCXX)" \
+		AR="$(tc-getAR)" \
+		RANLIB="$(tc-getRANLIB)" \
+		SHARED=on \
+		NTL_GMP_LIP=on \
+		NTL_GF2X_LIB=on \
+		NTL_THREADS=$(usex threads on off) \
+		NTL_ENABLE_AVX_FFT=$(usex cpu_flags_x86_avx2 on off) \
+		NATIVE=off \
+		|| die "DoConfig failed"
+
+	if use doc; then
+		DOCS+=( "${WORKDIR}/${P}"/doc/*.txt )
+		HTML_DOCS=( "${WORKDIR}/${P}"/doc/*.html "${WORKDIR}/${P}"/doc/*.gif )
+	fi
+
+	# 780534 - Required for rlibtool so it can find the generated libtool
+	ln -sf libtool-build/libtool . || die
+}
+
+src_install() {
+	default
+
+	if ! use static-libs; then
+		# bug #775884
+		find "${ED}" -name '*.la' -delete || die
+
+		# Use rm -f because the static archive may not be created when
+		# using (for example) slibtool-shared.
+		rm -f "${ED}/usr/$(get_libdir)"/libntl.a || die
+	fi
+
+	rm -r "${ED}"/usr/share/doc/NTL || die
+}