gentoo resync : 03.03.2021

7 files changed, 370 insertions, 0 deletions

diff --git a/dev-lisp/Manifest.gz b/dev-lisp/Manifest.gz
index a59d5b4091c0..0445144ea581 100644
--- a/dev-lisp/Manifest.gz
+++ b/dev-lisp/Manifest.gz
diff --git a/dev-lisp/abcl/Manifest b/dev-lisp/abcl/Manifest
index 80a0d412ed89..bc7bb8d69285 100644
--- a/dev-lisp/abcl/Manifest
+++ b/dev-lisp/abcl/Manifest
@@ -1,3 +1,5 @@
 DIST abcl-src-1.5.0.tar.gz 1187678 BLAKE2B 4c6993ab90d6fe12e93bf185ecdc16dd5c69ff5c65881e74db51ba9a8167e3a3de4b25ff9971084e92499f654aacec2a07757d100a5977944076476d47c17438 SHA512 d56c23a82103dfebb3361903af096f923738008e551f3b5e07e00f0423c8ade0b07a388b7834b5d79d9191863b38db2c17fa27bffd848d7cba88d6bb67e32db3
+DIST abcl-src-1.8.0.tar.gz 2613411 BLAKE2B cd50e5df0b7e48c902bc904ca4ea0e9c293241e04cfda154cb388c5f58da921645333fca8e0a95768a550fcb2a5b6346b3e8958745138ea6826f5c5a62ef0faf SHA512 90cc2d1e52a4dc83a0159a5763d2c7eb344952786a805a82180e0000a0cae26d89ae5a9293b629b7b5131eac05668fe21711abca32aebe05d7400187b0b3793b
 EBUILD abcl-1.5.0.ebuild 786 BLAKE2B 1f34923c3287dd474d33d30f22cc160c55fa39e129255236c9956b95d18d536f48b062799bcdc5f6476cec3f427388cf77110c857bd363e496b61f32cabc4f1f SHA512 9f6d3e7e298d798531bca0cf5f943b44dafa9a903a693f6edbbc7195b1300acc80c9ecffb47630eada7d63f4afa417ba54d8ef01b0cbc263dda10a7a42af3708
+EBUILD abcl-1.8.0.ebuild 784 BLAKE2B b518ac53ae90fdb6af090b6167693cb842ee13a47b0584a623bc045507c0a1fef80863e19f6961fd2077298a6eddeede19c704ae15df70035689d9057f68a99f SHA512 45d2910776289354856869b0f7b32e0af880802154a0ff09c92cf0bb71240e8b21cad877ee8a5a54cfa0266ba6af09a08baeab85a6834f021b45ec9286e4d29b
 MISC metadata.xml 509 BLAKE2B 484256eac69bd0c0bf0bffadc8513a1f9f7c90e22db8a45d3008517936aad0f00d028ab97987c954c3cd086c0e0824bba3969a24d1c544be47c2221f817bd5cc SHA512 7216031e2c4c73c0d0bcf4b454cfa7d859dc21cd6d1000792357dcda973e6ea78917d06077b283d0ed19bda53c01917fcccd562fab5770499b9cfae4dace1ef5
