gentoo auto-resync : 15:03:2025 - 00:29:11

2 files changed, 95 insertions, 0 deletions

diff --git a/dev-python/dbus-python/Manifest b/dev-python/dbus-python/Manifest
index 034f83dbb584..d17e52746f43 100644
--- a/dev-python/dbus-python/Manifest
+++ b/dev-python/dbus-python/Manifest
@@ -1,3 +1,5 @@
 DIST dbus-python-1.3.2.tar.gz 605495 BLAKE2B 6c60217b3837d655ab4f833b9f21d8f76eb4129cfeaa26586ef7adc8be8f8c5f03464428ff9f281b2566fb0f89cbb5e4b5618bf7cc961faf9f638d9011874839 SHA512 9b2885c9c2914142c72487f766b1cdd28a255d9f5a87eaf8f4eb420c6e096a77f210ac5a4fac9843c6531974872880cc28b7e45940e198856e984dcc0715519a
+DIST dbus-python-1.4.0.tar.xz 168268 BLAKE2B 17ed4ed1d6f76acf4dc55dc9d281081d0bb412811f0b340edd8c2ef767802dd0386ffa39cdbc7a61870b916b20c89bee0d6a5b6b8e9355c84d2fdc846575e465 SHA512 defd5fba8348635ce52654b7e93e6cacf52966f6facfb7bb04fc77f2f82129e0b7673d4f3d483ef3321985172987d8c3265b27b9200c68c39c729567ffa21456
 EBUILD dbus-python-1.3.2.ebuild 1934 BLAKE2B a99c6a4af45513350f05e87e72f3893e8796caa8ea4a14bdbb35c654151c24f0a785b11c877191b5f5c76c6d5dc1eea2b6a4ddd9015f719ef914b6dd9b801783 SHA512 2f1ac06fc12b5ea1c219b2e2151dd67675fe7be59311dbf6b81c82c6d18cac1c5965ac8330a4f5919d36d7021e91a18c3cf2e00c60683bafd412481518bd2ba3
+EBUILD dbus-python-1.4.0.ebuild 1946 BLAKE2B 769e4226b13eeccc9de655ff40be14cbc4993ffe494667060aa033a1816c2e940731111116b8b5adba261711e09a99640813ba8e326374b485ccaeadceebc514 SHA512 49d22a17f61b1629a4c4fa13eb7eaa95b3ac91aa1e768dbd98149d608e552f664c589085e499438c23c9d3e1b580dfd3c7638d384be4310b58d7fa0b5ca15c65
 MISC metadata.xml 404 BLAKE2B 14fb120b562c66c35e57d6686f87d2515d6e7a33e4a3027e2edde743ca533d8be63c8c3c4596de913c86091b2d768c997a1c25282efa657cab08131090cec588 SHA512 7a22b8fccd4715f6d817d528eadff1eaf126158f02113b318a4cf99b5a9bf7a05e67ad0ef1258399a937599bec23cb52f8fb42652948313fb8c8ba63bc5d22b6
diff --git a/dev-python/dbus-python/dbus-python-1.4.0.ebuild b/dev-python/dbus-python/dbus-python-1.4.0.ebuild
new file mode 100644
index 000000000000..d639a5a6848e
--- /dev/null
+++ b/dev-python/dbus-python/dbus-python-1.4.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit autotools python-r1
+
+DESCRIPTION="Python bindings for the D-Bus messagebus"
+HOMEPAGE="
+	https://www.freedesktop.org/wiki/Software/DBusBindings/
+	https://dbus.freedesktop.org/doc/dbus-python/
+"
+SRC_URI="https://dbus.freedesktop.org/releases/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc examples test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=sys-apps/dbus-1.8:=
+	>=dev-libs/glib-2.40
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		')
+	)
+	test? (
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/tap-py[${PYTHON_USEDEP}]
+	)
+"
+
+python_check_deps() {
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]" \
+		"dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	# Update py-compile, bug 529502.
+	eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	use doc && python_setup
+	local SPHINX_IMPL=${EPYTHON}
+
+	configuring() {
+		local myconf=(
+			--disable-documentation
+
+			# Work around broken AX_PYTHON_DEVEL macro.
+			# https://bugs.gentoo.org/815136
+			PYTHON_EXTRA_LIBS=' '
+		)
+		[[ ${EPYTHON} == ${SPHINX_IMPL} ]] &&
+			myconf+=( --enable-documentation )
+
+		econf "${myconf[@]}"
+	}
+	python_foreach_impl run_in_build_dir configuring
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir default
+	find "${D}" -name '*.la' -type f -delete || die
+
+	use examples && dodoc -r examples
+}