gentoo auto-resync : 01:06:2024 - 00:07:06

2 files changed, 274 insertions, 0 deletions

diff --git a/dev-lisp/sbcl/Manifest b/dev-lisp/sbcl/Manifest
index c154b6ced962..7da61eab7cb1 100644
--- a/dev-lisp/sbcl/Manifest
+++ b/dev-lisp/sbcl/Manifest
@@ -21,7 +21,10 @@ DIST sbcl-2.4.3-source.tar.bz2 8126417 BLAKE2B 11c304c4f28e41940e2981e6f9f3401db
 DIST sbcl-2.4.3-x86-64-linux-binary.tar.bz2 12003023 BLAKE2B a833630bf3c8ceac1aab64d351d7a19b73cac4906c60c6344ba2222c17831da749bc3b5d0d5fa3246c9c2a847c60e9c78567845efdd9cba50d59f2dfaef1b186 SHA512 c884d04b317b1a7ebd4c5f00b17058819d32c59e3cab437296868bc132a77e34bb6e286e7378c7d27f2b07055f879171533273978bbda84d7de9618638219088
 DIST sbcl-2.4.4-source.tar.bz2 8065883 BLAKE2B b0fd0d462dfa95435c09c44077edbcae0606081adf543e4994310f399491a5a52104114d8b281d459e49c7475fd427e0c20b210b750678e796e12b81882e6267 SHA512 2730b1375b8e871bda96e0fa8536142f5d93e454187a4b6dbe2a2b439c694a5d013648a320aa183f268fae7fda046f8a2a9ce80a315d198db4822d380f845600
 DIST sbcl-2.4.4-x86-64-linux-binary.tar.bz2 11643944 BLAKE2B 4328fda19201f4061955863bde89cabce3e07135bcba0f9bb085531965c019f3323e5c2411a297b08ee8e3b28d5eb81a3fd490d05673be002a5523f3b3466ae1 SHA512 94e06c055fe23da6b1a62a29e93fdc93e629943abf7b24c731b744cd9b32dc2ebd2c8ec1905b80a55944465dd2ee093721f7db196938426becc2c830237d0982
+DIST sbcl-2.4.5-source.tar.bz2 8070024 BLAKE2B 3c6a698ea59ad7399fa60744ad3380d5b3fdcb7a5a475717003fe0533e24876d4c5e9f32332bf420dd4e5812a900c2c8f621b99091102240f8940b3bb6520694 SHA512 53ae147a5c47a1492a0733a16d1bfa499c01b9866e12edd13afbea57277fca75078aff16c810d7996a84fa720326c82e20add6f24d02016571a46bc5fcc023a9
+DIST sbcl-2.4.5-x86-64-linux-binary.tar.bz2 11470027 BLAKE2B 858f56f1ecb1c1376f25a8690b6421c3ac0612f2b8f940f3d1cceac462d7022b8874b9347fefa610e37e982d888f54dd46cd1790a3b528a8f79b4193f16ba56d SHA512 76e68a1aec2e36b8a34d6c7773d0ff71530cf8a0a170d2244164f06adda5440e070444d20a2d9233467f692d49ba6f4a42845facb22a8dc60a3235a496334dbd
 EBUILD sbcl-2.3.5.ebuild 9204 BLAKE2B 4a609973bc0ba1286760c483fc53999fa64556df6a3360a657418427d91907a095cf8138f67c961506f25d56fb249c3db8db55abe0d4300cb494aac02ee73c04 SHA512 1782cb8dc6ce4f6ddfdbf28b442d0e6f851409f1968cdc3b550b6c742f258009be6ab39fab5cd4f632390b248a61dc3bd51a3168d37adf71c58f142fdee70146
 EBUILD sbcl-2.4.3.ebuild 9295 BLAKE2B 08c2524868217a4f771ffc4a1491d1ca4c7de96681b25882b90e63270a8113444a6fcf0f6a3af1a5f6295cbe7cc1952543631af69ef34db4b8692f3d41baa63f SHA512 7302b0cef9f67b3affb8f9166dc6f32e6fdd171deef59cf14437bbbf0d4bdf56ecf0b57aa073ab8506d7973123e0b3c3de1f172f0f21aac76db86eb35378a262
 EBUILD sbcl-2.4.4.ebuild 9298 BLAKE2B beca9ae8d8489b495aaee4227c635f05f4d2a83f8bffa0284ee0763e65f118229cecb8500177b8e2cf25e6b95548f67bd7047d247c174e7ddf974ea71dac6482 SHA512 8e5816af81e01f2852eed70662e20e51e3ecbc3cdf7af4a50b5a408833f0b3638142bc37130850521f80247c35d7fc24488809fb1f40862e782332e152a4a9c7
