gentoo auto-resync : 27:06:2024 - 07:59:39

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-python/Faker/Faker-25.9.2.ebuild b/dev-python/Faker/Faker-25.9.2.ebuild
new file mode 100644
index 000000000000..bef66c8c66a9
--- /dev/null
+++ b/dev-python/Faker/Faker-25.9.2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A Python package that generates fake data for you"
+HOMEPAGE="
+	https://github.com/joke2k/faker/
+	https://pypi.org/project/Faker/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
+	!dev-ruby/faker
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},tiff]
+		dev-python/validators[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=faker.contrib.pytest.plugin
+	epytest
+	EPYTEST_XDIST= epytest --exclusive-faker-session tests/pytest/session_overrides
+}