gentoo resync : 14.07.2018

4 files changed, 127 insertions, 0 deletions

diff --git a/dev-python/flask/Manifest b/dev-python/flask/Manifest
new file mode 100644
index 000000000000..039b24d80dec
--- /dev/null
+++ b/dev-python/flask/Manifest
@@ -0,0 +1,4 @@
+DIST Flask-0.12.2.tar.gz 548510 BLAKE2B bd92d0e7e6ff36d371ffd958708517d16e41d1475af9153bf3d5234c33aa5c0ab415cbd254b711731cf8cffddac94b475f62d9fff2f9fe756b0fa30bb36d4343 SHA512 c00bb807e8fbc943e23a3721acf5b04320e7a58d658bca46bdf83a345b4c4d5729accae338505e134f01bc908adec9555fd94e8c87ef6f0367e6037215c06319
+EBUILD flask-0.12.2.ebuild 1837 BLAKE2B 9a6bca9ba5d490e5ed6d05d63c17d269ec271821ec2293ad587a58038c4d1468ce0c2e520ab75155b260922196a55b1d2a0d972da6270e43f8ca8e2c8fa60e02 SHA512 d3c5d6ab73f049229b352862892392efb03135a3193b00d7891c13025b0c161ed6d8d22014e4fbe5b2e72604006f3cce1640ff10bb42c06198ba49408d910e2f
+EBUILD flask-9999.ebuild 1235 BLAKE2B 6b0b88f074f20770ffc605526307edb3f4175685eb759714ce9065847d4cd44e90773ff03c764170076dc0ee8b13d60a765608b643bfabde11c0f0ded175c88a SHA512 e22e9a737dd51d2e2b936d7dbd3f7116a78db6adad1f43f0ed5714c8932d0a7708d1ed494d5f004d866974962bbd23d6ef0e1a0adb36acc6eb7bbf6f87576b4b
+MISC metadata.xml 363 BLAKE2B f031e9e0d44bc626f4cc00538e6030e732f97286a09d061cfd8b7e03c8506cc9ddc8caab73d9c10363c5bd0eab1bfe6129a668bd6c66e3d82d9221cfd1175629 SHA512 33989d02b79b82d3256dbbf7402d79580d529e728222d74dbb80f740dfc1f8f1357f03ab5da857ff1821f2bb90f7b7eeae71d89e237516da62656d3d124ef4d6
diff --git a/dev-python/flask/flask-0.12.2.ebuild b/dev-python/flask/flask-0.12.2.ebuild
new file mode 100644
index 000000000000..a6175a6ac4c9
--- /dev/null
+++ b/dev-python/flask/flask-0.12.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+HOMEPAGE="https://github.com/pallets/flask/"
+MY_PN="Flask"
+MY_P="${MY_PN}-${PV}"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/mitsuhiko/flask.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+	KEYWORDS="amd64 arm ~arm64 ppc ppc64 x86 ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc examples test"
+
+RDEPEND=">=dev-python/click-2[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-0.21[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.4[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-0.7[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	sed -e "s/ 'sphinx.ext.intersphinx',//" -i docs/conf.py || die
+	# DeprecationWarning: Flags not at the start of the expression
+	sed -e "s/r'\(.*\)\((?.*)\)'/r'\2\1'/" -i tests/test_basic.py || die
+	# issubclass(ModuleNotFoundError, ImportError)
+	sed -e 's/\(excinfo.type\) is \(ImportError\)/issubclass(\1, \2)/' \
+		-i tests/test_ext.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	PYTHONPATH=${S}/examples/flaskr:${S}/examples/minitwit${PYTHONPATH:+:${PYTHONPATH}} \
+		py.test -v || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	use doc && HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/flask/flask-9999.ebuild b/dev-python/flask/flask-9999.ebuild
new file mode 100644
index 000000000000..3329ccaa5a94
--- /dev/null
+++ b/dev-python/flask/flask-9999.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+HOMEPAGE="https://pypi.org/project/Flask/"
+MY_PN="Flask"
+MY_P="${MY_PN}-${PV}"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/mitsuhiko/flask.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc examples test"
+
+RDEPEND="dev-python/blinker[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-0.21[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.4[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-0.7[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test tests || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	use doc && HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/flask/metadata.xml b/dev-python/flask/metadata.xml
new file mode 100644
index 000000000000..0d860934115e
--- /dev/null
+++ b/dev-python/flask/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">Flask</remote-id>
+		<remote-id type="github">mitsuhiko/flask</remote-id>
+	</upstream>
+</pkgmetadata>