gentoo resync : 16.09.2020

1 files changed, 57 insertions, 0 deletions

diff --git a/dev-libs/sord/sord-9999.ebuild b/dev-libs/sord/sord-9999.ebuild
new file mode 100644
index 000000000000..e1388ab2877c
--- /dev/null
+++ b/dev-libs/sord/sord-9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE='threads(+)'
+inherit python-any-r1 waf-utils multilib-build multilib-minimal git-r3
+
+DESCRIPTION="Library for storing RDF data in memory"
+HOMEPAGE="http://drobilla.net/software/sord/"
+EGIT_REPO_URI="https://github.com/drobilla/sord.git"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS=""
+IUSE="doc static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/libpcre
+	>=dev-libs/serd-0.30.0
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	doc? ( app-doc/doxygen )
+	virtual/pkgconfig"
+
+DOCS=( "AUTHORS" "NEWS" "README.md" )
+
+src_prepare() {
+	sed -i -e 's/^.*run_ldconfig/#\0/' wscript || die
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	waf-utils_src_configure \
+		--docdir=/usr/share/doc/${PF} \
+		$(multilib_native_usex doc --docs "") \
+		$(usex test --test "") \
+		$(usex static-libs --static "")
+}
+
+multilib_src_test() {
+	./waf test || die
+}
+
+multilib_src_compile() {
+	waf-utils_src_compile
+	default
+}
+
+multilib_src_install() {
+	waf-utils_src_install
+	default
+}