gentoo resync : 25.01.2018

3 files changed, 3 insertions, 198 deletions

diff --git a/dev-python/PyQt4/Manifest b/dev-python/PyQt4/Manifest
index b0631814a7ff..93cbd3113eee 100644
--- a/dev-python/PyQt4/Manifest
+++ b/dev-python/PyQt4/Manifest
@@ -1,7 +1,5 @@
 AUX PyQt4-4.11.2-phonon.patch 897 BLAKE2B b4834b319d15f96b80e4cb3bc4fe6d3f690df3f1b97d79ee35cd0dcb3a4abb4542c56b84991137ee50a86f1a0abcb6ccddca213d8d50e54e43520f76d2f11eb8 SHA512 e6e0364a24e43682c829da0a3d2ece8fdf54df00ee4fb00927a0530f3d5b62177877452058ab67cd9006ef8902d72f863e69d9ffb3b98b49f407566f96430bee
 AUX PyQt4-4.7.3-qreal_float_support.patch 5954 BLAKE2B ae198e39b05d42aa9be83a4d2bb69ba3705f3bc8e72ebc3e7b6ba7ef650f68f7d2dcb13dfade1dbb6a441809d39f4b9ade7fa3eaa075bc13cc16a0ef20b98022 SHA512 5431778103c333c1f13850f4b5fe982f4fe8e04c6cabb013ab8fff7d6117f9d0d5b8c7bbc6d5ceaceaa84fa8984276dda373e989ef3a8d90d3a1ae2220a97af2
 DIST PyQt4_gpl_x11-4.12.1.tar.gz 11328010 BLAKE2B b1261318eed18faa4eb94b1b3db9d2ba9f4d000f295eab6985ce2e6e39f3c94ab5b524a1d437406b8154d6b9ada1da710d427af0a1c410579eb9194b36aeb4cf SHA512 0651816ed5a371c24827e182eac5b2a2afe67928d95a09f63bd8158117aacd3e835b1efa06d4fc0c147a28038613a5bc088bd736a1348de68199da7952299af1
-DIST PyQt4_gpl_x11-4.12.tar.gz 11325395 BLAKE2B 5a31ecd4c4e516dc0520591313f420fa3d56d46454ea43309b26bfc00cbd7b737efd244f1377e705b1025670257c39d47c1687c76d3af1893878d8bb1834484e SHA512 bc5ee53e6ab8d32e240bbbd85aec9ce18a398848c0ee73d874763156256f7942a4a452a26f34fe035fdbeba5fb1df060910688f8a1bc7f7f183543d3dd0fd731
-EBUILD PyQt4-4.12.1.ebuild 4726 BLAKE2B dce917cd4c545ad37422e352b44ac582b7a5c346ad1176c4874ce08731ecf2e16a883ffafb5a28f9b815dc2ca342f9034a55a4b7df19e38317fa90b7ff7b818a SHA512 8814e5492d22fdc9f3e4af6d794545e258f57bfe6ffeee2903a94d989d174fb0c4169b2e3e0b676829ebe02e4f145dc94ce4311370028820ff2df17f47207930
-EBUILD PyQt4-4.12.ebuild 4723 BLAKE2B 441c0b2cfb0ff02295808a7d812cca49149ef06c7226ff95ff782ead9d90eab35af016188abcfe308d7d085058cc10aafb552dd4937af40af46090cc4fce31dc SHA512 04a5e08557d5f44c247105c9a52b3b524dc03f02e4798c7f3833bb6455ccc511ece323d3341c2e9e6213d9bd5f3d09b51258b006195a73072f5dc797ec448236
+EBUILD PyQt4-4.12.1.ebuild 4725 BLAKE2B 74a04ca3df420dc17b95bc5aec8e0d874c121a053c3018ecec8b7d3df567705ec99fe23fc8c9f567ecb22b95d74e0fea4e56b745b4af4d03619e370beca11380 SHA512 19fd9c014da59750dd5e0f5ada820ab7a97fc6f394d788f1d59d0e4d236d4d5fe2a8694e731e1200cc1fbd15854cc333f6889e6f21e2cc810f258fe6f5a8e38b
 MISC metadata.xml 1770 BLAKE2B dfb5d8b53c0a5666b0ffda7a9f055eb134f651781e579cd3171ddbcf0a50c3bd5d307a6ff87647c4632b66f5b64601021bb57bf6fb73cfbd504c0aea8a6dc1fe SHA512 6c6671ad8dd20f4d1701facd3b7de794b4eca907ba273f5c6626b691753ea26c0679cd4d91c1847beebcc298341ddf19d71bb4d3eb203e10720c64c54a2ee559