diff --git a/dev-lisp/abcl/abcl-1.8.0.ebuild b/dev-lisp/abcl/abcl-1.8.0.ebuild
new file mode 100644
index 000000000000..139a56a5ef2d
--- /dev/null
+++ b/dev-lisp/abcl/abcl-1.8.0.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit eutils java-pkg-2 java-ant-2
+
+MY_P=${PN}-src-${PV}
+
+DESCRIPTION="Armed Bear Common Lisp is a Common Lisp implementation for the JVM."
+HOMEPAGE="http://common-lisp.net/project/armedbear/"
+SRC_URI="http://abcl.org/releases/${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2-with-classpath-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND=">=virtual/jdk-1.8"
+RDEPEND=">=virtual/jre-1.8"
+
+S="${WORKDIR}"/${MY_P}
+
+src_compile() {
+	eant abcl.compile || die "Can't compile ABCL"
+	eant abcl.jar || die "Can't make ABCL jar archive"
+}
+
+src_install() {
+	java-pkg_dojar dist/abcl.jar
+	java-pkg_dolauncher ${PN} --java_args "-server -Xrs" --main org.armedbear.lisp.Main
+	dodoc README
+}
diff --git a/dev-lisp/ecls/Manifest b/dev-lisp/ecls/Manifest
index 4e8dffc3e105..9490249d3796 100644
--- a/dev-lisp/ecls/Manifest
+++ b/dev-lisp/ecls/Manifest
@@ -6,5 +6,6 @@ DIST ecl-20.4.24.tgz 7815444 BLAKE2B 11b908b028beaaf9243dc0f2ceaa178918ae4763a90
 DIST ecl-21.2.1.tgz 7875088 BLAKE2B b8c05fab8ce5892ad9df830e3ad230e1c646bd30bc35243703ace18f1bf963057b132d980c74b364ff30a5b776a8f161e71bfd69d7908970811ab3dddbab1aac SHA512 0849bebe1a8073ea8027cfb172c1d7781d43adb6a8b80585bd08d5674b80422d1648b6fbf718cc17a51c5de6c696514523b4d13a82e8113bf9365c95d3c28648
 EBUILD ecls-16.1.3.ebuild 2358 BLAKE2B ea2aeb0477a427e45e7f282a2da31f43c45b9b64189ec5d7bfeb5e7297a39307dcb162e594cca93c2aea53809452fe1f57609bcd6c446325781bb9a9bb388ae2 SHA512 5fc28521dd43df3560398c9782274b6fbe5421b96e1138173f8b033c5047dd24b5aeb61151423619a5369f88418f3b21bd9bc79b73554b8f99ae58d33756c4dd
 EBUILD ecls-20.4.24.ebuild 2389 BLAKE2B 4e3347c4d9aaafdf7a3f7f1454bbb18b3fa04762f23e909684fe39dddb18df05e92d79326918f2ddfbb0dbc8dcdb94530b0195cbcf86d5232b534ed5b70a5618 SHA512 9114c138fb74a15f80ca25230b68290f057e1aed205bf3ed5ba7d7109c15ab4a6c7e4db951d1e122dc2cbffac869294ceb557ef0150d7f6630c2cbefdf42d302
+EBUILD ecls-21.2.1-r1.ebuild 2036 BLAKE2B 509feed5dea520af1200f2ef0b68f58d69207a653d1d0e85661db8667343f366ea728c86b4dd833841eb1a725a0729e831b94be6038f41e30229c104a7791952 SHA512 669f05d42a8844392b95bcb1e0359b46996f24c2679623335c48aff39ca8727e81b808df4886c179c997a6704002891d82f99890584a72ca8f5f1a03c412f20f
 EBUILD ecls-21.2.1.ebuild 2077 BLAKE2B fa3478a440ad84b17ab3b7af216a5290fd74037ab48cdd53d5f36b495783a01cc48c8d232133e08a8b70d6ae13c3af872154072b71b6bd83929fd30bb5a976d8 SHA512 620cc9adc7863188418e7ee0bef019660ffed1edce295ad41d9afa50822787339c2b048a776231117ff14830979c7dd43abb4e83540ed1e7e11252b8f8e0c40a
 MISC metadata.xml 901 BLAKE2B 96892af45b0d5c6b7c0e0ee20010ce7ac068a25d024d31f2dae1acd730aaa62f7589f322d7ad0ade27a03cdae7eeef5297adcd9fb821ca67d4e1ba88de1c2a17 SHA512 15403f25533646601eb454946599d1d97353038286df0d075f923b598fe44047e525745a33f7e3dbc15fee717d6311abbe546371ecbc4c9df347771dd5c007e9
