gentoo resync : 11.08.2021

3 files changed, 241 insertions, 0 deletions

diff --git a/dev-lisp/Manifest.gz b/dev-lisp/Manifest.gz
index 5555a931b7cd..d8d06803f712 100644
--- a/dev-lisp/Manifest.gz
+++ b/dev-lisp/Manifest.gz
diff --git a/dev-lisp/sbcl/Manifest b/dev-lisp/sbcl/Manifest
index 38d227bdd08f..6ce3a8b9187c 100644
--- a/dev-lisp/sbcl/Manifest
+++ b/dev-lisp/sbcl/Manifest
@@ -36,8 +36,11 @@ DIST sbcl-2.1.5-source.tar.bz2 6566902 BLAKE2B 3e98a3d996120baf7cbddbe595aacc076
 DIST sbcl-2.1.5-x86-64-linux-binary.tar.bz2 10155269 BLAKE2B 8456fbe477d6afc4becf4ec2fadb296e40532f02ea0ad5de61891cf68384450028e85e52d44164323c1a40b5f67c591114cd1a077de305b3f1b20484310bf5a6 SHA512 cb90c2bc6bed5f5f3af9831cd520580d4e8207ee45ae3572a17cf0da21563ce8e03d1c0e22099d05b750e0f76b2a0701918c80e25e2b7a9846d8cc5169f82f7c
 DIST sbcl-2.1.6-source.tar.bz2 6579274 BLAKE2B bb3c915b1f3889575065d0737eaadb5a19b00748ab508d90bb30218c8ef09527ee2533271700b68fedb28030727cde86aaa7b7ed1d2e6b02cecc79b6e6ed0376 SHA512 fa8088e5275451863b9aa908c0718e03801340fc87c514caed8a67df6fd443a0cdc1eb90f90605c0de757c4be5e9e502a944c4856fea98d719f5135457ca41c7
 DIST sbcl-2.1.6-x86-64-linux-binary.tar.bz2 10106836 BLAKE2B d362f22402cfc183b6b8a9251e20d51672a4870bbc427e9f718bcfb02ae3e459f426b8f4bf4b568c864b56602e5d7b285ab5f1c5aece397385e17439934d23fa SHA512 3382829bfe6bd85b00eeaed04830de7e966d014dd626c7d5635c916a4fa9517f4404af4e5498cc6b4b8e00db9079e350db7cb6860c0c4a4921e99ba221f2ba6e
+DIST sbcl-2.1.7-source.tar.bz2 6622050 BLAKE2B df464999381a4b2e563606a4a25bf00b72b74b3964e548f7bb4de6a43e4f6c3d00eefdc2b0c7e673bd58aff02725ae9af001b46a859320cf3c53b6f882eb44ce SHA512 52996bced71d003d7337c237b6078c6d7cece71a0e69ba77e2c735b9d0e92204e50a1e5eeaea946ca2adcc9c3a334b14693735817c0a19a4fbb4caf9cca3b52b
+DIST sbcl-2.1.7-x86-64-linux-binary.tar.bz2 10117534 BLAKE2B 613356710b2fc80bd00f49ba0da1fd3f0a6fcf25b1343f70957800a41c46e89468646fa1800566fa06217c25976875a7c10910cbd279d0294c7297eea10cb991 SHA512 32b9c87d21d3bb431a52d36b8fb390e9f4e42bc2803a970a5bbf655e57341061385fa5465a70511c92fdfa4e69c683c2ec056768c4e44dc9305e1b2260be307a
 EBUILD sbcl-1.3.11.ebuild 7866 BLAKE2B 88e6b869fe4655f2a971a53213844fb08a4c6b59bc42a57dd2616c39df93e9721304f6a94b457ed3ac07ee7abb1f8321a747901f42f211b87e6a5041624c4e90 SHA512 41dfd91a56ee2dd4e2421c4fac03cd4263f4fdaee60db9e81745ec552199a7a97083194f72e1585bee7241e593a10eab3c57cbd300858e1752b909412ffca1d7
 EBUILD sbcl-1.4.9.ebuild 8213 BLAKE2B c227898102be21a2ef44b906e4316f07ad6711ef4bfd662fe391aaebbe6a515158fd41a05db644604f6fd494c04af7cb08b93e4a1dd40aa146ccbe08115be247 SHA512 674cfadbccca53a1cc4f665aa935cbc7a65cefbdd70bfb3f9b14f3b813706b2b5273380e67ca4a76b81aaa5363423feeb74fafe423121ff7e8c7427b48cc39c1
 EBUILD sbcl-2.1.5.ebuild 8233 BLAKE2B 1b36498a792e2a3facbc3d050cfe68097b2e69df4d08e036a4f2fa1f5927dd0279ceed72248ffc2afe5df3cb1a9c7dc87fb57603465316e1929a7a04edead55a SHA512 90f1aa10baa49c48a3b73b1ecfdc597b2bffd58fde896184b82c0045761da7d642b069116066145d335593ce28936c50a8138f20ecd649cbe01be8d59eaba5fa
 EBUILD sbcl-2.1.6.ebuild 8233 BLAKE2B ca5778c4c9f0606e9e908e6cc797e67bb9ed74aa162932fd891492eb0366a9be5214335fcd89813fe9bb3fe5e23bd33088e364cd15b6ee585b1a1302191b47bd SHA512 bd0fc6d0ff1d7454333cdce372e4bbba03abbc7d08aad47732ca0bbd9a0dd7b3b5957449206b63585bddf5150448c8433ba133aa585e431cb055d64e73e23602
