gentoo resync : 17.07.2021

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-perl/Net-RBLClient/Net-RBLClient-0.500.0-r3.ebuild b/dev-perl/Net-RBLClient/Net-RBLClient-0.500.0-r3.ebuild
new file mode 100644
index 000000000000..7c43e9bda6bf
--- /dev/null
+++ b/dev-perl/Net-RBLClient/Net-RBLClient-0.500.0-r3.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DIST_AUTHOR=ABLUM
+DIST_VERSION=0.5
+inherit perl-module
+
+DESCRIPTION="Queries multiple Realtime Blackhole Lists in parallel"
+
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ppc ppc64 sparc x86"
+
+RDEPEND="virtual/perl-Time-HiRes
+	dev-perl/Net-DNS"
+BDEPEND="${RDEPEND}
+"
+
+S=${WORKDIR}/RBLCLient-${DIST_VERSION} # second capitialized 'l' is deliberate
+
+src_test() {
+	local MODULES=(
+		"Net::RBLClient 0.4"
+	)
+	local failed=()
+	for dep in "${MODULES[@]}"; do
+		ebegin "Compile testing ${dep}"
+			perl -Mblib="${S}" -M"${dep} ()" -e1
+		eend $? || failed+=( "$dep" )
+	done
+	if [[ ${failed[@]} ]]; then
+		echo
+		eerror "One or more modules failed compile:";
+		for dep in "${failed[@]}"; do
+			eerror "  ${dep}"
+		done
+		die "Failing due to module compilation errors";
+	fi
+	perl-module_src_test
+}