diff --git a/dev-lisp/ecls/ecls-21.2.1-r1.ebuild b/dev-lisp/ecls/ecls-21.2.1-r1.ebuild
new file mode 100644
index 000000000000..6ed6c25641d4
--- /dev/null
+++ b/dev-lisp/ecls/ecls-21.2.1-r1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils multilib
+
+# test phase only works if ecls already installed #516876
+RESTRICT="test"
+
+MY_P=ecl-${PV}
+
+DESCRIPTION="ECL is an embeddable Common Lisp implementation"
+HOMEPAGE="https://common-lisp.net/project/ecl/"
+SRC_URI="https://common-lisp.net/project/ecl/static/files/release/${MY_P}.tgz"
+
+LICENSE="BSD-2 LGPL-2.1+"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
+IUSE="cxx debug emacs gengc precisegc cpu_flags_x86_sse +threads +unicode X"
+
+CDEPEND="dev-libs/gmp:0
+		dev-libs/libffi
+		dev-libs/libatomic_ops
+		>=dev-libs/boehm-gc-7.1[threads?]
+		>=dev-lisp/asdf-2.33-r3:="
+DEPEND="${CDEPEND}
+		app-text/texi2html
+		emacs? ( >=app-editors/emacs-23.1:* >=app-eselect/eselect-emacs-1.12 )"
+RDEPEND="${CDEPEND}"
+
+S="${WORKDIR}"/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}/${PN}-16.1.3-headers-gentoo.patch"
+	"${FILESDIR}/${PN}-16.1.3-build.patch"
+)
+
+src_prepare() {
+	default
+	cp "${EPREFIX}"/usr/share/common-lisp/source/asdf/build/asdf.lisp contrib/asdf/ || die
+}
+
+src_configure() {
+	econf \
+		--with-system-gmp \
+		--enable-boehm=system \
+		--enable-longdouble=yes \
+		--with-dffi \
+		--enable-libatomic=system \
+		$(use_with cxx) \
+		$(use_enable gengc) \
+		$(use_enable precisegc) \
+		$(use_with debug debug-cflags) \
+		$(use_with cpu_flags_x86_sse sse) \
+		$(use_enable threads) \
+		$(use_with threads __thread) \
+		$(use_enable unicode) \
+		$(use_with unicode unicode-names) \
+		$(use_with X x)
+}
+
+src_compile() {
+	if use emacs; then
+		local ETAGS=$(eselect --brief etags list | sed -ne '/emacs/{p;q}')
+		[[ -n ${ETAGS} ]] || die "No etags implementation found"
+		pushd build > /dev/null || die
+		emake ETAGS=${ETAGS} TAGS
+		popd > /dev/null
+	else
+		touch build/TAGS
+	fi
+
+	#parallel make fails
+	emake -j1
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc README.md CHANGELOG
+	dodoc "${FILESDIR}"/README.Gentoo
+	pushd build/doc
+	newman ecl.man ecl.1
+	newman ecl-config.man ecl-config.1
+	popd
+}
diff --git a/dev-lisp/sbcl/Manifest b/dev-lisp/sbcl/Manifest
index 3bcebdca476a..207465bcad9e 100644
--- a/dev-lisp/sbcl/Manifest
+++ b/dev-lisp/sbcl/Manifest
@@ -39,10 +39,13 @@ DIST sbcl-2.1.0-source.tar.bz2 6534157 BLAKE2B 575638084c208104bc782e7f6419b92e8
 DIST sbcl-2.1.0-x86-64-linux-binary.tar.bz2 10121503 BLAKE2B 4ee74c18316e863ed030dcbf88f9c0997e362f158eae1be856cea2b7001e9cff213a09179c0c1c925db5de991902a19d838adc9bf5683552310a57a3debf465f SHA512 dea33b800223505b6912c78d4233b82ab544100a64506e827ff78ccef1776dace2af14856d5e37c33659928afa823c4500ada34cd3759c46e72dc91cfa23f40d
 DIST sbcl-2.1.1-source.tar.bz2 6543910 BLAKE2B a567e30ea03d2a19f85afeda385d1d8af84e87b1f0afe436c47865e8d67d3a7d3008e7353d7bef0b139ffaba6278ceb985178361ba50f82db2683637f1e2a834 SHA512 4346318bcbd28916d107d004f7da62cd4a23545432369819f1d5c25d512d89343318f4acb857f6dd59bda59b58e88979663e882455f941e81edd9002b58f68e4
 DIST sbcl-2.1.1-x86-64-linux-binary.tar.bz2 10116591 BLAKE2B f9e4d2772b23cf03af6f7e8a44192bc48269990c4c7f4a89885497044855f8b637346704aafef54998942184bd58eeb1775cb2e8ef147b4d470cbbc7d44b8773 SHA512 0bf5e8e50e172debba70216e207a8b7d0caf53ccc8d2e682f52622740dfda2320d7c69fa5f966e5c4a5838252447f3704d6b31d0dfaf0b95503ec38c5d18afca