+EBUILD sbcl-2.1.7.ebuild 8233 BLAKE2B 556fc1326eebe42af01cbc7fc71f3c4adf0b6bcd4d0bcdeb9534d9b7d7fcc8e3b214ab8ca1f114ecfe758fe8b98bddd74a1fd0effc754011223b092936aae9e5 SHA512 20f441352cf86e6875aa58fc9e9e67d185d23063b436fca0e1daed85e6e62e6cb65b8227b4098b9b97c8924d9866de131d08b2fde381c0f5e4760c10825f7a7f
 MISC metadata.xml 1184 BLAKE2B ea8559ab65d1a9579739f537dfaa90790755e6ad448c9362516d18679c13d6f58c42de8f8840f3b109be4ae8744abe27af5efad88740e4aa7aad7edb5aee001d SHA512 b9621f775d3be8fb18ef0feb81f87f8cf956f79e077bfce6fe228c436763a67ac48e9da00969bee6b925786990bfc42240d3674af5fa9d1823a4bca83c03175a
diff --git a/dev-lisp/sbcl/sbcl-2.1.7.ebuild b/dev-lisp/sbcl/sbcl-2.1.7.ebuild
new file mode 100644
index 000000000000..cee2be629969
--- /dev/null
+++ b/dev-lisp/sbcl/sbcl-2.1.7.ebuild
@@ -0,0 +1,238 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit multilib flag-o-matic pax-utils toolchain-funcs
+
+#same order as http://www.sbcl.org/platform-table.html
+BV_X86=1.4.3
+BV_AMD64=2.1.7
+BV_PPC=1.2.7
+BV_SPARC=1.0.28
+BV_ALPHA=1.0.28
+BV_ARM=1.4.11
+BV_ARM64=1.4.2
+BV_X64_MACOS=1.2.11
+BV_PPC_MACOS=1.0.47
+BV_X86_SOLARIS=1.2.7
+BV_X64_SOLARIS=1.2.7
+BV_SPARC_SOLARIS=1.0.23
+
+DESCRIPTION="Steel Bank Common Lisp (SBCL) is an implementation of ANSI Common Lisp"
+HOMEPAGE="http://sbcl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/sbcl/${P}-source.tar.bz2
+	x86? ( mirror://sourceforge/sbcl/${PN}-${BV_X86}-x86-linux-binary.tar.bz2 )
+	amd64? ( mirror://sourceforge/sbcl/${PN}-${BV_AMD64}-x86-64-linux-binary.tar.bz2 )
+	ppc? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC}-powerpc-linux-binary.tar.bz2 )
+	sparc? ( mirror://sourceforge/sbcl/${PN}-${BV_SPARC}-sparc-linux-binary.tar.bz2 )
+	alpha? ( mirror://sourceforge/sbcl/${PN}-${BV_ALPHA}-alpha-linux-binary.tar.bz2 )
+	arm? ( mirror://sourceforge/sbcl/${PN}-${BV_ARM}-armhf-linux-binary.tar.bz2 )
+	arm64? ( mirror://sourceforge/sbcl/${PN}-${BV_ARM64}-arm64-linux-binary.tar.bz2 )
+	x64-macos? ( mirror://sourceforge/sbcl/${PN}-${BV_X64_MACOS}-x86-64-darwin-binary.tar.bz2 )
+	ppc-macos? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC_MACOS}-powerpc-darwin-binary.tar.bz2 )
+	x86-solaris? ( mirror://sourceforge/sbcl/${PN}-${BV_X86_SOLARIS}-x86-solaris-binary.tar.bz2 )
+	x64-solaris? ( mirror://sourceforge/sbcl/${PN}-${BV_X64_SOLARIS}-x86-64-solaris-binary.tar.bz2 )
+	sparc-solaris? ( mirror://sourceforge/sbcl/${PN}-${BV_SPARC_SOLARIS}-sparc-solaris-binary.tar.bz2 )"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-solaris"
+IUSE="debug doc source +threads +unicode zlib"
+
+CDEPEND=">=dev-lisp/asdf-3.3:="
+DEPEND="${CDEPEND}
+		doc? ( sys-apps/texinfo >=media-gfx/graphviz-2.26.0 )"
+RDEPEND="${CDEPEND}
+		!prefix? ( elibc_glibc? ( >=sys-libs/glibc-2.6 ) )"
+
+# Disable warnings about executable stacks, as this won't be fixed soon by upstream
+QA_EXECSTACK="usr/bin/sbcl"
+
+CONFIG="${S}/customize-target-features.lisp"
+ENVD="${T}/50sbcl"
+
+# Prevent ASDF from using the system libraries
+CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)"
+ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)"
+
+usep() {
+	use ${1} && echo "true" || echo "false"
+}
+
+sbcl_feature() {
+	echo "$( [[ ${1} == "true" ]] && echo "(enable ${2})" || echo "(disable ${2})")" >> "${CONFIG}"
+}
+
+sbcl_apply_features() {
+	sed 's/^X//' > "${CONFIG}" <<-'EOF'
+	(lambda (list)
+	X  (flet ((enable  (x) (pushnew x list))
+	X         (disable (x) (setf list (remove x list))))
+	EOF
+	if use x86 || use amd64; then
+		sbcl_feature "$(usep threads)" ":sb-thread"
+	fi
+	sbcl_feature "true" ":sb-ldb"
+	sbcl_feature "false" ":sb-test"
+	sbcl_feature "$(usep unicode)" ":sb-unicode"
+	sbcl_feature "$(usep zlib)" ":sb-core-compression"
+	sbcl_feature "$(usep debug)" ":sb-xref-for-internals"
+	sed 's/^X//' >> "${CONFIG}" <<-'EOF'
+	X    )
+	X  list)
+	EOF
+	cat "${CONFIG}"
+}
+
+src_unpack() {
+	unpack ${A}
+	mv sbcl-*-* sbcl-binary || die
+	cd "${S}"
+}
+
+src_prepare() {
+	# bug #468482
+	eapply "${FILESDIR}"/concurrency-test-2.0.1.patch
+	# bugs #486552, #527666, #517004
+	eapply "${FILESDIR}"/bsd-sockets-test-2.0.5.patch
+	# bugs #560276, #561018
+	eapply "${FILESDIR}"/sb-posix-test-1.2.15.patch
+	# bug #767742
+	eapply "${FILESDIR}"/etags-2.1.0.patch
+
+	eapply "${FILESDIR}"/verbose-build-2.0.3.patch
+
+	eapply_user
+
+	# Make sure the *FLAGS variables are sane.
+	# sbcl needs symbols in resulting binaries, so building with the -s linker flag will fail.
+	strip-unsupported-flags
+	filter-flags -fomit-frame-pointer -Wl,-s
+	filter-ldflags -s
+
+	# original bugs #526194, #620532
+	# this broke no-pie default builds, c.f. bug #632670
+	# Pass CFLAGS down by appending our value, to let users override
+	# the default values.
+	# Keep passing LDFLAGS down via the LINKFLAGS variable.
+	sed -e "s@\(CFLAGS += -g .*\)\$@\1 ${CFLAGS}@" \
+		-e "s@LINKFLAGS += -g\$@LINKFLAGS += ${LDFLAGS}@" \
+		-i src/runtime/GNUmakefile || die
+
+	sed -e "s@SBCL_PREFIX=\"/usr/local\"@SBCL_PREFIX=\"${EPREFIX}/usr\"@" \
+		-i make-config.sh || die
+
+	# Use installed ASDF version
+	cp "${EPREFIX}"/usr/share/common-lisp/source/asdf/build/asdf.lisp contrib/asdf/ || die
+	# Avoid installation of ASDF info page. See bug #605752
+	sed '/INFOFILES/s/asdf.info//' -i doc/manual/Makefile || die
+
+	use source && sed 's%"$(BUILD_ROOT)%$(MODULE).lisp "$(BUILD_ROOT)%' -i contrib/vanilla-module.mk
+
+	# Some shells(such as dash) don't have "time" as builtin
+	# and we don't want to DEPEND on sys-process/time
+	sed "s,^time ,," -i make.sh || die
+	sed "s,/lib,/$(get_libdir),g" -i install.sh || die
+	# #define SBCL_HOME ...
+	sed "s,/usr/local/lib,${EPREFIX}/usr/$(get_libdir),g" -i src/runtime/runtime.c || die
+	# change location of /etc/sbclrc ...
+	sed  "s,/etc/sbclrc,${EPREFIX}/etc/sbclrc,g" -i src/code/toplevel.lisp || die
+
+	find . -type f -name .cvsignore -delete
+}
+
+src_configure() {
+	# customizing SBCL version as per
+	# http://sbcl.cvs.sourceforge.net/sbcl/sbcl/doc/PACKAGING-SBCL.txt?view=markup
+	echo -e ";;; Auto-generated by Gentoo\n\"gentoo-${PR}\"" > branch-version.lisp-expr
+
+	# applying customizations
+	sbcl_apply_features
+}
+
+src_compile() {
+	local bindir="${WORKDIR}"/sbcl-binary
+
+	# clear the environment to get rid of non-ASCII strings, see bug #174702
+	# set HOME for paludis
+	env - HOME="${T}" PATH="${PATH}" \
+		CC="$(tc-getCC)" AS="$(tc-getAS)" LD="$(tc-getLD)" \
+		CPPFLAGS="${CPPFLAGS}" CFLAGS="${CFLAGS}" ASFLAGS="${ASFLAGS}" LDFLAGS="${LDFLAGS}" \
+		GNUMAKE=make ./make.sh \
+		"sh ${bindir}/run-sbcl.sh --no-sysinit --no-userinit --disable-debugger" \
+		|| die "make failed"
+
+	# need to set HOME because libpango(used by graphviz) complains about it
+	if use doc; then
+		env - HOME="${T}" PATH="${PATH}" \
+			CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)" \
+			ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)" \
+			make -C doc/manual info html || die "Cannot build manual"
+		env - HOME="${T}" PATH="${PATH}" \
+			CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)" \
+			ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)" \
+			make -C doc/internals info html || die "Cannot build internal docs"
+	fi
+}
+
+src_test() {
+	ewarn "Unfortunately, it is known that some tests fail eg."
+	ewarn "run-program.impure.lisp. This is an issue of the upstream's"
+	ewarn "development and not of Gentoo's side. Please, before filing"
+	ewarn "any bug(s) search for older submissions. Thank you."
+	time ( cd tests && sh run-tests.sh )
+}
+
+src_install() {
+	# install system-wide initfile
+	dodir /etc/
+	sed 's/^X//' > "${ED}"/etc/sbclrc <<-EOF
+	;;; The following is required if you want source location functions to
+	;;; work in SLIME, for example.
+	X
+	(setf (logical-pathname-translations "SYS")
+	X      '(("SYS:SRC;**;*.*.*" #p"${EPREFIX}/usr/$(get_libdir)/sbcl/src/**/*.*")
+	X        ("SYS:CONTRIB;**;*.*.*" #p"${EPREFIX}/usr/$(get_libdir)/sbcl/**/*.*")))
+	X
+	;;; Setup ASDF2
+	(load "${EPREFIX}/etc/common-lisp/gentoo-init.lisp")
+	EOF
+
+	# Install documentation
+	unset SBCL_HOME
+	INSTALL_ROOT="${ED}/usr" LIB_DIR="${EPREFIX}/usr/$(get_libdir)" DOC_DIR="${ED}/usr/share/doc/${PF}" \
+		sh install.sh || die "install.sh failed"
+
+	# bug #517008
+	pax-mark -mr "${D}"/usr/bin/sbcl
+
+	# rm empty directories lest paludis complain about this
+	find "${ED}" -empty -type d -exec rmdir -v {} +
+
+	if use doc; then
+		dodoc -r doc/internals/sbcl-internals
+
+		doinfo doc/manual/*.info*
+		doinfo doc/internals/sbcl-internals.info
+
+		docinto internals-notes
+		dodoc doc/internals-notes/*
+	else
+		rm -Rv "${ED}/usr/share/doc/${PF}" || die
+	fi
+
+	# install the SBCL source
+	if use source; then
+		./clean.sh
+		cp -av src "${ED}/usr/$(get_libdir)/sbcl/" || die
+		for d in contrib/*/; do
+			cp -av "$d" "${ED}/usr/$(get_libdir)/sbcl/" || die
+		done
+	fi
+
+	# necessary for running newly-saved images
+	echo "SBCL_HOME=${EPREFIX}/usr/$(get_libdir)/${PN}" > "${ENVD}"
+	echo "SBCL_SOURCE_ROOT=${EPREFIX}/usr/$(get_libdir)/${PN}/src" >> "${ENVD}"
+	doenvd "${ENVD}"
+}