diff --git a/dev-python/PyQt4/PyQt4-4.12.1.ebuild b/dev-python/PyQt4/PyQt4-4.12.1.ebuild
index 29f5ca288ca8..33ecc5f591f6 100644
--- a/dev-python/PyQt4/PyQt4-4.12.1.ebuild
+++ b/dev-python/PyQt4/PyQt4-4.12.1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -18,7 +18,7 @@ fi
 
 LICENSE="GPL-3"
 SLOT="0"
-KEYWORDS="alpha amd64 ~arm ~arm64 ia64 ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux"
+KEYWORDS="alpha amd64 arm ~arm64 ia64 ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux"
 
 IUSE="X compat dbus debug declarative designer doc examples help multimedia
 	opengl phonon script scripttools sql svg testlib webkit xmlpatterns"
diff --git a/dev-python/PyQt4/PyQt4-4.12.ebuild b/dev-python/PyQt4/PyQt4-4.12.ebuild
deleted file mode 100644
index 979f8323a03b..000000000000
--- a/dev-python/PyQt4/PyQt4-4.12.ebuild
+++ /dev/null
@@ -1,193 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
-
-inherit multibuild python-r1 qmake-utils toolchain-funcs
-
-DESCRIPTION="Python bindings for the Qt framework"
-HOMEPAGE="https://www.riverbankcomputing.com/software/pyqt/intro"
-
-MY_P=${PN}_gpl_x11-${PV/_pre/.dev}
-if [[ ${PV} == *_pre* ]]; then
-	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.xz"
-else
-	SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"
-fi
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="alpha amd64 arm ~arm64 ia64 ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux"
-
-IUSE="X compat dbus debug declarative designer doc examples help multimedia
-	opengl phonon script scripttools sql svg testlib webkit xmlpatterns"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	sql? ( X )
-	testlib? ( X )
-"
-
-# Minimal supported version of Qt.
-QT_PV="4.8.5:4"
-
-RDEPEND="
-	${PYTHON_DEPS}
-	>=dev-python/sip-4.19:=[${PYTHON_USEDEP}]
-	>=dev-qt/qtcore-${QT_PV}
-	X? ( >=dev-qt/qtgui-${QT_PV} )
-	dbus? (
-		dev-python/dbus-python[${PYTHON_USEDEP}]
-		>=dev-qt/qtdbus-${QT_PV}
-	)
-	declarative? ( >=dev-qt/qtdeclarative-${QT_PV} )
-	designer? ( >=dev-qt/designer-${QT_PV} )
-	help? ( >=dev-qt/qthelp-${QT_PV} )
-	multimedia? ( >=dev-qt/qtmultimedia-${QT_PV} )
-	opengl? ( >=dev-qt/qtopengl-${QT_PV} )
-	phonon? ( >=media-libs/phonon-4.7[qt4] )
-	script? ( >=dev-qt/qtscript-${QT_PV} )
-	scripttools? ( >=dev-qt/qtgui-${QT_PV} )
-	sql? ( >=dev-qt/qtsql-${QT_PV} )
-	svg? ( >=dev-qt/qtsvg-${QT_PV} )
-	testlib? ( >=dev-qt/qttest-${QT_PV} )
-	webkit? ( >=dev-qt/qtwebkit-${QT_PV} )
-	xmlpatterns? ( >=dev-qt/qtxmlpatterns-${QT_PV} )
-"
-DEPEND="${RDEPEND}
-	dbus? ( virtual/pkgconfig )
-"
-
-S=${WORKDIR}/${MY_P}
-
-DOCS=( "${S}"/{ChangeLog,NEWS,THANKS} )
-PATCHES=(
-	# Allow building against KDE's phonon (bug 525354)
-	"${FILESDIR}/${PN}-4.11.2-phonon.patch"
-)
-
-src_prepare() {
-	# Support qreal on arm architecture (bug 322349)
-	use arm && PATCHES+=("${FILESDIR}/${PN}-4.7.3-qreal_float_support.patch")
-
-	default
-}
-
-pyqt_run() {
-	echo "$@"
-	"${PYTHON}" "$@"
-}
-
-pyqt_use_enable() {
-	use "$1" || return
-
-	echo --enable=${2:-Qt$(tr 'a-z' 'A-Z' <<< ${1:0:1})${1:1}}
-}
-
-src_configure() {
-	configuration() {
-		local myconf=(
-			$(usex debug '--debug --trace' '')
-			--verbose
-			--confirm-license
-			--qmake="$(qt4_get_bindir)"/qmake
-			--bindir="${EPREFIX}/usr/bin"
-			--destdir="$(python_get_sitedir)"
-			--qsci-api
-			--enable=QtCore
-			--enable=QtNetwork
-			--enable=QtXml
-			$(pyqt_use_enable X QtGui)
-			$(pyqt_use_enable dbus QtDBus)
-			$(pyqt_use_enable declarative)
-			$(pyqt_use_enable designer)
-			$(usex designer '' --no-designer-plugin)
-			$(pyqt_use_enable help)
-			$(pyqt_use_enable multimedia)
-			$(pyqt_use_enable opengl QtOpenGL)
-			$(pyqt_use_enable phonon phonon)
-			$(pyqt_use_enable script)
-			$(pyqt_use_enable scripttools QtScriptTools)
-			$(pyqt_use_enable sql)
-			$(pyqt_use_enable svg)
-			$(pyqt_use_enable testlib QtTest)
-			$(pyqt_use_enable webkit QtWebKit)
-			$(pyqt_use_enable xmlpatterns QtXmlPatterns)
-		)
-
-		if use compat; then
-			local compat_build_dir=${BUILD_DIR%/}-compat
-			cp -Rp "${S}" "${compat_build_dir}" || die
-			pushd "${compat_build_dir}" >/dev/null || die
-
-			local mycompatconf=(
-				"${myconf[@]}"
-				AR="$(tc-getAR) cqs"
-				CC="$(tc-getCC)"
-				CFLAGS="${CFLAGS}"
-				CFLAGS_RELEASE=
-				CXX="$(tc-getCXX)"
-				CXXFLAGS="${CXXFLAGS}"
-				CXXFLAGS_RELEASE=
-				LINK="$(tc-getCXX)"
-				LINK_SHLIB="$(tc-getCXX)"
-				LFLAGS="${LDFLAGS}"
-				LFLAGS_RELEASE=
-				RANLIB=
-				STRIP=
-			)
-			pyqt_run configure.py "${mycompatconf[@]}" || die
-
-			popd >/dev/null || die
-		fi
-
-		myconf+=(
-			--sip-incdir="$(python_get_includedir)"
-			$(usex dbus '' --no-python-dbus)
-		)
-		pyqt_run "${S}"/configure-ng.py "${myconf[@]}" || die
-
-		eqmake4 -recursive ${PN}.pro
-	}
-	python_foreach_impl run_in_build_dir configuration
-}
-
-src_compile() {
-	python_foreach_impl run_in_build_dir default
-}
-
-src_install() {
-	installation() {
-		local tmp_root=${D%/}/tmp
-		emake INSTALL_ROOT="${tmp_root}" install
-
-		local uic_dir=${tmp_root}$(python_get_sitedir)/${PN}/uic
-		if python_is_python3; then
-			rm -r "${uic_dir}"/port_v2 || die
-		else
-			rm -r "${uic_dir}"/port_v3 || die
-		fi
-
-		python_doexe "${tmp_root}${EPREFIX}"/usr/bin/pyuic4
-		rm "${tmp_root}${EPREFIX}"/usr/bin/pyuic4 || die
-
-		multibuild_merge_root "${tmp_root}" "${D}"
-
-		if use compat; then
-			local compat_build_dir=${BUILD_DIR%/}-compat
-			python_moduleinto ${PN}
-			python_domodule "${compat_build_dir}"/pyqtconfig.py
-		fi
-
-		python_optimize
-	}
-	python_foreach_impl run_in_build_dir installation
-
-	einstalldocs
-	use doc && dodoc -r doc/html
-
-	if use examples; then
-		insinto /usr/share/doc/${PF}
-		doins -r examples
-	fi
-}