+DIST sbcl-2.1.2-source.tar.bz2 6539563 BLAKE2B 601331d82c00a153bf7a8e5c556aea1e03eabf9bcd6c6ff874b3e96e3cf96aa8f780297eed3c87411fc1902a0ec36ee9a6b8b8ce51a4a6a8d8f0aa3491270c7e SHA512 53b7be18753bf6e2a4811d47afee3a7b1ece9c1205f73d783880f420870b784a34c07320575a1b5c6bbaf3eca2f7a82f51382f857b6a27fc19e02348ea8bdd70
+DIST sbcl-2.1.2-x86-64-linux-binary.tar.bz2 10131524 BLAKE2B 7edb4be77623ac09e650716026f1ecdc8808e9545a658b6c7ebdf0d13ea147217b65f35cfccc3682f303638ef672b822112d13c25cc809ec9b153eaaa7003085 SHA512 e491905fe4929b2dd35080acc1d67f03e7584c36580334be995f6eeec144a87d7c32f19bcc84bcb14fc3157fce0bdc37b7f1f531b1873b1bbddf365932542385
 EBUILD sbcl-1.3.11.ebuild 8275 BLAKE2B 3a54bd91f515f85f3c36eafc776fdd199001b0e576187a573c714902b1b79fae0eb552d6e7020506cba1714aed1c568b3df3a7ef43a65ac347db24ebaadc729e SHA512 4f0109295a7a17c7068636c07638da7f464032ff81221dab41e073e7dc6e8ab86268964e23b6ed97d500e0f999f3c1222b1ff836e4a3d3e045bedf25dbad26f4
 EBUILD sbcl-1.4.9.ebuild 8559 BLAKE2B 513825109663297611a5ada0a96a5f8c02d3e32d9d18721c74b1adf3a224afa1224ac7abfef4a9fbef2728a9cbe184022483ab64ce06595a55283b7b6d218d7e SHA512 5d21f6d8f3f19430cc4ffef49cf57ea6b48035e88234e2a0c69fb4e80c2607405d7c7cb4685c720736ebb39d70e6139e004334dd81e25ab5b82bbc11c00d1d2d
 EBUILD sbcl-2.0.10.ebuild 8501 BLAKE2B 8f059823a9bfcbb369fae7c319331f9d986dae249d093bca964871d90a84d7b375177186a7894e8395e3f9a744912f61eef26eaaf2bdd9be6fbca1905ee1d7b6 SHA512 9db0cbd59f3156154d927384df32875925887520072a355e909f943549194faa2204a15aabbd72c25ae24ee5ab2c11d4ca6b122a87c63a5645107a15225d97f0
 EBUILD sbcl-2.0.11.ebuild 8501 BLAKE2B 78edc8b39a8ee1dbbd0864c0aa93e745bd9b1e66ec5bca5be97435223f1a669c4e2e4abd31b5b10905d9eaf9f26ebc87596e1d2b9ec25c5779ea47a912fbd9b5 SHA512 77e4034387813a089fce1724888d06e6716fe77beaf5f6a30ea1d333744d423c4d10f18dce7f32440f21be94091eefe65f2d405375bfcb271929735b3aa25cec
 EBUILD sbcl-2.1.0.ebuild 8555 BLAKE2B d201561605da86ee73782d4460d82f3562f0f117f0d53414378c8abe58c4bd7cfd5bf7441e8059d6a4d3dfd1113cb81fa922c6fc83a371fe3959d27cc6fe7032 SHA512 cbcb9938c643b1c0d6be07cb2d8959a5e1669ce6255ae78cd649f8ee45ca97b55f62963bc641b82322ed9666f52d18653f010e7b9dedb80060a6992d0876aacc
 EBUILD sbcl-2.1.1.ebuild 8555 BLAKE2B a007118cefb8fb856a957b6e0fd830047fa40df42332ad0c505f02612209b2ec5fa067dcb6031b95f58c749121e0c1fc60a05a4d8544d89ea43e15c47dfa8717 SHA512 6f2dd56047a26298300e94a7fd2f32e0a1ed1d6a50de596035b37bda6e90ab35eb3bc67af1e34ca13fe5a11c70be4586e428e5031dbf3c05aaa22468786ce9cc