+EBUILD sbcl-2.4.5.ebuild 9298 BLAKE2B 16ea73b9a27accd121f8b92349b7a12cfa71ed6297d6f4916b11d0fbfd076db77fd770cf969db91d4fcee9b78798bff23bdf54a983f01f61fd9258d63f4134fd SHA512 7fe552c26db3c40c1c7d6370acbbf9d812aa4f7e537d728bdb10196002071370f9f49601667cac430a18ef6efee794b8635524898f196a3a70f977cd777c63a9
 MISC metadata.xml 1498 BLAKE2B 26fd9f6375ae06e3158d09608aeb5ea4a50e6ce7dd002c7c8f7827cf05798aebd7cba2b630238495ab0a27152ef6e485af2101446dd31e9592e9ffb14fb012b2 SHA512 c56fbecceb20c9550b4f5a07662276af099e7a600ad4f93139e25618aefd57bc45489fd85049da35b1f19937f2293640c1f953cb76780b849435b26f1f27285f
diff --git a/dev-lisp/sbcl/sbcl-2.4.5.ebuild b/dev-lisp/sbcl/sbcl-2.4.5.ebuild
new file mode 100644
index 000000000000..76fa22daaeaf
--- /dev/null
+++ b/dev-lisp/sbcl/sbcl-2.4.5.ebuild
@@ -0,0 +1,271 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic pax-utils toolchain-funcs
+
+#same order as http://www.sbcl.org/platform-table.html
+BV_X86=1.4.3
+BV_AMD64=2.4.5
+BV_PPC=1.2.7
+BV_PPC64LE=1.5.8
+BV_SPARC=1.0.28
+BV_ALPHA=1.0.28
+BV_ARM=2.3.3
+BV_ARM64=1.4.2
+BV_X64_MACOS=1.2.11
+BV_PPC_MACOS=1.0.47
+BV_X86_SOLARIS=1.2.7
+BV_X64_SOLARIS=1.2.7
+BV_SPARC_SOLARIS=1.0.23
+
+DESCRIPTION="Steel Bank Common Lisp (SBCL) is an implementation of ANSI Common Lisp"
+HOMEPAGE="https://www.sbcl.org/ http://sbcl.sourceforge.net/"
+BSD_SOCKETS_TEST_PATCH=bsd-sockets-test-2.3.6.patch
+SRC_URI="https://downloads.sourceforge.net/sbcl/${P}-source.tar.bz2
+	https://dev.gentoo.org/~grozin/${BSD_SOCKETS_TEST_PATCH}.gz
+	!system-bootstrap? (
+		x86? ( https://downloads.sourceforge.net/sbcl/${PN}-${BV_X86}-x86-linux-binary.tar.bz2 )
+		amd64? ( https://downloads.sourceforge.net/sbcl/${PN}-${BV_AMD64}-x86-64-linux-binary.tar.bz2 )
+		ppc? ( https://downloads.sourceforge.net/sbcl/${PN}-${BV_PPC}-powerpc-linux-binary.tar.bz2 )
+		ppc64? ( https://downloads.sourceforge.net/sbcl/${PN}-${BV_PPC64LE}-ppc64le-linux-binary.tar.bz2 )
+		sparc? ( https://downloads.sourceforge.net/sbcl/${PN}-${BV_SPARC}-sparc-linux-binary.tar.bz2 )
+		alpha? ( https://downloads.sourceforge.net/sbcl/${PN}-${BV_ALPHA}-alpha-linux-binary.tar.bz2 )
+		arm? ( https://downloads.sourceforge.net/sbcl/${PN}-${BV_ARM}-armhf-linux-binary.tar.bz2 )
+		arm64? ( https://downloads.sourceforge.net/sbcl/${PN}-${BV_ARM64}-arm64-linux-binary.tar.bz2 )
+		x64-macos? ( https://downloads.sourceforge.net/sbcl/${PN}-${BV_X64_MACOS}-x86-64-darwin-binary.tar.bz2 )
+		ppc-macos? ( https://downloads.sourceforge.net/sbcl/${PN}-${BV_PPC_MACOS}-powerpc-darwin-binary.tar.bz2 )
+		x64-solaris? ( https://downloads.sourceforge.net/sbcl/${PN}-${BV_X64_SOLARIS}-x86-64-solaris-binary.tar.bz2 )
+	)"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="-* ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="system-bootstrap debug doc source +threads +unicode +zstd"
+
+CDEPEND=">=dev-lisp/asdf-3.3:= \
+	prefix? ( dev-util/patchelf )"
+# bug #843851
+BDEPEND="${CDEPEND}
+		dev-debug/strace
+		doc? ( sys-apps/texinfo >=media-gfx/graphviz-2.26.0 )
+		system-bootstrap? ( || ( dev-lisp/clisp dev-lisp/sbcl ) )"
+RDEPEND="${CDEPEND}
+		zstd? ( app-arch/zstd )
+		!prefix? ( elibc_glibc? ( >=sys-libs/glibc-2.6 ) )"
+
+# Disable warnings about executable stacks, as this won't be fixed soon by upstream
+QA_EXECSTACK="usr/bin/sbcl"
+
+CONFIG="${S}/customize-target-features.lisp"
+ENVD="${T}/50sbcl"
+
+# Prevent ASDF from using the system libraries
+CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)"
+ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)"
+
+usep() {
+	use ${1} && echo "true" || echo "false"
+}
+
+sbcl_feature() {
+	echo "$( [[ ${1} == "true" ]] && echo "(enable ${2})" || echo "(disable ${2})")" >> "${CONFIG}"
+}
+
+sbcl_apply_features() {
+	sed 's/^X//' > "${CONFIG}" <<-'EOF'
+	(lambda (list)
+	X  (flet ((enable  (x) (pushnew x list))
+	X         (disable (x) (setf list (remove x list))))
+	EOF
+	if use x86 || use amd64; then
+		sbcl_feature "$(usep threads)" ":sb-thread"
+	fi
+	sbcl_feature "true" ":sb-ldb"
+	sbcl_feature "false" ":sb-test"
+	sbcl_feature "$(usep unicode)" ":sb-unicode"
+	sbcl_feature "$(usep zstd)" ":sb-core-compression"
+	sbcl_feature "$(usep debug)" ":sb-xref-for-internals"
+	sed 's/^X//' >> "${CONFIG}" <<-'EOF'
+	X    )
+	X  list)
+	EOF
+	cat "${CONFIG}"
+}
+
+src_unpack() {
+	unpack ${A}
+	if ! use system-bootstrap ; then
+		mv sbcl-*-* sbcl-binary || die
+	fi
+	cd "${S}"
+}
+
+src_prepare() {
+	# bug #468482
+	eapply "${FILESDIR}"/concurrency-test-2.0.1.patch
+	# bugs #486552, #527666, #517004
+	eapply "${WORKDIR}"/${BSD_SOCKETS_TEST_PATCH}
+	# bugs #560276, #561018
+	eapply "${FILESDIR}"/sb-posix-test-2.2.9.patch
+	# bug #767742
+	eapply "${FILESDIR}"/etags-2.1.0.patch
+	# Use ${PV} as build-id, bug #797574
+	eapply "${FILESDIR}"/build-id-2.4.3.patch
+
+	eapply "${FILESDIR}"/verbose-build-2.0.3.patch
+
+	eapply_user
+
+	# Make sure the *FLAGS variables are sane.
+	# sbcl needs symbols in resulting binaries, so building with the -s linker flag will fail.
+	strip-unsupported-flags
+	filter-flags -fomit-frame-pointer -Wl,-s
+	filter-ldflags -s
+
+	# original bugs #526194, #620532
+	# this broke no-pie default builds, c.f. bug #632670
+	# Pass CFLAGS down by appending our value, to let users override
+	# the default values.
+	# Keep passing LDFLAGS down via the LINKFLAGS variable.
+	sed -e "s@\(CFLAGS += -g .*\)\$@\1 ${CFLAGS}@" \
+		-e "s@LINKFLAGS += -g\$@LINKFLAGS += ${LDFLAGS}@" \
+		-i src/runtime/GNUmakefile || die
+
+	sed -e "s@SBCL_PREFIX=\"/usr/local\"@SBCL_PREFIX=\"${EPREFIX}/usr\"@" \
+		-i make-config.sh || die
+
+	# Use installed ASDF version
+	cp "${EPREFIX}"/usr/share/common-lisp/source/asdf/build/asdf.lisp contrib/asdf/ || die
+	# Avoid installation of ASDF info page. See bug #605752
+	sed '/INFOFILES/s/asdf.info//' -i doc/manual/Makefile || die
+
+	use source && sed 's%"$(BUILD_ROOT)%$(MODULE).lisp "$(BUILD_ROOT)%' -i contrib/vanilla-module.mk
+
+	# Some shells(such as dash) don't have "time" as builtin
+	# and we don't want to DEPEND on sys-process/time
+	sed "s,^time ,," -i make.sh || die
+	sed "s,/lib,/$(get_libdir),g" -i install.sh || die
+	# #define SBCL_HOME ...
+	sed "s,/usr/local/lib,${EPREFIX}/usr/$(get_libdir),g" -i src/runtime/runtime.c || die
+	# change location of /etc/sbclrc ...
+	sed  "s,/etc/sbclrc,${EPREFIX}/etc/sbclrc,g" -i src/code/toplevel.lisp || die
+
+	find . -type f -name .cvsignore -delete
+}
+
+src_configure() {
+	# customizing SBCL version as per
+	# http://sbcl.cvs.sourceforge.net/sbcl/sbcl/doc/PACKAGING-SBCL.txt?view=markup
+	echo -e ";;; Auto-generated by Gentoo\n\"gentoo-${PR}\"" > branch-version.lisp-expr
+
+	# set interpreter for Prefix
+	if use prefix ; then
+		patchelf --set-interpreter \
+			"${EPREFIX}/$(get_libdir)"/ld-linux-x86-64.so.2 \
+			"${WORKDIR}"/sbcl-binary/src/runtime/sbcl
+	fi
+
+	# applying customizations
+	sbcl_apply_features
+}
+
+src_compile() {
+	local bindir="${WORKDIR}"/sbcl-binary
+	local bootstrap_lisp="sh ${bindir}/run-sbcl.sh --no-sysinit --no-userinit --disable-debugger"
+
+	if use system-bootstrap ; then
+		if has_version "dev-lisp/sbcl" ; then
+			bootstrap_lisp="sbcl --no-sysinit --no-userinit --disable-debugger"
+		else
+			bootstrap_lisp="clisp"
+		fi
+	fi
+
+	# Bug #869434
+	append-cppflags -D_GNU_SOURCE
+
+	# clear the environment to get rid of non-ASCII strings, see bug #174702
+	# set HOME for paludis
+	env - HOME="${T}" PATH="${PATH}" \
+		CC="$(tc-getCC)" AS="$(tc-getAS)" LD="$(tc-getLD)" \
+		CPPFLAGS="${CPPFLAGS}" CFLAGS="${CFLAGS}" ASFLAGS="${ASFLAGS}" LDFLAGS="${LDFLAGS}" \
+		SBCL_HOME="/usr/$(get_libdir)/sbcl" SBCL_SOURCE_ROOT="/usr/$(get_libdir)/sbcl/src" \
+		GNUMAKE=make PV=${PV} ./make.sh \
+		"${bootstrap_lisp}" \
+		|| die "make failed"
+
+	# need to set HOME because libpango(used by graphviz) complains about it
+	if use doc; then
+		env - HOME="${T}" PATH="${PATH}" \
+			CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)" \
+			ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)" \
+			make -C doc/manual info html || die "Cannot build manual"
+		env - HOME="${T}" PATH="${PATH}" \
+			CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)" \
+			ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)" \
+			make -C doc/internals info html || die "Cannot build internal docs"
+	fi
+}
+
+src_test() {
+	ewarn "Unfortunately, it is known that some tests fail eg."
+	ewarn "run-program.impure.lisp. This is an issue of the upstream's"
+	ewarn "development and not of Gentoo's side. Please, before filing"
+	ewarn "any bug(s) search for older submissions. Thank you."
+	time ( cd tests && sh run-tests.sh )
+}
+
+src_install() {
+	# install system-wide initfile
+	dodir /etc/
+	sed 's/^X//' > "${ED}"/etc/sbclrc <<-EOF
+	;;; The following is required if you want source location functions to
+	;;; work in SLIME, for example.
+	X
+	(setf (logical-pathname-translations "SYS")
+	X      '(("SYS:SRC;**;*.*.*" #p"${EPREFIX}/usr/$(get_libdir)/sbcl/src/**/*.*")
+	X        ("SYS:CONTRIB;**;*.*.*" #p"${EPREFIX}/usr/$(get_libdir)/sbcl/**/*.*")))
+	X
+	;;; Setup ASDF2
+	(load "${EPREFIX}/etc/common-lisp/gentoo-init.lisp")
+	EOF
+
+	# Install documentation
+	unset SBCL_HOME
+	INSTALL_ROOT="${ED}/usr" LIB_DIR="${EPREFIX}/usr/$(get_libdir)" DOC_DIR="${ED}/usr/share/doc/${PF}" \
+		sh install.sh || die "install.sh failed"
+
+	# bug #517008
+	pax-mark -mr "${D}"/usr/bin/sbcl
+
+	# rm empty directories lest paludis complain about this
+	find "${ED}" -empty -type d -exec rmdir -v {} +
+
+	if use doc; then
+		dodoc -r doc/internals/sbcl-internals
+
+		doinfo doc/manual/*.info*
+		doinfo doc/internals/sbcl-internals.info
+
+		docinto internals-notes
+		dodoc doc/internals-notes/*
+	else
+		rm -Rv "${ED}/usr/share/doc/${PF}" || die
+	fi
+
+	# install the SBCL source
+	if use source; then
+		./clean.sh
+		cp -av src "${ED}/usr/$(get_libdir)/sbcl/" || die
+		for d in contrib/*/; do
+			cp -av "$d" "${ED}/usr/$(get_libdir)/sbcl/" || die
+		done
+	fi
+
+	# necessary for running newly-saved images
+	echo "SBCL_HOME=${EPREFIX}/usr/$(get_libdir)/${PN}" > "${ENVD}"
+	echo "SBCL_SOURCE_ROOT=${EPREFIX}/usr/$(get_libdir)/${PN}/src" >> "${ENVD}"
+	doenvd "${ENVD}"
+}