+EBUILD sbcl-2.1.2.ebuild 8555 BLAKE2B d81ce4ce030cae01d2b76f7f4a6224452942dec0f3d62371c9a582cfdf4b3975d59cbe92836da79c27fdd778f76e81be3690c886a5b6622fdae63044515b17bd SHA512 7abbfaf23d3dca40a3b5af8a2b9d8f9bc9f6689529285af124d3c140e04837e062148a09ba58f77e7a608d4922bcca5d581effe4a64e34d90912093961ccf1e8
 MISC metadata.xml 1312 BLAKE2B a03042bd9d39465fe7ae45d6b749571fc4d22cf9d7f81d3cd498b155729576ec1f2ddec03c2c662ecb23abfd19a627ba2cbe9798960009e998a8823902062118 SHA512 3c4463de4a8871ab56fe74c286977fda3037e953d5fa26162d07976efa00b0d99bc98295435a7c5233c43b27369e31eb5d1c0b4c66600477a307aa1a7a322e1c
diff --git a/dev-lisp/sbcl/sbcl-2.1.2.ebuild b/dev-lisp/sbcl/sbcl-2.1.2.ebuild
new file mode 100644
index 000000000000..82b60facb57d
--- /dev/null
+++ b/dev-lisp/sbcl/sbcl-2.1.2.ebuild
@@ -0,0 +1,245 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit multilib eutils flag-o-matic pax-utils toolchain-funcs
+
+#same order as http://www.sbcl.org/platform-table.html
+BV_X86=1.4.3
+BV_AMD64=2.1.2
+BV_PPC=1.2.7
+BV_SPARC=1.0.28
+BV_ALPHA=1.0.28
+BV_ARM=1.4.11
+BV_ARM64=1.4.2
+BV_X64_MACOS=1.2.11
+BV_PPC_MACOS=1.0.47
+BV_X86_SOLARIS=1.2.7
+BV_X64_SOLARIS=1.2.7
+BV_SPARC_SOLARIS=1.0.23
+
+DESCRIPTION="Steel Bank Common Lisp (SBCL) is an implementation of ANSI Common Lisp"
+HOMEPAGE="http://sbcl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/sbcl/${P}-source.tar.bz2
+	x86? ( mirror://sourceforge/sbcl/${PN}-${BV_X86}-x86-linux-binary.tar.bz2 )
+	amd64? ( mirror://sourceforge/sbcl/${PN}-${BV_AMD64}-x86-64-linux-binary.tar.bz2 )
+	ppc? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC}-powerpc-linux-binary.tar.bz2 )
+	sparc? ( mirror://sourceforge/sbcl/${PN}-${BV_SPARC}-sparc-linux-binary.tar.bz2 )
+	alpha? ( mirror://sourceforge/sbcl/${PN}-${BV_ALPHA}-alpha-linux-binary.tar.bz2 )
+	arm? ( mirror://sourceforge/sbcl/${PN}-${BV_ARM}-armhf-linux-binary.tar.bz2 )
+	arm64? ( mirror://sourceforge/sbcl/${PN}-${BV_ARM64}-arm64-linux-binary.tar.bz2 )
+	x64-macos? ( mirror://sourceforge/sbcl/${PN}-${BV_X64_MACOS}-x86-64-darwin-binary.tar.bz2 )
+	ppc-macos? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC_MACOS}-powerpc-darwin-binary.tar.bz2 )
+	x86-solaris? ( mirror://sourceforge/sbcl/${PN}-${BV_X86_SOLARIS}-x86-solaris-binary.tar.bz2 )
+	x64-solaris? ( mirror://sourceforge/sbcl/${PN}-${BV_X64_SOLARIS}-x86-64-solaris-binary.tar.bz2 )
+	sparc-solaris? ( mirror://sourceforge/sbcl/${PN}-${BV_SPARC_SOLARIS}-sparc-solaris-binary.tar.bz2 )"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-solaris"
+IUSE="debug doc source +threads +unicode pax_kernel zlib"
+
+CDEPEND=">=dev-lisp/asdf-3.3:="
+DEPEND="${CDEPEND}
+		doc? ( sys-apps/texinfo >=media-gfx/graphviz-2.26.0 )
+		pax_kernel? ( sys-apps/elfix )"
+RDEPEND="${CDEPEND}
+		!prefix? ( elibc_glibc? ( >=sys-libs/glibc-2.6 ) )"
+
+# Disable warnings about executable stacks, as this won't be fixed soon by upstream
+QA_EXECSTACK="usr/bin/sbcl"
+
+CONFIG="${S}/customize-target-features.lisp"
+ENVD="${T}/50sbcl"
+
+# Prevent ASDF from using the system libraries
+CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)"
+ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)"
+
+usep() {
+	use ${1} && echo "true" || echo "false"
+}
+
+sbcl_feature() {
+	echo "$( [[ ${1} == "true" ]] && echo "(enable ${2})" || echo "(disable ${2})")" >> "${CONFIG}"
+}
+
+sbcl_apply_features() {
+	sed 's/^X//' > "${CONFIG}" <<-'EOF'
+	(lambda (list)
+	X  (flet ((enable  (x) (pushnew x list))
+	X         (disable (x) (setf list (remove x list))))
+	EOF
+	if use x86 || use amd64; then
+		sbcl_feature "$(usep threads)" ":sb-thread"
+	fi
+	sbcl_feature "true" ":sb-ldb"
+	sbcl_feature "false" ":sb-test"
+	sbcl_feature "$(usep unicode)" ":sb-unicode"
+	sbcl_feature "$(usep zlib)" ":sb-core-compression"
+	sbcl_feature "$(usep debug)" ":sb-xref-for-internals"
+	sed 's/^X//' >> "${CONFIG}" <<-'EOF'
+	X    )
+	X  list)
+	EOF
+	cat "${CONFIG}"
+}
+
+src_unpack() {
+	unpack ${A}
+	mv sbcl-*-* sbcl-binary || die
+	cd "${S}"
+}
+
+src_prepare() {
+	# bug #468482
+	eapply "${FILESDIR}"/concurrency-test-2.0.1.patch
+	# bugs #486552, #527666, #517004
+	eapply "${FILESDIR}"/bsd-sockets-test-2.0.5.patch
+	# bugs #560276, #561018
+	eapply "${FILESDIR}"/sb-posix-test-1.2.15.patch
+	# bug #767742
+	eapply "${FILESDIR}"/etags-2.1.0.patch
+
+	eapply "${FILESDIR}"/verbose-build-2.0.3.patch
+
+	eapply_user
+
+	# Make sure the *FLAGS variables are sane.
+	# sbcl needs symbols in resulting binaries, so building with the -s linker flag will fail.
+	strip-unsupported-flags
+	filter-flags -fomit-frame-pointer -Wl,-s
+	filter-ldflags -s
+
+	# original bugs #526194, #620532
+	# this broke no-pie default builds, c.f. bug #632670
+	# Pass CFLAGS down by appending our value, to let users override
+	# the default values.
+	# Keep passing LDFLAGS down via the LINKFLAGS variable.
+	sed -e "s@\(CFLAGS += -g .*\)\$@\1 ${CFLAGS}@" \
+		-e "s@LINKFLAGS += -g\$@LINKFLAGS += ${LDFLAGS}@" \
+		-i src/runtime/GNUmakefile || die
+
+	sed -e "s@SBCL_PREFIX=\"/usr/local\"@SBCL_PREFIX=\"${EPREFIX}/usr\"@" \
+		-i make-config.sh || die
+
+	# Use installed ASDF version
+	cp "${EPREFIX}"/usr/share/common-lisp/source/asdf/build/asdf.lisp contrib/asdf/ || die
+	# Avoid installation of ASDF info page. See bug #605752
+	sed '/INFOFILES/s/asdf.info//' -i doc/manual/Makefile || die
+
+	use source && sed 's%"$(BUILD_ROOT)%$(MODULE).lisp "$(BUILD_ROOT)%' -i contrib/vanilla-module.mk
+
+	# Some shells(such as dash) don't have "time" as builtin
+	# and we don't want to DEPEND on sys-process/time
+	sed "s,^time ,," -i make.sh || die
+	sed "s,/lib,/$(get_libdir),g" -i install.sh || die
+	# #define SBCL_HOME ...
+	sed "s,/usr/local/lib,${EPREFIX}/usr/$(get_libdir),g" -i src/runtime/runtime.c || die
+	# change location of /etc/sbclrc ...
+	sed  "s,/etc/sbclrc,${EPREFIX}/etc/sbclrc,g" -i src/code/toplevel.lisp || die
+
+	find . -type f -name .cvsignore -delete
+}
+
+src_configure() {
+	# customizing SBCL version as per
+	# http://sbcl.cvs.sourceforge.net/sbcl/sbcl/doc/PACKAGING-SBCL.txt?view=markup
+	echo -e ";;; Auto-generated by Gentoo\n\"gentoo-${PR}\"" > branch-version.lisp-expr
+
+	# applying customizations
+	sbcl_apply_features
+}
+
+src_compile() {
+	local bindir="${WORKDIR}"/sbcl-binary
+
+	if use pax_kernel ; then
+		# To disable PaX on hardened systems
+		pax-mark -mr "${bindir}"/src/runtime/sbcl
+
+		# Hack to disable PaX on second GENESIS stage
+		sed -i -e '/^[ \t]*echo \/\/doing warm init - compilation phase$/a\    paxmark.sh -mr \.\/src\/runtime\/sbcl' \
+			"${S}"/make-target-2.sh || die "Cannot disable PaX on second GENESIS runtime"
+	fi
+
+	# clear the environment to get rid of non-ASCII strings, see bug #174702
+	# set HOME for paludis
+	env - HOME="${T}" PATH="${PATH}" \
+		CC="$(tc-getCC)" AS="$(tc-getAS)" LD="$(tc-getLD)" \
+		CPPFLAGS="${CPPFLAGS}" CFLAGS="${CFLAGS}" ASFLAGS="${ASFLAGS}" LDFLAGS="${LDFLAGS}" \
+		GNUMAKE=make ./make.sh \
+		"sh ${bindir}/run-sbcl.sh --no-sysinit --no-userinit --disable-debugger" \
+		|| die "make failed"
+
+	# need to set HOME because libpango(used by graphviz) complains about it
+	if use doc; then
+		env - HOME="${T}" PATH="${PATH}" \
+			CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)" \
+			ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)" \
+			make -C doc/manual info html || die "Cannot build manual"
+		env - HOME="${T}" PATH="${PATH}" \
+			CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)" \
+			ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)" \
+			make -C doc/internals info html || die "Cannot build internal docs"
+	fi
+}
+
+src_test() {
+	ewarn "Unfortunately, it is known that some tests fail eg."
+	ewarn "run-program.impure.lisp. This is an issue of the upstream's"
+	ewarn "development and not of Gentoo's side. Please, before filing"
+	ewarn "any bug(s) search for older submissions. Thank you."
+	time ( cd tests && sh run-tests.sh )
+}
+
+src_install() {
+	# install system-wide initfile
+	dodir /etc/
+	sed 's/^X//' > "${ED}"/etc/sbclrc <<-EOF
+	;;; The following is required if you want source location functions to
+	;;; work in SLIME, for example.
+	X
+	(setf (logical-pathname-translations "SYS")
+	X      '(("SYS:SRC;**;*.*.*" #p"${EPREFIX}/usr/$(get_libdir)/sbcl/src/**/*.*")
+	X        ("SYS:CONTRIB;**;*.*.*" #p"${EPREFIX}/usr/$(get_libdir)/sbcl/**/*.*")))
+	X
+	;;; Setup ASDF2
+	(load "${EPREFIX}/etc/common-lisp/gentoo-init.lisp")
+	EOF
+
+	# Install documentation
+	unset SBCL_HOME
+	INSTALL_ROOT="${ED}/usr" LIB_DIR="${EPREFIX}/usr/$(get_libdir)" DOC_DIR="${ED}/usr/share/doc/${PF}" \
+		sh install.sh || die "install.sh failed"
+
+	# bug #517008
+	pax-mark -mr "${D}"/usr/bin/sbcl
+
+	# rm empty directories lest paludis complain about this
+	find "${ED}" -empty -type d -exec rmdir -v {} +
+
+	if use doc; then
+		dodoc -r doc/internals/sbcl-internals
+
+		doinfo doc/manual/*.info*
+		doinfo doc/internals/sbcl-internals.info
+
+		docinto internals-notes
+		dodoc doc/internals-notes/*
+	else
+		rm -Rv "${ED}/usr/share/doc/${PF}" || die
+	fi
+
+	# install the SBCL source
+	if use source; then
+		./clean.sh
+		cp -av src "${ED}/usr/$(get_libdir)/sbcl/" || die
+	fi
+
+	# necessary for running newly-saved images
+	echo "SBCL_HOME=${EPREFIX}/usr/$(get_libdir)/${PN}" > "${ENVD}"
+	echo "SBCL_SOURCE_ROOT=${EPREFIX}/usr/$(get_libdir)/${PN}/src" >> "${ENVD}"
+	doenvd "${ENVD}"
+}